/usr/share/perl5/Mojolicious/Command/routes.pm is in libmojolicious-perl 2.23-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 | package Mojolicious::Command::routes;
use Mojo::Base 'Mojo::Command';
use re 'regexp_pattern';
use Getopt::Long 'GetOptions';
has description => <<'EOF';
Show available routes.
EOF
has usage => <<"EOF";
usage: $0 routes [OPTIONS]
These options are available:
--verbose Print additional details about routes.
EOF
# "I'm finally richer than those snooty ATM machines."
sub run {
my $self = shift;
# Options
local @ARGV = @_;
my $verbose;
GetOptions(verbose => sub { $verbose = 1 });
# Check if application has routes
my $app = $self->app;
die "Application has no routes.\n" unless $app->can('routes');
# Walk and draw
my $routes = [];
$self->_walk($_, 0, $routes) for @{$app->routes->children};
$self->_draw($routes, $verbose);
}
sub _draw {
my ($self, $routes, $verbose) = @_;
# Length
my @length = (0, 0, 0);
for my $node (@$routes) {
# Pattern
my $len = length $node->[0];
$length[0] = $len if $len > $length[0];
# Methods
unless (defined $node->[1]->via) { $len = length '*' }
else { $len = length(join ',', @{$node->[1]->via}) }
$length[1] = $len if $len > $length[1];
# Name
$len = length $node->[1]->name;
$len += 2 if $node->[1]->has_custom_name;
$length[2] = $len if $len > $length[2];
}
# Draw
foreach my $node (@$routes) {
my @parts;
# Pattern
push @parts, $node->[0];
$parts[-1] .= ' ' x ($length[0] - length $parts[-1]);
# Methods
my $methods;
unless (defined $node->[1]->via) { $methods = '*' }
else { $methods = uc join ',', @{$node->[1]->via} }
push @parts, $methods . ' ' x ($length[1] - length $methods);
# Name
my $name = $node->[1]->name;
$name = qq/"$name"/ if $node->[1]->has_custom_name;
push @parts, $name . ' ' x ($length[2] - length $name);
# Regex
(my $pattern = $node->[1]->pattern)->match('/');
my $regex = (regexp_pattern $pattern->regex)[0];
my $format = (regexp_pattern $pattern->format)[0];
my $req = $pattern->reqs->{format};
$format = defined $req ? '' : "(?:$format)?" unless $req;
push @parts, $node->[1]->is_endpoint ? "$regex$format" : $regex
if $verbose;
# Route
say join(' ', @parts);
}
}
# "I surrender, and volunteer for treason!"
sub _walk {
my ($self, $node, $depth, $routes) = @_;
# Pattern
my $prefix = '';
if (my $i = $depth * 2) { $prefix .= ' ' x $i . '+' }
push @$routes, [$prefix . ($node->pattern->pattern || '/'), $node];
# Walk
$depth++;
$self->_walk($_, $depth, $routes) for @{$node->children};
$depth--;
}
1;
__END__
=head1 NAME
Mojolicious::Command::routes - Routes command
=head1 SYNOPSIS
use Mojolicious::Command::routes;
my $routes = Mojolicious::Command::routes->new;
$routes->run(@ARGV);
=head1 DESCRIPTION
L<Mojolicious::Command::routes> prints all your application routes.
=head1 ATTRIBUTES
L<Mojolicious::Command::routes> inherits all attributes from L<Mojo::Command>
and implements the following new ones.
=head2 C<description>
my $description = $routes->description;
$routes = $routes->description('Foo!');
Short description of this command, used for the command list.
=head2 C<usage>
my $usage = $routes->usage;
$routes = $routes->usage('Foo!');
Usage information for this command, used for the help screen.
=head1 METHODS
L<Mojolicious::Command::routes> inherits all methods from L<Mojo::Command>
and implements the following new ones.
=head2 C<run>
$routes->run(@ARGV);
Run this command.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|