/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/Themes/Ambiance/CheckBoxStyle.qml is in ubuntu-ui-toolkit-theme 0.1.46+14.04.20140408.1-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 | /*
* Copyright 2013 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.0
import Ubuntu.Components 0.1
Item {
id: checkBoxStyle
/*!
The image to show inside the checkbox when it is checked.
*/
property url tickSource: "artwork/tick.png"
opacity: enabled ? 1.0 : 0.5
implicitWidth: units.gu(4.25)
implicitHeight: units.gu(4)
UbuntuShape {
id: background
anchors.fill: parent
anchors.margins: units.gu(0.5)
}
Image {
id: tick
anchors.centerIn: parent
smooth: true
source: tickSource
visible: styledItem.checked || transitionToChecked.running || transitionToUnchecked.running
}
state: styledItem.checked ? "checked" : "unchecked"
states: [
State {
name: "checked"
PropertyChanges {
target: tick
anchors.verticalCenterOffset: 0
}
PropertyChanges {
target: background
color: Theme.palette.selected.foreground
}
},
State {
name: "unchecked"
PropertyChanges {
target: tick
anchors.verticalCenterOffset: checkBoxStyle.height
}
PropertyChanges {
target: background
color: Theme.palette.normal.foreground
}
}
]
transitions: [
Transition {
id: transitionToUnchecked
to: "unchecked"
ColorAnimation {
target: background
duration: UbuntuAnimation.BriskDuration
easing: UbuntuAnimation.StandardEasingReverse
}
SequentialAnimation {
PropertyAction {
target: checkBoxStyle
property: "clip"
value: true
}
NumberAnimation {
target: tick
property: "anchors.verticalCenterOffset"
duration: UbuntuAnimation.BriskDuration
easing: UbuntuAnimation.StandardEasingReverse
}
PropertyAction {
target: checkBoxStyle
property: "clip"
value: false
}
}
},
Transition {
id: transitionToChecked
to: "checked"
ColorAnimation {
target: background
duration: UbuntuAnimation.BriskDuration
easing: UbuntuAnimation.StandardEasing
}
SequentialAnimation {
PropertyAction {
target: checkBoxStyle
property: "clip"
value: true
}
NumberAnimation {
target: tick
property: "anchors.verticalCenterOffset"
duration: UbuntuAnimation.BriskDuration
easing: UbuntuAnimation.StandardEasing
}
PropertyAction {
target: checkBoxStyle
property: "clip"
value: false
}
}
}
]
}
|