/usr/share/perl5/Mojolicious/Plugin/Config.pm is in libmojolicious-perl 2.23-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 | package Mojolicious::Plugin::Config;
use Mojo::Base 'Mojolicious::Plugin';
use File::Basename 'basename';
use File::Spec;
use Mojo::Util 'decamelize';
use constant DEBUG => $ENV{MOJO_CONFIG_DEBUG} || 0;
# "Who are you, my warranty?!"
sub load {
my ($self, $file, $conf, $app) = @_;
$app->log->debug(qq/Reading config file "$file"./);
# Slurp UTF-8 file
open my $handle, "<:encoding(UTF-8)", $file
or die qq/Couldn't open config file "$file": $!/;
my $content = do { local $/; <$handle> };
# Process
return $self->parse($content, $file, $conf, $app);
}
sub parse {
my ($self, $content, $file, $conf, $app) = @_;
# Run Perl code
no warnings;
die qq/Couldn't parse config file "$file": $@/
unless my $config = eval "sub app { \$app }; $content";
die qq/Config file "$file" did not return a hashref.\n/
unless ref $config && ref $config eq 'HASH';
return $config;
}
sub register {
my ($self, $app, $conf) = @_;
$conf ||= {};
# Config file
my $file = $conf->{file} || $ENV{MOJO_CONFIG};
unless ($file) {
$file = $ENV{MOJO_APP};
# Class
if ($file && !ref $file) { $file = decamelize $file }
# File
else { $file = basename($ENV{MOJO_EXE} || $0) }
# Remove .pl and .t extentions
$file =~ s/\.(?:pl|t)$//i;
# Default extension
$file .= '.' . ($conf->{ext} || 'conf');
}
warn "CONFIG FILE $file\n" if DEBUG;
# Mode specific config file
my $mode;
if ($file =~ /^(.*)\.([^\.]+)$/) {
$mode = join '.', $1, $app->mode, $2;
warn "MODE SPECIFIC CONFIG FILE $mode\n" if DEBUG;
}
# Absolute path
$file = $app->home->rel_file($file)
unless File::Spec->file_name_is_absolute($file);
$mode = $app->home->rel_file($mode)
if defined $mode && !File::Spec->file_name_is_absolute($mode);
# Read config file
my $config = {};
if (-e $file) { $config = $self->load($file, $conf, $app) }
# Check for default
else {
# All missing
die qq/Config file "$file" missing, maybe you need to create it?\n/
unless $conf->{default};
$app->log->debug(qq/Config file "$file" missing, using default config./);
}
# Merge everything
$config = {%$config, %{$self->load($mode, $conf, $app)}}
if defined $mode && -e $mode;
$config = {%{$conf->{default}}, %$config} if $conf->{default};
# Add "config" helper
$app->helper(
config => sub {
my $self = shift;
return $config unless @_;
$config->{$_[0]};
}
);
# Add default stash value
$app->defaults(($conf->{stash_key} || 'config') => $config);
return $config;
}
1;
__END__
=head1 NAME
Mojolicious::Plugin::Config - Perl-ish configuration plugin
=head1 SYNOPSIS
# myapp.conf
{
foo => "bar",
music_dir => app->home->rel_dir('music')
};
# Mojolicious
my $config = $self->plugin('Config');
# Mojolicious::Lite
my $config = plugin 'Config';
# Reads myapp.conf by default and puts the parsed version into the stash
my $config = $self->stash('config');
# Everything can be customized with options
my $config = plugin Config => {
file => '/etc/myapp.stuff',
stash_key => 'conf'
};
=head1 DESCRIPTION
L<Mojolicious::Plugin::Config> is a Perl-ish configuration plugin.
The application object can be accessed via the C<app> helper.
You can extend the normal config file C<myapp.conf> with C<mode> specific
ones like C<myapp.$mode.conf>.
=head1 OPTIONS
L<Mojolicious::Plugin::Config> supports the following options.
=head2 C<default>
# Mojolicious::Lite
plugin Config => {default => {foo => 'bar'}};
Default configuration.
=head2 C<ext>
# Mojolicious::Lite
plugin Config => {ext => 'stuff'};
File extension of config file, defaults to C<conf>.
=head2 C<file>
# Mojolicious::Lite
plugin Config => {file => 'myapp.conf'};
plugin Config => {file => '/etc/foo.stuff'};
Configuration file, defaults to the value of the C<MOJO_CONFIG> environment
variable or C<myapp.conf> in the application home directory.
=head2 C<stash_key>
# Mojolicious::Lite
plugin Config => {stash_key => 'conf'};
Configuration stash key.
=head1 HELPERS
L<Mojolicious::Plugin::Config> implements the following helpers.
=head2 C<config>
%= config 'something'
%= config->{something}
Access config values.
=head1 METHODS
L<Mojolicious::Plugin::Config> inherits all methods from
L<Mojolicious::Plugin> and implements the following new ones.
=head2 C<load>
$plugin->load($file, $conf, $app);
Loads config file and passes the content to C<parse>.
sub load {
my ($self, $file, $conf, $app) = @_;
...
return $self->parse($content, $file, $conf, $app);
}
=head2 C<parse>
$plugin->parse($content, $file, $conf, $app);
Parse config file.
sub parse {
my ($self, $content, $file, $conf, $app) = @_;
...
return $hash;
}
=head2 C<register>
$plugin->register;
Register plugin in L<Mojolicious> application.
=head1 DEBUGGING
You can set the C<MOJO_CONFIG_DEBUG> environment variable to get some
advanced diagnostics information printed to C<STDERR>.
MOJO_CONFIG_DEBUG=1
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|