/usr/lib/x86_64-linux-gnu/qt5/qml/QtQuick/Controls/Styles/Base/ToggleButtonStyle.qml is in qml-module-qtquick-controls 5.9.5-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 | /****************************************************************************
**
** Copyright (C) 2016 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Qt Quick Extras module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:LGPL$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPL3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl-3.0.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or (at your option) the GNU General
** Public license version 3 or any later version approved by the KDE Free
** Qt Foundation. The licenses are as published by the Free Software
** Foundation and appearing in the file LICENSE.GPL2 and LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-2.0.html and
** https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.2
import QtGraphicalEffects 1.0
import QtQuick.Controls.Styles 1.4
import QtQuick.Extras 1.4
import QtQuick.Extras.Private 1.0
import QtQuick.Extras.Private.CppUtils 1.0
/*!
\qmltype ToggleButtonStyle
\inqmlmodule QtQuick.Controls.Styles
\since 5.5
\ingroup controlsstyling
\brief Provides custom styling for ToggleButton.
You can create a custom toggle button by replacing the same delegates that
\l {ButtonStyle} provides.
*/
CircularButtonStyle {
id: circularButtonStyle
/*!
The \l ToggleButton that this style is attached to.
*/
readonly property ToggleButton control: __control
/*!
The gradient that is displayed on the inactive state indicator. The
inactive state indicator will be the checked gradient when the button
is unchecked, and the unchecked gradient when the button is checked.
\sa checkedGradient, uncheckedGradient
*/
property Gradient inactiveGradient: Gradient {
GradientStop {
position: 0
color: commonStyleHelper.inactiveColor
}
GradientStop {
position: 1
color: commonStyleHelper.inactiveColorShine
}
}
/*!
The gradient that is displayed on the checked state indicator.
\sa uncheckedGradient, inactiveGradient
*/
property Gradient checkedGradient: Gradient {
GradientStop {
position: 0
color: commonStyleHelper.onColor
}
GradientStop {
position: 1
color: commonStyleHelper.onColorShine
}
}
/*!
The gradient that is displayed on the unchecked state indicator.
\sa checkedGradient, inactiveGradient
*/
property Gradient uncheckedGradient: Gradient {
GradientStop {
position: 0
color: commonStyleHelper.offColor
}
GradientStop {
position: 1
color: commonStyleHelper.offColorShine
}
}
/*!
The color that is used for the drop shadow below the checked state
indicator.
\sa uncheckedDropShadowColor
*/
property color checkedDropShadowColor: commonStyleHelper.onColor
/*!
The color that is used for the drop shadow below the checked state
indicator.
\sa checkedDropShadowColor
*/
property color uncheckedDropShadowColor: commonStyleHelper.offColor
CommonStyleHelper {
id: commonStyleHelper
}
background: Item {
implicitWidth: __buttonHelper.implicitWidth
implicitHeight: __buttonHelper.implicitHeight
Connections {
target: control
onPressedChanged: {
backgroundCanvas.requestPaint();
}
onCheckedChanged: {
uncheckedCanvas.requestPaint();
checkedCanvas.requestPaint();
}
}
Connections {
target: circularButtonStyle
onCheckedGradientChanged: checkedCanvas.requestPaint()
onCheckedDropShadowColorChanged: checkedCanvas.requestPaint()
onUncheckedGradientChanged: uncheckedCanvas.requestPaint()
onUncheckedDropShadowColorChanged: uncheckedCanvas.requestPaint()
onInactiveGradientChanged: {
checkedCanvas.requestPaint();
uncheckedCanvas.requestPaint();
}
}
Connections {
target: circularButtonStyle.checkedGradient
onUpdated: checkedCanvas.requestPaint()
}
Connections {
target: circularButtonStyle.uncheckedGradient
onUpdated: uncheckedCanvas.requestPaint()
}
Connections {
target: circularButtonStyle.inactiveGradient
onUpdated: {
uncheckedCanvas.requestPaint();
checkedCanvas.requestPaint();
}
}
Canvas {
id: backgroundCanvas
anchors.fill: parent
onPaint: {
var ctx = getContext("2d");
__buttonHelper.paintBackground(ctx);
}
}
Canvas {
id: uncheckedCanvas
anchors.fill: parent
anchors.margins: -(__buttonHelper.radius * 3)
visible: control.checked
readonly property real xCenter: width / 2
readonly property real yCenter: height / 2
onPaint: {
var ctx = getContext("2d");
ctx.reset();
/* Draw unchecked indicator */
ctx.beginPath();
ctx.lineWidth = __buttonHelper.outerArcLineWidth - __buttonHelper.innerArcLineWidth;
ctx.arc(xCenter, yCenter, __buttonHelper.outerArcRadius + __buttonHelper.innerArcLineWidth / 2,
MathUtils.degToRad(180), MathUtils.degToRad(270), false);
var gradient = ctx.createLinearGradient(xCenter, yCenter + __buttonHelper.radius,
xCenter, yCenter - __buttonHelper.radius);
var relevantGradient = control.checked ? inactiveGradient : uncheckedGradient;
for (var i = 0; i < relevantGradient.stops.length; ++i) {
gradient.addColorStop(relevantGradient.stops[i].position, relevantGradient.stops[i].color);
}
ctx.strokeStyle = gradient;
ctx.stroke();
}
}
Canvas {
id: checkedCanvas
anchors.fill: parent
anchors.margins: -(__buttonHelper.radius * 3)
visible: !control.checked
readonly property real xCenter: width / 2
readonly property real yCenter: height / 2
onPaint: {
var ctx = getContext("2d");
ctx.reset();
/* Draw checked indicator */
ctx.beginPath();
ctx.lineWidth = __buttonHelper.outerArcLineWidth - __buttonHelper.innerArcLineWidth;
ctx.arc(xCenter, yCenter, __buttonHelper.outerArcRadius + __buttonHelper.innerArcLineWidth / 2,
MathUtils.degToRad(270), MathUtils.degToRad(0), false);
var gradient = ctx.createLinearGradient(xCenter, yCenter + __buttonHelper.radius,
xCenter, yCenter - __buttonHelper.radius);
var relevantGradient = control.checked ? checkedGradient : inactiveGradient;
for (var i = 0; i < relevantGradient.stops.length; ++i) {
gradient.addColorStop(relevantGradient.stops[i].position, relevantGradient.stops[i].color);
}
ctx.strokeStyle = gradient;
ctx.stroke();
}
}
DropShadow {
id: uncheckedDropShadow
anchors.fill: uncheckedCanvas
cached: true
color: uncheckedDropShadowColor
source: uncheckedCanvas
visible: !control.checked
}
DropShadow {
id: checkedDropShadow
anchors.fill: checkedCanvas
cached: true
color: checkedDropShadowColor
source: checkedCanvas
visible: control.checked
}
}
panel: Item {
implicitWidth: backgroundLoader.implicitWidth
implicitHeight: backgroundLoader.implicitHeight
Loader {
id: backgroundLoader
anchors.fill: parent
sourceComponent: background
}
Loader {
id: labelLoader
sourceComponent: label
anchors.fill: parent
anchors.leftMargin: padding.left
anchors.topMargin: padding.top
anchors.rightMargin: padding.right
anchors.bottomMargin: padding.bottom
}
}
}
|