/usr/share/perl5/Excel/Writer/XLSX/Package/XMLwriter.pm is in libexcel-writer-xlsx-perl 0.76-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 | package Excel::Writer::XLSX::Package::XMLwriter;
###############################################################################
#
# XMLwriter - A base class for the Excel::Writer::XLSX writer classes.
#
# Used in conjunction with Excel::Writer::XLSX
#
# Copyright 2000-2013, John McNamara, jmcnamara@cpan.org
#
# Documentation after __END__
#
# perltidy with the following options: -mbl=2 -pt=0 -nola
use 5.008002;
use strict;
use warnings;
use Exporter;
use Carp;
use IO::File;
our @ISA = qw(Exporter);
our $VERSION = '0.76';
#
# NOTE: this module is a light weight re-implementation of XML::Writer. See
# the Pod docs below for a full explanation. The methods are implemented
# for speed rather than readability since they are used heavily in tight
# loops by Excel::Writer::XLSX.
#
# Note "local $\ = undef" protect print statements from -l on commandline.
###############################################################################
#
# new()
#
# Constructor.
#
sub new {
my $class = shift;
# FH may be undef and set later in _set_xml_writer(), see below.
my $fh = shift;
my $self = { _fh => $fh };
bless $self, $class;
return $self;
}
###############################################################################
#
# _set_xml_writer()
#
# Set the XML writer filehandle for the object. This can either be done
# in the constructor (usually for testing since the file name isn't generally
# known at that stage) or later via this method.
#
sub _set_xml_writer {
my $self = shift;
my $filename = shift;
my $fh = IO::File->new( $filename, 'w' );
croak "Couldn't open file $filename for writing.\n" unless $fh;
binmode $fh, ':utf8';
$self->{_fh} = $fh;
}
###############################################################################
#
# xml_declaration()
#
# Write the XML declaration.
#
sub xml_declaration {
my $self = shift;
local $\ = undef;
print { $self->{_fh} }
qq(<?xml version="1.0" encoding="UTF-8" standalone="yes"?>\n);
}
###############################################################################
#
# xml_start_tag()
#
# Write an XML start tag with optional attributes.
#
sub xml_start_tag {
my $self = shift;
my $tag = shift;
while ( @_ ) {
my $key = shift @_;
my $value = shift @_;
$value = _escape_attributes( $value );
$tag .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<$tag>";
}
###############################################################################
#
# xml_start_tag_unencoded()
#
# Write an XML start tag with optional, unencoded, attributes.
# This is a minor speed optimisation for elements that don't need encoding.
#
sub xml_start_tag_unencoded {
my $self = shift;
my $tag = shift;
while ( @_ ) {
my $key = shift @_;
my $value = shift @_;
$tag .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<$tag>";
}
###############################################################################
#
# xml_end_tag()
#
# Write an XML end tag.
#
sub xml_end_tag {
my $self = shift;
my $tag = shift;
local $\ = undef;
print { $self->{_fh} } "</$tag>";
}
###############################################################################
#
# xml_empty_tag()
#
# Write an empty XML tag with optional attributes.
#
sub xml_empty_tag {
my $self = shift;
my $tag = shift;
while ( @_ ) {
my $key = shift @_;
my $value = shift @_;
$value = _escape_attributes( $value );
$tag .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<$tag/>";
}
###############################################################################
#
# xml_empty_tag_unencoded()
#
# Write an empty XML tag with optional, unencoded, attributes.
# This is a minor speed optimisation for elements that don't need encoding.
#
sub xml_empty_tag_unencoded {
my $self = shift;
my $tag = shift;
while ( @_ ) {
my $key = shift @_;
my $value = shift @_;
$tag .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<$tag/>";
}
###############################################################################
#
# xml_data_element()
#
# Write an XML element containing data with optional attributes.
# XML characters in the data are encoded.
#
sub xml_data_element {
my $self = shift;
my $tag = shift;
my $data = shift;
my $end_tag = $tag;
while ( @_ ) {
my $key = shift @_;
my $value = shift @_;
$value = _escape_attributes( $value );
$tag .= qq( $key="$value");
}
$data = _escape_data( $data );
local $\ = undef;
print { $self->{_fh} } "<$tag>$data</$end_tag>";
}
###############################################################################
#
# xml_data_element_unencoded()
#
# Write an XML unencoded element containing data with optional attributes.
# This is a minor speed optimisation for elements that don't need encoding.
#
sub xml_data_element_unencoded {
my $self = shift;
my $tag = shift;
my $data = shift;
my $end_tag = $tag;
while ( @_ ) {
my $key = shift @_;
my $value = shift @_;
$tag .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<$tag>$data</$end_tag>";
}
###############################################################################
#
# xml_string_element()
#
# Optimised tag writer for <c> cell string elements in the inner loop.
#
sub xml_string_element {
my $self = shift;
my $index = shift;
my $attr = '';
while ( @_ ) {
my $key = shift;
my $value = shift;
$attr .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<c$attr t=\"s\"><v>$index</v></c>";
}
###############################################################################
#
# xml_si_element()
#
# Optimised tag writer for shared strings <si> elements.
#
sub xml_si_element {
my $self = shift;
my $string = shift;
my $attr = '';
while ( @_ ) {
my $key = shift;
my $value = shift;
$attr .= qq( $key="$value");
}
$string = _escape_data( $string );
local $\ = undef;
print { $self->{_fh} } "<si><t$attr>$string</t></si>";
}
###############################################################################
#
# xml_rich_si_element()
#
# Optimised tag writer for shared strings <si> rich string elements.
#
sub xml_rich_si_element {
my $self = shift;
my $string = shift;
local $\ = undef;
print { $self->{_fh} } "<si>$string</si>";
}
###############################################################################
#
# xml_number_element()
#
# Optimised tag writer for <c> cell number elements in the inner loop.
#
sub xml_number_element {
my $self = shift;
my $number = shift;
my $attr = '';
while ( @_ ) {
my $key = shift;
my $value = shift;
$attr .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<c$attr><v>$number</v></c>";
}
###############################################################################
#
# xml_formula_element()
#
# Optimised tag writer for <c> cell formula elements in the inner loop.
#
sub xml_formula_element {
my $self = shift;
my $formula = shift;
my $result = shift;
my $attr = '';
while ( @_ ) {
my $key = shift;
my $value = shift;
$attr .= qq( $key="$value");
}
$formula = _escape_data( $formula );
local $\ = undef;
print { $self->{_fh} } "<c$attr><f>$formula</f><v>$result</v></c>";
}
###############################################################################
#
# xml_inline_string()
#
# Optimised tag writer for inlineStr cell elements in the inner loop.
#
sub xml_inline_string {
my $self = shift;
my $string = shift;
my $preserve = shift;
my $attr = '';
my $t_attr = '';
# Set the <t> attribute to preserve whitespace.
$t_attr = ' xml:space="preserve"' if $preserve;
while ( @_ ) {
my $key = shift;
my $value = shift;
$attr .= qq( $key="$value");
}
$string = _escape_data( $string );
local $\ = undef;
print { $self->{_fh} }
"<c$attr t=\"inlineStr\"><is><t$t_attr>$string</t></is></c>";
}
###############################################################################
#
# xml_rich_inline_string()
#
# Optimised tag writer for rich inlineStr cell elements in the inner loop.
#
sub xml_rich_inline_string {
my $self = shift;
my $string = shift;
my $attr = '';
while ( @_ ) {
my $key = shift;
my $value = shift;
$attr .= qq( $key="$value");
}
local $\ = undef;
print { $self->{_fh} } "<c$attr t=\"inlineStr\"><is>$string</is></c>";
}
###############################################################################
#
# xml_get_fh()
#
# Return the output filehandle.
#
sub xml_get_fh {
my $self = shift;
return $self->{_fh};
}
###############################################################################
#
# _escape_attributes()
#
# Escape XML characters in attributes.
#
sub _escape_attributes {
my $str = $_[0];
return $str if $str !~ m/["&<>]/;
for ( $str ) {
s/&/&/g;
s/"/"/g;
s/</</g;
s/>/>/g;
}
return $str;
}
###############################################################################
#
# _escape_data()
#
# Escape XML characters in data sections. Note, this is different from
# _escape_attributes() in that double quotes are not escaped by Excel.
#
sub _escape_data {
my $str = $_[0];
return $str if $str !~ m/[&<>]/;
for ( $str ) {
s/&/&/g;
s/</</g;
s/>/>/g;
}
return $str;
}
1;
__END__
=pod
=head1 NAME
XMLwriter - A base class for the Excel::Writer::XLSX writer classes.
=head1 DESCRIPTION
This module is used by L<Excel::Writer::XLSX> for writing XML documents. It is a light weight re-implementation of L<XML::Writer>.
XMLwriter is approximately twice as fast as L<XML::Writer>. This speed is achieved at the expense of error and correctness checking. In addition not all of the L<XML::Writer> methods are implemented. As such, XMLwriter is not recommended for use outside of Excel::Writer::XLSX.
=head1 SEE ALSO
L<XML::Writer>.
=head1 AUTHOR
John McNamara jmcnamara@cpan.org
=head1 COPYRIGHT
(c) MM-MMXIIII, John McNamara.
All Rights Reserved. This module is free software. It may be used, redistributed and/or modified under the same terms as Perl itself.
=head1 LICENSE
Either the Perl Artistic Licence L<http://dev.perl.org/licenses/artistic.html> or the GPL L<http://www.opensource.org/licenses/gpl-license.php>.
=head1 DISCLAIMER OF WARRANTY
See the documentation for L<Excel::Writer::XLSX>.
=cut
|