/usr/lib/perl5/Apache2/compat.pm is in libapache2-mod-perl2 2.0.8+httpd24-r1449661-6ubuntu2.1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 721 722 723 724 725 726 727 728 729 730 731 732 733 734 735 736 737 738 739 740 741 742 743 744 745 746 747 748 749 750 751 752 753 754 755 756 757 758 759 760 761 762 763 764 765 766 767 768 769 770 771 772 773 774 775 776 777 778 779 780 781 782 783 784 785 786 787 788 789 790 791 792 793 794 795 796 797 798 799 800 801 802 803 804 805 806 807 808 809 810 811 812 813 814 815 816 817 818 819 820 821 822 823 824 825 826 827 828 829 830 831 832 833 834 835 836 837 838 839 840 841 842 843 844 845 846 847 848 849 850 851 852 853 854 855 856 857 858 859 860 861 862 863 864 865 866 867 868 869 870 871 872 873 874 875 876 877 878 879 880 881 882 883 884 885 886 887 888 889 890 891 892 893 894 895 896 897 898 899 900 901 902 903 904 905 906 907 908 909 910 911 912 913 914 915 916 917 918 919 920 921 922 923 924 925 926 927 928 929 930 931 932 933 934 935 936 937 938 939 940 941 942 943 944 945 946 947 948 949 950 951 952 953 954 955 956 957 958 959 960 961 962 963 964 965 966 967 968 969 970 971 972 973 974 975 976 977 978 979 980 981 982 983 984 985 986 987 988 989 990 991 992 993 994 995 996 997 998 999 1000 1001 1002 1003 1004 1005 1006 1007 1008 1009 1010 1011 1012 1013 1014 1015 1016 1017 1018 1019 1020 1021 1022 1023 1024 1025 1026 1027 1028 1029 1030 1031 1032 1033 1034 1035 1036 1037 1038 1039 1040 1041 1042 1043 1044 1045 1046 1047 1048 1049 1050 1051 1052 1053 1054 1055 1056 1057 1058 1059 1060 1061 1062 1063 1064 1065 1066 1067 1068 1069 1070 1071 1072 1073 1074 1075 1076 | # Licensed to the Apache Software Foundation (ASF) under one or more
# contributor license agreements. See the NOTICE file distributed with
# this work for additional information regarding copyright ownership.
# The ASF licenses this file to You under the Apache License, Version 2.0
# (the "License"); you may not use this file except in compliance with
# the License. You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package Apache2::compat;
use strict;
use warnings FATAL => 'all';
no warnings 'redefine';
#1.xx compat layer
#some of this will stay as-is
#some will be implemented proper later on
#there's enough here to get simple registry scripts working
#add to startup.pl:
#use Apache2::compat ();
#use lib ...; #or something to find 1.xx Apache2::Registry
#Alias /perl /path/to/perl/scripts
#<Location /perl>
# Options +ExecCGI
# SetHandler modperl
# PerlResponseHandler Apache2::Registry
#</Location>
use Apache2::Connection ();
use Apache2::ServerRec ();
use Apache2::ServerUtil ();
use Apache2::Access ();
use Apache2::Module ();
use Apache2::RequestRec ();
use Apache2::RequestIO ();
use Apache2::RequestUtil ();
use Apache2::Response ();
use Apache2::SubRequest ();
use Apache2::Filter ();
use Apache2::Util ();
use Apache2::Log ();
use Apache2::URI ();
use APR::Date ();
use APR::Table ();
use APR::Pool ();
use APR::URI ();
use APR::Util ();
use APR::Brigade ();
use APR::Bucket ();
use mod_perl2 ();
use Symbol ();
use File::Spec ();
use APR::Const -compile => qw(FINFO_NORM);
BEGIN {
$INC{'Apache.pm'} = __FILE__;
$INC{'Apache/Constants.pm'} = __FILE__;
$INC{'Apache/File.pm'} = __FILE__;
$INC{'Apache/Table.pm'} = __FILE__;
}
($Apache::Server::Starting, $Apache::Server::ReStarting) =
Apache2::ServerUtil::restart_count() == 1 ? (1, 0) : (0, 1);
# api => "overriding code"
# the overriding code, needs to "return" the original CODE reference
# when eval'ed , so that it can be restored later
my %overridable_mp2_api = (
'Apache2::RequestRec::filename' => <<'EOI',
{
require Apache2::RequestRec;
require APR::Finfo;
my $orig_sub = *Apache2::RequestRec::filename{CODE};
*Apache2::RequestRec::filename = sub {
my ($r, $newfile) = @_;
my $old_filename;
if (defined $newfile) {
$old_filename = $r->$orig_sub($newfile);
die "'$newfile' doesn't exist" unless -e $newfile;
$r->finfo(APR::Finfo::stat($newfile, APR::Const::FINFO_NORM, $r->pool));
}
else {
$old_filename = $r->$orig_sub();
}
return $old_filename;
};
$orig_sub;
}
EOI
'Apache2::RequestRec::notes' => <<'EOI',
{
require Apache2::RequestRec;
my $orig_sub = *Apache2::RequestRec::notes{CODE};
*Apache2::RequestRec::notes = sub {
my $r = shift;
return wantarray()
? ($r->table_get_set(scalar($r->$orig_sub), @_))
: scalar($r->table_get_set(scalar($r->$orig_sub), @_));
};
$orig_sub;
}
EOI
'Apache2::RequestRec::finfo' => <<'EOI',
{
require APR::Finfo;
my $orig_sub = *APR::Finfo::finfo{CODE};
sub Apache2::RequestRec::finfo {
my $r = shift;
stat $r->filename;
\*_;
}
$orig_sub;
}
EOI
'Apache2::Connection::local_addr' => <<'EOI',
{
require Apache2::Connection;
require Socket;
require APR::SockAddr;
my $orig_sub = *Apache2::Connection::local_addr{CODE};
*Apache2::Connection::local_addr = sub {
my $c = shift;
Socket::pack_sockaddr_in($c->$orig_sub->port,
Socket::inet_aton($c->$orig_sub->ip_get));
};
$orig_sub;
}
EOI
'Apache2::Connection::remote_addr' => <<'EOI',
{
require Apache2::Connection;
require APR::SockAddr;
require Socket;
my $orig_sub = *Apache2::Connection::client_addr{CODE};
*Apache2::Connection::remote_addr = sub {
my $c = shift;
if (@_) {
my $addr_in = shift;
my ($port, $addr) = Socket::unpack_sockaddr_in($addr_in);
$c->$orig_sub->ip_set($addr);
$c->$orig_sub->port_set($port);
}
else {
Socket::pack_sockaddr_in($c->$orig_sub->port,
Socket::inet_aton($c->$orig_sub->ip_get));
}
};
$orig_sub;
}
EOI
'Apache2::Module::top_module' => <<'EOI',
{
require Apache2::Module;
my $orig_sub = *Apache2::Module::top_module{CODE};
*Apache2::Module::top_module = sub {
shift;
$orig_sub->(@_);
};
$orig_sub;
}
EOI
'Apache2::Module::get_config' => <<'EOI',
{
require Apache2::Module;
my $orig_sub = *Apache2::Module::get_config{CODE};
*Apache2::Module::get_config = sub {
shift;
$orig_sub->(@_);
};
$orig_sub;
}
EOI
'APR::URI::unparse' => <<'EOI',
{
require APR::URI;
my $orig_sub = *APR::URI::unparse{CODE};
*APR::URI::unparse = sub {
my ($uri, $flags) = @_;
if (defined $uri->hostname && !defined $uri->scheme) {
# we do this only for back compat, the new APR::URI is
# protocol-agnostic and doesn't fallback to 'http' when the
# scheme is not provided
$uri->scheme('http');
}
$orig_sub->(@_);
};
$orig_sub;
}
EOI
'Apache2::Util::ht_time' => <<'EOI',
{
require Apache2::Util;
my $orig_sub = *Apache2::Util::ht_time{CODE};
*Apache2::Util::ht_time = sub {
my $r = Apache2::compat::request('Apache2::Util::ht_time');
return $orig_sub->($r->pool, @_);
};
$orig_sub;
}
EOI
);
my %overridden_mp2_api = ();
# this function enables back-compatible APIs which can't coexist with
# mod_perl 2.0 APIs with the same name and therefore it should be
# avoided if possible.
#
# it expects a list of fully qualified functions, like
# "Apache2::RequestRec::finfo"
sub override_mp2_api {
my (@subs) = @_;
for my $sub (@subs) {
unless (exists $overridable_mp2_api{$sub}) {
die __PACKAGE__ . ": $sub is not overridable";
}
if (exists $overridden_mp2_api{$sub}) {
warn __PACKAGE__ . ": $sub has been already overridden";
next;
}
$overridden_mp2_api{$sub} = eval $overridable_mp2_api{$sub};
unless (exists $overridden_mp2_api{$sub} &&
ref($overridden_mp2_api{$sub}) eq 'CODE') {
die "overriding $sub didn't return a CODE ref";
}
}
}
# restore_mp2_api does the opposite of override_mp2_api(), it removes
# the overridden API and restores the original mod_perl 2.0 API
sub restore_mp2_api {
my (@subs) = @_;
for my $sub (@subs) {
unless (exists $overridable_mp2_api{$sub}) {
die __PACKAGE__ . ": $sub is not overridable";
}
unless (exists $overridden_mp2_api{$sub}) {
warn __PACKAGE__ . ": can't restore $sub, " .
"as it has not been overridden";
next;
}
# XXX: 5.8.2+ can't delete and assign at once - gives:
# Attempt to free unreferenced scalar
# after perl_clone. the 2 step works ok. to reproduce:
# t/TEST -maxclients 1 perl/ithreads2.t compat/request.t
my $original_sub = $overridden_mp2_api{$sub};
delete $overridden_mp2_api{$sub};
no warnings 'redefine';
no strict 'refs';
*$sub = $original_sub;
}
}
sub request {
my $what = shift;
my $r = Apache2::RequestUtil->request;
unless ($r) {
die "cannot use $what ",
"without 'SetHandler perl-script' ",
"or 'PerlOptions +GlobalRequest'";
}
$r;
}
{
my $orig_sub = *Apache2::Module::top_module{CODE};
*Apache2::Module::top_module = sub {
$orig_sub->();
};
}
{
my $orig_sub = *Apache2::Module::get_config{CODE};
*Apache2::Module::get_config = sub {
shift if $_[0] eq 'Apache2::Module';
$orig_sub->(@_);
};
}
package Apache::Server;
# XXX: is that good enough? see modperl/src/modules/perl/mod_perl.c:367
our $CWD = Apache2::ServerUtil::server_root();
our $AddPerlVersion = 1;
sub warn {
shift if @_ and $_[0] eq 'Apache::Server';
Apache2::ServerRec::warn(@_);
}
package Apache;
sub request {
return Apache2::compat::request(@_);
}
sub unescape_url_info {
my ($class, $string) = @_;
Apache2::URI::unescape_url($string);
$string =~ tr/+/ /;
$string;
}
#sorry, have to use $r->Apache2::args at the moment
#for list context splitting
sub args {
my $r = shift;
my $args = $r->args;
return $args unless wantarray;
return $r->parse_args($args);
}
sub server_root_relative {
my $class = shift;
if (@_ && defined($_[0]) && File::Spec->file_name_is_absolute($_[0])) {
return File::Spec->catfile(@_);
}
else {
File::Spec->catfile(Apache2::ServerUtil::server_root(), @_);
}
}
sub exit {
require ModPerl::Util;
my $status = 0;
my $nargs = @_;
if ($nargs == 2) {
$status = $_[1];
}
elsif ($nargs == 1 and $_[0] =~ /^\d+$/) {
$status = $_[0];
}
ModPerl::Util::exit($status);
}
#XXX: warn
sub import {
}
sub untaint {
shift;
require ModPerl::Util;
ModPerl::Util::untaint(@_);
}
sub module {
require Apache2::Module;
die 'Usage: Apache2->module($name)' if @_ != 2;
return Apache2::Module::loaded($_[1]);
}
sub gensym {
return Symbol::gensym();
}
sub define {
shift if @_ == 2;
Apache2::ServerUtil::exists_config_define(@_);
}
sub log_error {
Apache2::ServerUtil->server->log_error(@_);
}
sub warn {
shift if @_ and $_[0] eq 'Apache';
Apache2::ServerRec::warn(@_);
}
sub httpd_conf {
shift;
my $obj;
eval { $obj = Apache2::RequestUtil->request };
$obj = Apache2::ServerUtil->server if $@;
my $err = $obj->add_config([split /\n/, join '', @_]);
die $err if $err;
}
# mp2 always can stack handlers
sub can_stack_handlers { 1; }
sub push_handlers {
shift;
Apache2::ServerUtil->server->push_handlers(@_);
}
sub set_handlers {
shift;
Apache2::ServerUtil->server->set_handlers(@_);
}
sub get_handlers {
shift;
Apache2::ServerUtil->server->get_handlers(@_);
}
package Apache::Constants;
use Apache2::Const ();
sub import {
my $class = shift;
my $package = scalar caller;
my @args = @_;
# treat :response as :common - it's not perfect
# but simple and close enough for the majority
my %args = map { s/^:response$/:common/; $_ => 1 } @args;
Apache2::Const->compile($package => keys %args);
}
#no need to support in 2.0
sub export {}
sub SERVER_VERSION { Apache2::ServerUtil::get_server_version() }
package Apache2::RequestRec;
use Apache2::Const -compile => qw(REMOTE_NAME);
#no longer exist in 2.0
sub soft_timeout {}
sub hard_timeout {}
sub kill_timeout {}
sub reset_timeout {}
# this function is from mp1's Apache2::SubProcess 3rd party module
# which is now a part of mp2 API. this function doesn't exist in 2.0.
sub cleanup_for_exec {}
sub current_callback {
require ModPerl::Util;
return ModPerl::Util::current_callback();
}
sub send_http_header {
my ($r, $type) = @_;
# since send_http_header() in mp1 was telling mod_perl not to
# parse headers and in mp2 one must call $r->content_type($type) to
# perform the same, we make sure that this happens
$type = $r->content_type || 'text/html' unless defined $type;
$r->content_type($type);
}
#we support Apache2::RequestUtil->request; this is needed to support $r->request
#XXX: seems sorta backwards
*request = \&Apache2::request;
sub table_get_set {
my ($r, $table) = (shift, shift);
my ($key, $value) = @_;
if (1 == @_) {
return wantarray()
? ($table->get($key))
: scalar($table->get($key));
}
elsif (2 == @_) {
if (defined $value) {
return wantarray()
? ($table->set($key, $value))
: scalar($table->set($key, $value));
}
else {
return wantarray()
? ($table->unset($key))
: scalar($table->unset($key));
}
}
elsif (0 == @_) {
return $table;
}
else {
my $name = (caller(1))[3];
$r->warn("Usage: \$r->$name([key [,val]])");
}
}
sub header_out {
my $r = shift;
return wantarray()
? ($r->table_get_set(scalar($r->headers_out), @_))
: scalar($r->table_get_set(scalar($r->headers_out), @_));
}
sub header_in {
my $r = shift;
return wantarray()
? ($r->table_get_set(scalar($r->headers_in), @_))
: scalar($r->table_get_set(scalar($r->headers_in), @_));
}
sub err_header_out {
my $r = shift;
return wantarray()
? ($r->table_get_set(scalar($r->err_headers_out), @_))
: scalar($r->table_get_set(scalar($r->err_headers_out), @_));
}
sub register_cleanup {
shift->pool->cleanup_register(@_);
}
*post_connection = \®ister_cleanup;
sub get_remote_host {
my ($r, $type) = @_;
$type = Apache2::Const::REMOTE_NAME unless defined $type;
$r->connection->get_remote_host($type, $r->per_dir_config);
}
sub parse_args {
my ($r, $string) = @_;
return () unless defined $string and $string;
return map {
tr/+/ /;
s/%([0-9a-fA-F]{2})/pack("C",hex($1))/ge;
$_;
} split /[=&;]/, $string, -1;
}
use Apache2::Const -compile => qw(MODE_READBYTES);
use APR::Const -compile => qw(SUCCESS BLOCK_READ);
use constant IOBUFSIZE => 8192;
sub content {
my $r = shift;
my $bb = APR::Brigade->new($r->pool,
$r->connection->bucket_alloc);
my $data = '';
my $seen_eos = 0;
do {
$r->input_filters->get_brigade($bb, Apache2::Const::MODE_READBYTES,
APR::Const::BLOCK_READ, IOBUFSIZE);
while (!$bb->is_empty) {
my $b = $bb->first;
if ($b->is_eos) {
$seen_eos++;
last;
}
if ($b->read(my $buf)) {
$data .= $buf;
}
$b->delete;
}
} while (!$seen_eos);
$bb->destroy;
return $data unless wantarray;
return $r->parse_args($data);
}
sub server_root_relative {
my $r = shift;
File::Spec->catfile(Apache2::ServerUtil::server_root(), @_);
}
sub clear_rgy_endav {
my ($r, $script_name) = @_;
require ModPerl::Global;
my $package = 'Apache2::ROOT' . $script_name;
ModPerl::Global::special_list_clear(END => $package);
}
sub stash_rgy_endav {
#see run_rgy_endav
}
#if somebody really wants to have END subroutine support
#with the 1.x Apache2::Registry they will need to configure:
# PerlHandler Apache2::Registry Apache2::compat::run_rgy_endav
sub Apache2::compat::run_rgy_endav {
my $r = shift;
require ModPerl::Global;
require Apache2::PerlRun; #1.x's
my $package = Apache2::PerlRun->new($r)->namespace;
ModPerl::Global::special_list_call(END => $package);
}
sub seqno {
1;
}
sub chdir_file {
#XXX resolve '.' in @INC to basename $r->filename
}
#XXX: would like to have a proper implementation
#that reads line-by-line as defined by $/
#the best way will probably be to use perlio in 5.8.0
#anything else would be more effort than it is worth
sub READLINE {
my $r = shift;
my $line;
$r->read($line, $r->headers_in->get('Content-length'));
$line ? $line : undef;
}
#XXX: howto convert PerlIO to apr_file_t
#so we can use the real ap_send_fd function
#2.0 ap_send_fd() also has an additional offset parameter
sub send_fd_length {
my ($r, $fh, $length) = @_;
my $buff;
my $total_bytes_sent = 0;
my $len;
return 0 if $length == 0;
if (($length > 0) && ($total_bytes_sent + IOBUFSIZE) > $length) {
$len = $length - $total_bytes_sent;
}
else {
$len = IOBUFSIZE;
}
binmode $fh;
while (CORE::read($fh, $buff, $len)) {
$total_bytes_sent += $r->puts($buff);
}
$total_bytes_sent;
}
sub send_fd {
my ($r, $fh) = @_;
$r->send_fd_length($fh, -1);
}
sub is_main { !shift->main }
# really old back-compat methods, they shouldn't be used in mp1
*cgi_var = *cgi_env = \&Apache2::RequestRec::subprocess_env;
package Apache::File;
use Fcntl ();
use Symbol ();
use Carp ();
sub new {
my ($class) = shift;
my $fh = Symbol::gensym;
my $self = bless $fh, ref($class)||$class;
if (@_) {
return $self->open(@_) ? $self : undef;
}
else {
return $self;
}
}
sub open {
my ($self) = shift;
Carp::croak("no Apache2::File object passed")
unless $self && ref($self);
# cannot forward @_ to open() because of its prototype
if (@_ > 1) {
my ($mode, $file) = @_;
CORE::open $self, $mode, $file;
}
else {
my $file = shift;
CORE::open $self, $file;
}
}
sub close {
my ($self) = shift;
CORE::close $self;
}
my $TMPNAM = 'aaaaaa';
my $TMPDIR = $ENV{'TMPDIR'} || $ENV{'TEMP'} || '/tmp';
($TMPDIR) = $TMPDIR =~ /^([^<>|;*]+)$/; #untaint
my $Mode = Fcntl::O_RDWR()|Fcntl::O_EXCL()|Fcntl::O_CREAT();
my $Perms = 0600;
sub tmpfile {
my $class = shift;
my $limit = 100;
my $r = Apache2::compat::request('Apache::File->tmpfile');
while ($limit--) {
my $tmpfile = "$TMPDIR/${$}" . $TMPNAM++;
my $fh = $class->new;
sysopen $fh, $tmpfile, $Mode, $Perms
or die "failed to open $tmpfile: $!";
$r->pool->cleanup_register(sub { unlink $tmpfile });
if ($fh) {
return wantarray ? ($tmpfile, $fh) : $fh;
}
}
}
# the following functions now live in Apache2::RequestIO
# * discard_request_body
# the following functions now live in Apache2::Response
# * meets_conditions
# * set_content_length
# * set_etag
# * set_last_modified
# * update_mtime
# the following functions now live in Apache2::RequestRec
# * mtime
package Apache::Util;
sub size_string {
my ($size) = @_;
if (!$size) {
$size = " 0k";
}
elsif ($size == -1) {
$size = " -";
}
elsif ($size < 1024) {
$size = " 1k";
}
elsif ($size < 1048576) {
$size = sprintf "%4dk", ($size + 512) / 1024;
}
elsif ($size < 103809024) {
$size = sprintf "%4.1fM", $size / 1048576.0;
}
else {
$size = sprintf "%4dM", ($size + 524288) / 1048576;
}
return $size;
}
*unescape_uri = \&Apache2::URI::unescape_url;
*escape_path = \&Apache2::Util::escape_path;
sub escape_uri {
my $path = shift;
my $r = Apache2::compat::request('Apache2::Util::escape_uri');
Apache2::Util::escape_path($path, $r->pool);
}
#tmp compat until ap_escape_html is reworked to not require a pool
my %html_escapes = (
'<' => 'lt',
'>' => 'gt',
'&' => 'amp',
'"' => 'quot',
);
%html_escapes = map { $_, "&$html_escapes{$_};" } keys %html_escapes;
my $html_escape = join '|', keys %html_escapes;
sub escape_html {
my $html = shift;
$html =~ s/($html_escape)/$html_escapes{$1}/go;
$html;
}
*parsedate = \&APR::Date::parse_http;
*validate_password = \&APR::Util::password_validate;
sub Apache2::URI::parse {
my ($class, $r, $uri) = @_;
$uri ||= $r->construct_url;
APR::URI->parse($r->pool, $uri);
}
package Apache::Table;
sub new {
my ($class, $r, $nelts) = @_;
$nelts ||= 10;
APR::Table::make($r->pool, $nelts);
}
package Apache::SIG;
use Apache2::Const -compile => 'DECLINED';
sub handler {
# don't set the SIGPIPE
return Apache2::Const::DECLINED;
}
package Apache2::Connection;
# auth_type and user records don't exist in 2.0 conn_rec struct
# 'PerlOptions +GlobalRequest' is required
sub auth_type { shift; Apache2::RequestUtil->request->ap_auth_type(@_) }
sub user { shift; Apache2::RequestUtil->request->user(@_) }
1;
__END__
=head1 NAME
Apache2::compat -- 1.0 backward compatibility functions deprecated in 2.0
=head1 Synopsis
# either add at the very beginning of startup.pl
use Apache2::compat;
# or httpd.conf
PerlModule Apache2::compat
# override and restore compat functions colliding with mp2 API
Apache2::compat::override_mp2_api('Apache2::Connection::local_addr');
my ($local_port, $local_addr) = sockaddr_in($c->local_addr);
Apache2::compat::restore_mp2_api('Apache2::Connection::local_addr');
=head1 Description
C<Apache2::compat> provides mod_perl 1.0 compatibility layer and can be
used to smooth the transition process to mod_perl 2.0.
It includes functions that have changed their API or were removed in
mod_perl 2.0. If your code uses any of those functions, you should
load this module at the server startup, and everything should work as
it did in 1.0. If it doesn't please L<report the
bug|docs::2.0::user::help::help/Reporting_Problems>, but before you
do that please make sure that your code does work properly under
mod_perl 1.0.
However, remember, that it's implemented in pure Perl and not C,
therefore its functionality is not optimized and it's the best to try
to L<port your
code|docs::2.0::user::porting::porting> not to use deprecated
functions and stop using the compatibility layer.
=head1 Compatibility Functions Colliding with mod_perl 2.0 API
Most of the functions provided by Apache2::compat don't interfere with
mod_perl 2.0 API. However there are several functions which have the
same name in the mod_perl 1.0 and mod_perl 2.0 API, accept the same
number of arguments, but either the arguments themselves aren't the
same or the return values are different. For example the mod_perl 1.0
code:
require Socket;
my $sockaddr_in = $c->local_addr;
my ($local_port, $local_addr) = Socket::sockaddr_in($sockaddr_in);
should be adjusted to be:
require Apache2::Connection;
require APR::SockAddr;
my $sockaddr = $c->local_addr;
my ($local_port, $local_addr) = ($sockaddr->port, $sockaddr->ip_get);
to work under mod_perl 2.0.
As you can see in mod_perl 1.0 API local_addr() was returning a
SOCKADDR_IN object (see the Socket perl manpage), in mod_perl 2.0 API
it returns an C<L<APR::SockAddr|docs::2.0::api::APR::SockAddr>>
object, which is a totally different beast. If Apache2::compat
overrides the function C<local_addr()> to be back-compatible with
mod_perl 1.0 API. Any code that relies on this function to work as it
should under mod_perl 2.0 will be broken. Therefore the solution is
not to override C<local_addr()> by default. Instead a special API is
provided which overrides colliding functions only when needed and
which can be restored when no longer needed. So for example if you
have code from mod_perl 1.0:
my ($local_port, $local_addr) = Socket::sockaddr_in($c->local_addr);
and you aren't ready to port it to to use the mp2 API:
my ($local_port, $local_addr) = ($c->local_addr->port,
$c->local_addr->ip_get);
you could do the following:
Apache2::compat::override_mp2_api('Apache2::Connection::local_addr');
my ($local_port, $local_addr) = Socket::sockaddr_in($c->local_addr);
Apache2::compat::restore_mp2_api('Apache2::Connection::local_addr');
Notice that you need to restore the API as soon as possible.
Both C<override_mp2_api()> and C<restore_mp2_api()> accept a list of
functions to operate on.
=head2 Available Overridable Functions
At the moment the following colliding functions are available for
overriding:
=over
=item Apache2::RequestRec::notes
=item Apache2::RequestRec::filename
=item Apache2::RequestRec::finfo
=item Apache2::Connection::local_addr
=item Apache2::Connection::remote_addr
=item Apache2::Util::ht_time
=item Apache2::Module::top_module
=item Apache2::Module::get_config
=item APR::URI::unparse
=back
=head1 Use in CPAN Modules
The short answer: B<Do not use> C<Apache2::compat> in CPAN modules.
The long answer:
C<Apache2::compat> is useful during the mod_perl 1.0 code
porting. Though remember that it's implemented in pure Perl. In
certain cases it overrides mod_perl 2.0 methods, because their API is
very different and doesn't map 1:1 to mod_perl 1.0. So if anything,
not under user's control, loads C<Apache2::compat> user's code is
forced to use the potentially slower method. Which is quite bad.
Some users may choose to keep using C<Apache2::compat> in production
and it may perform just fine. Other users will choose not to use that
module, by porting their code to use mod_perl 2.0 API. However it
should be users' choice whether to load this module or not and not to
be enforced by CPAN modules.
If you port your CPAN modules to work with mod_perl 2.0, you should
follow the porting L<Perl|docs::2.0::user::porting::porting> and
L<XS|docs::2.0::devel::porting::porting> module guidelines.
Users that are stuck with CPAN modules preloading C<Apache2::compat>,
can prevent this from happening by adding
$INC{'Apache2/compat.pm'} = __FILE__;
at the very beginning of their I<startup.pl>. But this will most
certainly break the module that needed this module.
=head1 API
You should be reading the mod_perl 1.0 L<API
docs|docs::1.0::api::index> for usage of the methods and functions
in this package, since what this module is doing is providing a
backwards compatibility and it makes no sense to duplicate
documentation.
Another important document to read is: L<Migrating from mod_perl 1.0
to mod_perl 2.0|docs::2.0::user::porting::compat> which covers all
mod_perl 1.0 constants, functions and methods that have changed in
mod_perl 2.0.
=head1 See Also
L<mod_perl 2.0 documentation|docs::2.0::index>.
=head1 Copyright
mod_perl 2.0 and its core modules are copyrighted under
The Apache Software License, Version 2.0.
=head1 Authors
L<The mod_perl development team and numerous
contributors|about::contributors::people>.
=cut
|