/usr/share/perl5/Mojo/IOLoop/Stream.pm is in libmojolicious-perl 2.23-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 | package Mojo::IOLoop::Stream;
use Mojo::Base 'Mojo::EventEmitter';
use Errno qw/EAGAIN ECONNRESET EINTR EPIPE EWOULDBLOCK/;
use Scalar::Util 'weaken';
use constant CHUNK_SIZE => $ENV{MOJO_CHUNK_SIZE} || 131072;
has iowatcher => sub {
require Mojo::IOLoop;
Mojo::IOLoop->singleton->iowatcher;
};
# "And America has so many enemies.
# Iran, Iraq, China, Mordor, the hoochies that laid low Tiger Woods,
# undesirable immigrants - by which I mean everyone that came after me,
# including my children..."
sub DESTROY {
my $self = shift;
return unless my $watcher = $self->{iowatcher};
return unless my $handle = $self->{handle};
$watcher->drop_handle($handle);
close $handle;
$self->_close;
}
sub new {
my $self = shift->SUPER::new;
$self->{handle} = shift;
$self->{buffer} = '';
return $self;
}
sub handle { shift->{handle} }
sub is_writing {
my $self = shift;
return length($self->{buffer}) || $self->has_subscribers('drain');
}
sub pause {
my $self = shift;
return if $self->{paused}++;
$self->iowatcher->change($self->{handle}, 0, $self->is_writing);
}
sub resume {
my $self = shift;
# Start streaming
unless ($self->{streaming}++) {
weaken $self;
return $self->iowatcher->watch(
$self->{handle},
on_readable => sub { $self->_read },
on_writable => sub { $self->_write }
);
}
# Resume streaming
return unless delete $self->{paused};
$self->iowatcher->change($self->{handle}, 1, $self->is_writing);
}
# "No children have ever meddled with the Republican Party and lived to tell
# about it."
sub steal_handle {
my $self = shift;
$self->iowatcher->drop_handle($self->{handle});
return delete $self->{handle};
}
sub write {
my ($self, $chunk, $cb) = @_;
# Prepare chunk for writing
$self->{buffer} .= $chunk;
# Write with roundtrip
if ($cb) { $self->once(drain => $cb) }
else { return unless length $self->{buffer} }
# Start writing
$self->iowatcher->change($self->{handle}, !$self->{paused}, 1)
if $self->{handle};
}
sub _close {
my $self = shift;
$self->emit_safe('close') unless $self->{closed}++;
}
sub _read {
my $self = shift;
# Read
my $read = $self->{handle}->sysread(my $buffer, CHUNK_SIZE, 0);
# Error
unless (defined $read) {
# Retry
return if $! ~~ [EAGAIN, EINTR, EWOULDBLOCK];
# Closed
return $self->_close if $! == ECONNRESET;
# Read error
return $self->emit_safe(error => $!);
}
# EOF
return $self->_close if $read == 0;
# Handle read
$self->emit_safe(read => $buffer);
}
sub _write {
my $self = shift;
# Write as much as possible
my $handle = $self->{handle};
if (length $self->{buffer}) {
my $written = $handle->syswrite($self->{buffer});
# Error
unless (defined $written) {
# Retry
return if $! ~~ [EAGAIN, EINTR, EWOULDBLOCK];
# Closed
return $self->_close if $! ~~ [ECONNRESET, EPIPE];
# Write error
return $self->emit_safe(error => $!);
}
# Remove written chunk from buffer
substr $self->{buffer}, 0, $written, '';
}
# Handle drain
$self->emit_safe('drain') if !length $self->{buffer};
# Stop writing
return if $self->is_writing;
$self->iowatcher->change($handle, !$self->{paused}, 0);
}
1;
__END__
=head1 NAME
Mojo::IOLoop::Stream - IOLoop stream
=head1 SYNOPSIS
use Mojo::IOLoop::Stream;
# Create stream
my $stream = Mojo::IOLoop::Stream->new($handle);
$stream->on(read => sub {
my ($stream, $chunk) = @_;
...
});
$stream->on(close => sub {
my $stream = shift;
...
});
$stream->on(error => sub {
my ($stream, $error) = @_;
...
});
# Start and stop watching for new data
$stream->resume;
$stream->pause;
=head1 DESCRIPTION
L<Mojo::IOLoop::Stream> is a container for streaming handles used by
L<Mojo::IOLoop>.
Note that this module is EXPERIMENTAL and might change without warning!
=head1 EVENTS
L<Mojo::IOLoop::Stream> can emit the following events.
=head2 C<close>
$stream->on(close => sub {
my $stream = shift;
});
Emitted if the stream gets closed.
=head2 C<drain>
$stream->on(drain => sub {
my $stream = shift;
});
Emitted once all data has been written.
=head2 C<error>
$stream->on(error => sub {
my ($stream, $error) = @_;
});
Emitted if an error happens on the stream.
=head2 C<read>
$stream->on(read => sub {
my ($stream, $chunk) = @_;
});
Emitted if new data arrives on the stream.
=head1 ATTRIBUTES
L<Mojo::IOLoop::Stream> implements the following attributes.
=head2 C<iowatcher>
my $watcher = $stream->iowatcher;
$stream = $stream->iowatcher(Mojo::IOWatcher->new);
Low level event watcher, defaults to the C<iowatcher> attribute value of the
global L<Mojo::IOLoop> singleton.
=head1 METHODS
L<Mojo::IOLoop::Stream> inherits all methods from L<Mojo::EventEmitter> and
implements the following new ones.
=head2 C<new>
my $stream = Mojo::IOLoop::Stream->new($handle);
Construct a new L<Mojo::IOLoop::Stream> object.
=head2 C<handle>
my $handle = $stream->handle;
Get handle for stream.
=head2 C<is_writing>
my $success = $stream->is_writing;
Check if stream is writing.
=head2 C<pause>
$stream->pause;
Stop watching for new data on the stream.
=head2 C<resume>
$stream->resume;
Start watching for new data on the stream.
=head2 C<steal_handle>
my $handle = $stream->steal_handle;
Steal handle from stream and prevent it from getting closed automatically.
=head2 C<write>
$stream->write('Hello!');
$stream->write('Hello!', sub {...});
Write data to stream, the optional drain callback will be invoked once all
data has been written.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|