/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/Themes/Ambiance/SwitchStyle.qml is in ubuntu-ui-toolkit-theme 0.1.46+14.04.20140408.1-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 | /*
* Copyright 2013 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.0
import Ubuntu.Components 0.1
Item {
id: switchStyle
property real thumbPadding: units.gu(0.5)
/* FIXME: setting the width and height is required because in the case no width
is set on the Switch, then even though the width is set eventually to
implicitWidth, it still goes through the value 0.0 which triggers an
undesired animation if the Switch is checked.
Example, values of width at instantiation:
width = 0.0 (before SwitchStyle is loaded)
width = implicitWidth (after SwitchStyle is loaded)
*/
width: implicitWidth
height: implicitHeight
implicitWidth: units.gu(8)
implicitHeight: units.gu(4)
opacity: styledItem.enabled ? 1.0 : 0.5
LayoutMirroring.enabled: false
LayoutMirroring.childrenInherit: true
UbuntuShape {
id: background
anchors.fill: parent
color: Theme.palette.normal.base
clip: true
UbuntuShape {
id: thumb
width: (background.width - switchStyle.thumbPadding * 3.0) / 2.0
x: styledItem.checked ? rightThumbPosition.x : leftThumbPosition.x
anchors {
top: parent.top
bottom: parent.bottom
topMargin: switchStyle.thumbPadding
bottomMargin: switchStyle.thumbPadding
}
color: styledItem.checked ? Theme.palette.selected.foreground
: Theme.palette.normal.foreground
Behavior on x {
UbuntuNumberAnimation {
duration: UbuntuAnimation.BriskDuration
easing: UbuntuAnimation.StandardEasing
}
}
Behavior on color {
ColorAnimation {
duration: UbuntuAnimation.BriskDuration
easing: UbuntuAnimation.StandardEasing
}
}
PartialColorize {
anchors {
verticalCenter: parent.verticalCenter
right: parent.left
rightMargin: switchStyle.thumbPadding * 3.0
}
rightColor: Theme.palette.normal.backgroundText
source: Image {
source: "artwork/cross.png"
}
}
PartialColorize {
anchors {
verticalCenter: parent.verticalCenter
left: parent.right
leftMargin: switchStyle.thumbPadding * 2.0
}
rightColor: Theme.palette.normal.backgroundText
source: Image {
source: "artwork/tick.png"
}
}
}
Item {
id: leftThumbPosition
anchors {
left: parent.left
top: parent.top
leftMargin: switchStyle.thumbPadding
topMargin: switchStyle.thumbPadding
}
height: thumb.height
width: thumb.width
PartialColorize {
anchors.centerIn: parent
source: Image {
source: "artwork/cross.png"
}
progress: MathUtils.clamp((thumb.x - parent.x - x) / width, 0.0, 1.0)
leftColor: "transparent"
rightColor: Theme.palette.selected.foregroundText
}
}
Item {
id: rightThumbPosition
anchors {
right: parent.right
top: parent.top
rightMargin: switchStyle.thumbPadding
topMargin: switchStyle.thumbPadding
}
height: thumb.height
width: thumb.width
PartialColorize {
anchors.centerIn: parent
source: Image {
source: "artwork/tick.png"
}
progress: MathUtils.clamp((thumb.x + thumb.width - parent.x - x) / width, 0.0, 1.0)
leftColor: Theme.palette.selected.foregroundText
rightColor: "transparent"
}
}
}
}
|