/usr/share/perl5/PPIx/Regexp/Token/Reference.pm is in libppix-regexp-perl 0.023-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 | =head1 NAME
PPIx::Regexp::Token::Reference - Represent a reference to a capture
=head1 SYNOPSIS
use PPIx::Regexp::Dumper;
PPIx::Regexp::Dumper->new( 'qr{\1}smx' )
->print();
=head1 INHERITANCE
C<PPIx::Regexp::Token::Reference> is a
L<PPIx::Regexp::Token|PPIx::Regexp::Token>.
C<PPIx::Regexp::Token::Reference> is the parent of
L<PPIx::Regexp::Token::Backreference|PPIx::Regexp::Token::Backreference>,
L<PPIx::Regexp::Token::Condition|PPIx::Regexp::Token::Condition> and
L<PPIx::Regexp::Token::Recursion|PPIx::Regexp::Token::Recursion>.
=head1 DESCRIPTION
This abstract class represents a reference to a capture buffer, either
numbered or named. It should never be instantiated, but it provides a
number of methods to its subclasses.
=head1 METHODS
This class provides the following public methods. Methods not documented
here are private, and unsupported in the sense that the author reserves
the right to change or remove them without notice.
=cut
package PPIx::Regexp::Token::Reference;
use strict;
use warnings;
use base qw{ PPIx::Regexp::Token };
use Carp qw{ confess };
use List::Util qw{ first };
our $VERSION = '0.023';
=head2 absolute
print "The absolute reference is ", $ref->absolute(), "\n";
This method returns the absolute number of the capture buffer referred
to. This is the same as number() for unsigned numeric references. If the
reference is to a named buffer, C<undef> is returned.
=cut
sub absolute {
my ( $self ) = @_;
return $self->{absolute};
}
=head2 is_named
$ref->is_named and print "named reference\n";
This method returns true if the reference is named rather than numbered.
=cut
sub is_named {
my ( $self ) = @_;
return $self->{is_named};
}
=head2 is_relative
$ref->is_relative()
and print "relative numbered reference\n";
This method returns true if the reference is numbered and it is a
relative number (i.e. if it is signed).
=cut
sub is_relative {
my ( $self ) = @_;
return $self->{is_relative};
}
=head2 name
print "The name is ", $ref->name(), "\n";
This method returns the name of the capture buffer referred to. In the
case of a reference to a numbered capture (i.e. C<is_named> returns
false), this method returns C<undef>.
=cut
sub name {
my ( $self ) = @_;
return $self->{name};
}
=head2 number
print "The number is ", $ref->number(), "\n";
This method returns the number of the capture buffer referred to. In the
case of a reference to a named capture (i.e. C<is_named> returns true),
this method returns C<undef>.
=cut
sub number {
my ( $self ) = @_;
return $self->{number};
}
# Called by the lexer to record the capture number.
sub __PPIX_LEXER__record_capture_number {
my ( $self, $number ) = @_;
if ( ! exists $self->{absolute} && exists $self->{number}
&& $self->{number} =~ m/ \A [-+] /smx ) {
my $delta = $self->{number};
$delta > 0 and --$delta; # no -0 or +0.
$self->{absolute} = $number + $delta;
}
return $number;
}
# Called after the token is manufactured. The calling sequence is
# $token->__PPIX_TOKEN__post_make( $tokenizer, $arg );
# For the sake of reblessing into this class, we are expected to deal
# with the situation where the optional argument is missing.
sub __PPIX_TOKEN__post_make {
my ( $self, $tokenizer, $arg ) = @_;
my $capture;
if ( defined $arg ) {
$tokenizer
and $capture = first { defined $_ } $tokenizer->capture();
defined $capture or $capture = $arg->{capture};
} else {
my $content = $self->content();
foreach ( $self->__PPIX_TOKEN__recognize() ) {
my ( $re, $a ) = @{ $_ };
$content =~ $re or next;
$arg = $a;
if ( exists $arg->{capture} ) {
$capture = $arg->{capture};
} else {
foreach my $inx ( 1 .. $#- ) {
defined $-[$inx] or next;
$capture = substr $content, $-[$inx], $+[$inx] - $-[$inx];
last;
}
}
last;
}
}
defined $capture
or confess q{Programming error - reference '},
$self->content(), q{' of unknown form};
foreach my $key ( keys %{ $arg } ) {
$key eq 'capture' and next;
$self->{$key} = $arg->{$key};
}
if ( $arg->{is_named} ) {
$self->{absolute} = undef;
$self->{is_relative} = undef;
$self->{name} = $capture;
} elsif ( $capture !~ m/ \A [-+] /smx ) {
$self->{absolute} = $self->{number} = $capture;
$self->{is_relative} = undef;
} else {
$self->{number} = $capture;
$self->{is_relative} = 1;
}
return;
};
1;
__END__
=head1 SUPPORT
Support is by the author. Please file bug reports at
L<http://rt.cpan.org>, or in electronic mail to the author.
=head1 AUTHOR
Thomas R. Wyant, III F<wyant at cpan dot org>
=head1 COPYRIGHT AND LICENSE
Copyright (C) 2009-2011 by Thomas R. Wyant, III
This program is free software; you can redistribute it and/or modify it
under the same terms as Perl 5.10.0. For more details, see the full text
of the licenses in the directory LICENSES.
This program is distributed in the hope that it will be useful, but
without any warranty; without even the implied warranty of
merchantability or fitness for a particular purpose.
=cut
# ex: set textwidth=72 :
|