hobbit-plugins 20131022 / etc / xymon / misc.d / zombies

#!/usr/bin/perl -w

use strict;
use File::Basename qw(dirname);

# Function to parse config file; splits at first blanks.
sub file_to_hash_of_regexp_keys_and_values($) {
    my %regexps = ();
    my $filename = shift;
    open(my $fh, '<', $filename) or return %regexps;
    while(<$fh>) {
        unless (/^#|^\s*$/) {
            chomp;
            my ($key, $value) = split(/\s+/, $_, 2);
            $regexps{$key} = $value;
        }
    }
    return %regexps;
}

my $ext_apt_config = dirname($0).'/..';
my $ignore_file = $ext_apt_config."/zombies_ignore";
my %ignore = file_to_hash_of_regexp_keys_and_values($ignore_file);

chdir ("/proc");

my $zombies = 0;

foreach my $pid (glob ("[1-9]*")) {
	open(F, '<', "$pid/status") or next;
	my $maybe_zombie = 0;
	while (<F>) {
		if (/^State:\s+Z/) {
			my $mtime = (stat ($pid))[9];
			# Don't report zombies which are younger than 1 minute
			last if not defined $mtime or time - $mtime < 60;
			$maybe_zombie++;
			last;
		}
	}
	close F;
	next unless $maybe_zombie;

	# Check after 1 second if the process in question is still a
	# zombie. Only report if that's the case.
	sleep 1;

	my $ignored = undef;
	my $userignored = undef;
	my $name = '';
	open(F, '<', "$pid/status") or next;
	my $zombie = 0;
	while (<F>) {
		if (/^Name:\s+(.*?)$/) {
			$name = $1;
			foreach my $regexp (keys %ignore) {
				next if $regexp =~ /:\^/;
				if ($name =~ /^$regexp$/) {
					$ignored = $ignore{$regexp};
				}
			}
		}
		if (/^State:\s+Z/) {
			my $mtime = (stat ($pid))[9];
			last if not defined $mtime or time - $mtime < 60;
			$zombie = 1;
		}
		if (/^Uid:\s+(\d+)\s/) {
			my $username = getpwuid($1);
			foreach my $regexp (keys %ignore) {
				next unless $regexp =~ /:\^/;
				my ($user_re, $process_re) = split(/:\^/, $regexp, 2);
				if ($username =~ /^$user_re$/ and
				    $name =~ /^$process_re$/) {
					$userignored = "$username: $ignore{$regexp}";
				}
			}
			last;
		}
	}
	close F;
	if ($zombie) {
	    system "ps u $pid";
	    if ($ignored) {
		print "($name zombies ignored: $ignored)\n";
	    } elsif ($userignored) {
		print "($name zombies ignored under user $userignored)\n";
	    } else {
		$zombies++;
	    }
	}
}

if ($zombies) {
	exit 1;
} else {
	print "No zombie processes\n";
	exit 0;
}