/usr/share/doc/libreadonly-perl/examples/benchmark.pl is in libreadonly-perl 1.03-3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 | #!/usr/bin/perl
# Very simple benchmark script to show how slow Readonly.pm is,
# and how Readonly::XS solves the problem.
use strict;
use Readonly;
use Benchmark;
use vars qw/$feedme/;
#
# use constant
#
use constant CONST_LINCOLN => 'Fourscore and seven years ago...';
sub const
{
$feedme = CONST_LINCOLN;
}
#
# literal constant
#
sub literal
{
$feedme = 'Fourscore and seven years ago...';
}
#
# typeglob constant
#
use vars qw/$glob_lincoln/;
*glob_lincoln = \ 'Fourscore and seven years ago...';
sub tglob
{
$feedme = $glob_lincoln;
}
#
# Normal perl read/write scalar
#
use vars qw/$norm_lincoln/;
$norm_lincoln = 'Fourscore and seven years ago...';
sub normal
{
$feedme = $norm_lincoln;
}
#
# Readonly.pm with Readonly::XS
#
use vars qw/$roxs_lincoln/;
Readonly::Scalar $roxs_lincoln => 'Fourscore and seven years ago...';
sub roxs
{
$feedme = $roxs_lincoln;
}
#
# Readonly.pm w/o Readonly::XS
#
use vars qw/$ro_lincoln/;
{
local $Readonly::XSokay = 0; # disable XS
Readonly::Scalar $ro_lincoln => 'Fourscore and seven years ago...';
}
sub ro
{
$feedme = $ro_lincoln;
}
my $code =
{
const => \&const,
literal => \&literal,
tglob => \&tglob,
normal => \&normal,
roxs => \&roxs,
ro => \&ro,
};
unless ($Readonly::XSokay)
{
print "Readonly::XS module not found; skipping that test.\n";
delete $code->{roxs};
}
timethese(2_000_000, $code);
|