/usr/share/jed/jed-extra/tm.sed is in jed-extra 2.5.6-1.
This file is owned by root:root, with mode 0o755.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 | #!/bin/sed -f
#
# $Id: tm.sed,v 1.2 2007/09/08 16:08:53 boekholt Exp $
#
# copyright (c) 2004, 2007 Paul Boekholt
# Released under the terms of the GNU GPL (version 2 or later).
#
# This is a sed script to extract tm documentation from S-Lang sources and
# render it as ASCII text.
# This matches beginning and end of a tm entry. The entire script
# is in this block.
/^%!%[+]/,/^%!%-/{
s/%!%[+]//
s/%!%[-]/--------------------------------------------------------------/
s/^%/ /
# verbatim
/^ #v+/,/ #v-/{
s/^ #v+//
s/^ #v-//
s/^/ /
p
d
}
# \var, \ivar, \svar, \ifun, \sfun, \exmp
# { and } characters inside parameter lists are escaped
# this scripts supports at most one such character
s/\\\(var\|ivar\|svar\|ifun\|sfun\|exmp\){\([^}]*\)\\}\([^}]*\)}/`\2}\3'/g
s/\\\(var\|ivar\|svar\|ifun\|sfun\|exmp\){\([^}]*\)\\{\([^}]*\)}/`\2{\3'/g
s/\\\(var\|ivar\|svar\|ifun\|sfun\|exmp\){\(\(\\}\|[^}]\)*\)}/`\2'/g
# \em
s/\\em{\(\(\\}\|[^}]\)*\)}/_\1_/g
# \NULL, \slang
s/\\NULL/NULL/g
s/\\slang/S-Lang/g
# \function, \variable
s/ \\function{\([^}]*\)}/\1/
s/ \\variable{\([^}]*\)}/\1/
# sections
s/\\seealso{\([^}]*\)}/\
SEE ALSO\
\1/
s/\\synopsis{\([^}]*\)}/\
SYNOPSIS\
\1/
s/\\usage{\([^}]*\)}/\
USAGE\
\1/
s/\\description/\
DESCRIPTION/
s/\\example/\
EXAMPLE/
s/\\notes/\
NOTES/
# undouble \-es
s/\\\\/\\/g
# print it!
p
}
# don't print the rest
d
|