/usr/share/perl5/KiokuDB/Backend/Serialize/JSON.pm is in libkiokudb-perl 0.56-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 | package KiokuDB::Backend::Serialize::JSON;
BEGIN {
$KiokuDB::Backend::Serialize::JSON::AUTHORITY = 'cpan:NUFFIN';
}
{
$KiokuDB::Backend::Serialize::JSON::VERSION = '0.56';
}
use Moose::Role;
# ABSTRACT: Role to serialize entries to JSON strings with KiokuDB::Backend::Serialize::JSPON semantics
use IO::Handle;
use namespace::clean -except => 'meta';
with qw(
KiokuDB::Backend::Serialize
KiokuDB::Backend::Role::UnicodeSafe
KiokuDB::Backend::Serialize::JSPON
);
has pretty => (
isa => "Bool",
is => "rw",
default => 0,
);
has [qw(utf8 canonical)] => (
isa => "Bool",
is => "rw",
default => 1,
);
has json => (
isa => "Object",
is => "rw",
lazy_build => 1,
handles => [qw(encode decode)],
);
sub _build_json {
my $self = shift;
my $json = JSON->new;
foreach my $flag (qw(utf8 pretty canonical)) {
$json->$flag if $self->$flag;
}
return $json;
}
sub serialize {
my ( $self, @args ) = @_;
$self->encode( $self->collapse_jspon(@args) );
}
sub deserialize {
my ( $self, $json, @args ) = @_;
$self->expand_jspon( $self->decode($json), @args );
}
sub serialize_to_stream {
my ( $self, $fh, $entry ) = @_;
$fh->print( $self->serialize($entry) );
}
sub deserialize_from_stream {
my ( $self, $fh ) = @_;
local $_;
local $/ = \4096;
my $json = $self->json;
while ( <$fh> ) {
if ( my @docs = $json->incr_parse($_) ) {
my @entries = map { $self->expand_jspon($_) } @docs;
return @entries;
} else {
return if $fh->eof;
}
}
return;
}
__PACKAGE__
__END__
=pod
=head1 NAME
KiokuDB::Backend::Serialize::JSON - Role to serialize entries to JSON strings with KiokuDB::Backend::Serialize::JSPON semantics
=head1 VERSION
version 0.56
=head1 SYNOPSIS
with qw(KiokuDB::Backend::Serialize::JSON);
sub foo {
my ( $self, $entry ) = @_;
my $json_string = $self->serialize($entry);
}
=head1 DESCRIPTION
This role provides additional convenience attributes and methods for backends
that encode entries to JSON strings, on top of
L<KiokuDB::Backend::Serialize::JSPON> which only restructures the data.
L<KiokuDB::Backend::Serialize::Delegate> is preferred to using this directly.
=head1 METHODS
=over 4
=item serialize $entry
Returns a JSON string
=item deserialize $json_str
Returns a L<KiokuDB::Entry>
=back
=head1 ATTRIBUTES
=over 4
=item json
The L<JSON> instance used to encode/decode the JSON.
=item pretty
Whether or not to pass the C<pretty> flag to the L<JSON> object after
construction.
=back
=head1 AUTHOR
Yuval Kogman <nothingmuch@woobling.org>
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2013 by Yuval Kogman, Infinity Interactive.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|