/usr/share/ada/adainclude/gtkada/gtkada-dialogs.adb is in libgtkada2.24.1-dev 2.24.1-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 | -----------------------------------------------------------------------
-- GtkAda - Ada95 binding for Gtk+/Gnome --
-- --
-- Copyright (C) 2000 E. Briot, J. Brobecker and A. Charlet --
-- Copyright (C) 2001-2008, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or --
-- modify it under the terms of the GNU General Public --
-- License as published by the Free Software Foundation; either --
-- version 2 of the License, or (at your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, --
-- but WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public --
-- License along with this library; if not, write to the --
-- Free Software Foundation, Inc., 59 Temple Place - Suite 330, --
-- Boston, MA 02111-1307, USA. --
-- --
-----------------------------------------------------------------------
with Ada.Strings; use Ada.Strings;
with Ada.Strings.Fixed; use Ada.Strings.Fixed;
with Gdk.Pixmap; use Gdk.Pixmap;
with Gdk.Color; use Gdk.Color;
with Gdk.Event; use Gdk.Event;
with Gdk.Window; use Gdk.Window;
with Glib; use Glib;
with Gtk.Box; use Gtk.Box;
with Gtk.Label; use Gtk.Label;
pragma Warnings (Off); -- Gtk.Pixmap is obsolescent
with Gtk.Pixmap; use Gtk.Pixmap;
pragma Warnings (On);
with Gtk.Widget; use Gtk.Widget;
with Gtkada.Intl; use Gtkada.Intl;
with Gtkada.Pixmaps; use Gtkada.Pixmaps;
package body Gtkada.Dialogs is
subtype String_6 is String (1 .. 6);
type String_Const_Ptr is access constant String;
Dialog_Button_String : constant array (Button_Range) of String_6 :=
("Yes ",
"No ",
"All ",
"OK ",
"Cancel",
"Abort ",
"Retry ",
"Ignore",
"Help ");
Yes : aliased constant String := "gtk-yes";
No : aliased constant String := "gtk-no";
Ok : aliased constant String := "gtk-ok";
Cancel : aliased constant String := "gtk-cancel";
Help : aliased constant String := "gtk-help";
-- ??? We used to reference Gtk.Stock.Stock_* instead, but there is
-- apparently a bug in GCC when generating 'Access to these variables.
Dialog_Button_Stock : constant array (Button_Range) of String_Const_Ptr :=
(Yes'Access,
No'Access,
null,
Ok'Access,
Cancel'Access,
null,
null,
null,
Help'Access);
--------------------
-- Message_Dialog --
--------------------
function Message_Dialog
(Msg : UTF8_String;
Dialog_Type : Message_Dialog_Type := Information;
Buttons : Message_Dialog_Buttons := Button_OK or Button_Help;
Default_Button : Message_Dialog_Buttons := Button_OK;
Help_Msg : UTF8_String := "";
Title : UTF8_String := "";
Justification : Gtk_Justification := Justify_Center;
Parent : Gtk.Window.Gtk_Window := null)
return Message_Dialog_Buttons
is
Dialog : constant Gtk_Dialog := Create_Gtk_Dialog
(Msg => Msg,
Dialog_Type => Dialog_Type,
Title => Title,
Justification => Justification,
Parent => Parent);
Button : Gtk_Widget;
Result : Message_Dialog_Buttons;
Response : Gtk_Response_Type;
begin
if Parent = null
or else not Realized_Is_Set (Parent)
then
Set_Position (Dialog, Win_Pos_Mouse);
elsif (Get_State (Get_Window (Parent))
and Window_State_Iconified) /= 0
then
-- If the parent is not visible, do not center the dialog on it,
-- let the window manager decide the position instead.
Set_Position (Dialog, Win_Pos_None);
end if;
for J in Button_Range loop
if (Buttons and 2 ** Integer (J)) /= 0 then
-- Use Gtk_Response_Cancel for the Cancel or No buttons, so that
-- Esc can be used to close the dialog. Likewise, if none of these
-- two was provided, simply use Cancel for the OK button
if J = 4
or else (J = 1 and then (Buttons and Button_Cancel) = 0)
or else (J = 3 and then (Buttons and Button_Cancel) = 0
and then (Buttons and Button_No) = 0)
then
Response := Gtk_Response_Cancel;
else
Response := Gtk_Response_Type (2 ** Integer (J));
end if;
if Dialog_Button_Stock (J) = null then
Button := Add_Button
(Dialog,
Text => Trim (-Dialog_Button_String (J), Right),
Response_Id => Response);
else
Button := Add_Button
(Dialog,
Text => Dialog_Button_Stock (J).all,
Response_Id => Response);
end if;
if Default_Button = 2 ** Integer (J) then
Grab_Default (Button);
end if;
end if;
end loop;
Show_All (Dialog);
loop
Response := Run (Dialog);
if Response = Gtk_Response_Delete_Event then
Destroy (Dialog);
return Button_None;
elsif Response = Gtk_Response_Cancel then
Destroy (Dialog);
if (Buttons and Button_Cancel) /= 0 then
return Button_Cancel;
elsif (Buttons and Button_No) /= 0 then
return Button_No;
else
return Button_OK;
end if;
elsif Response >= 0 then
Result := Message_Dialog_Buttons (Response);
case Result is
when Button_Yes
| Button_No
| Button_All
| Button_OK
| Button_Cancel
| Button_Abort
| Button_Retry
| Button_Ignore =>
Destroy (Dialog);
return Result;
when Button_Help =>
if Help_Msg /= "" then
Result := Message_Dialog
(Help_Msg, Buttons => Button_OK, Title => -"Help");
else
Result := Message_Dialog
(-"No help available",
Buttons => Button_OK, Title => -"Help");
end if;
when others =>
null;
end case;
end if;
end loop;
end Message_Dialog;
-----------------------
-- Create_Gtk_Dialog --
-----------------------
function Create_Gtk_Dialog
(Msg : UTF8_String;
Dialog_Type : Message_Dialog_Type := Information;
Title : UTF8_String := "";
Justification : Gtk_Justification := Justify_Center;
Parent : Gtk.Window.Gtk_Window := null)
return Gtk.Dialog.Gtk_Dialog
is
Dialog : Gtk_Dialog;
Label : Gtk_Label;
Box : Gtk_Box;
Pix : Gtk_Pixmap;
Pixmap : Gdk_Pixmap;
Mask : Gdk_Pixmap;
use Gdk;
begin
Gtk_New
(Dialog,
Title => Title,
Parent => Parent,
Flags => Modal or Destroy_With_Parent);
-- Realize it so that we force the creation of its Gdk_Window.
-- This is needed below to create a pixmap.
Realize (Dialog);
case Dialog_Type is
when Warning =>
Create_From_Xpm_D
(Pixmap, Get_Window (Dialog), Mask,
Null_Color, Warning_Xpm);
if Title = "" then
Set_Title (Dialog, -"Warning");
end if;
when Error =>
Create_From_Xpm_D
(Pixmap, Get_Window (Dialog), Mask,
Null_Color, Error_Xpm);
if Title = "" then
Set_Title (Dialog, -"Error");
end if;
when Information =>
Create_From_Xpm_D
(Pixmap, Get_Window (Dialog), Mask,
Null_Color, Information_Xpm);
if Title = "" then
Set_Title (Dialog, -"Information");
end if;
when Confirmation =>
Create_From_Xpm_D
(Pixmap, Get_Window (Dialog), Mask,
Null_Color, Confirmation_Xpm);
if Title = "" then
Set_Title (Dialog, -"Confirmation");
end if;
when Custom =>
null;
end case;
Gtk_New_Hbox (Box);
Pack_Start (Get_Vbox (Dialog), Box, Padding => 10);
if Pixmap /= null then
Gtk_New (Pix, Pixmap, Mask);
Pack_Start (Box, Pix, Padding => 10);
end if;
Gtk_New (Label, Msg);
Set_Selectable (Label, True);
Set_Justify (Label, Justification);
Pack_Start (Box, Label, Padding => 10);
return Dialog;
end Create_Gtk_Dialog;
end Gtkada.Dialogs;
|