libncarg-data 6.1.2-7 / usr / share / ncarg / nclex / mapplot / mp03n.ncl

This file is indexed.

/usr/share/ncarg/nclex/mapplot/mp03n.ncl is in libncarg-data 6.1.2-7.

This file is owned by root:root, with mode 0o644.

The actual contents of the file can be viewed below. 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;                                                                      ;
;                Copyright (C)  1993                                   ;
;        University Corporation for Atmospheric Research               ;
;                All Rights Reserved                                   ;
;                                                                      ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;   File:       mp03n.ncl
;
;   Author:     David Brown
;           National Center for Atmospheric Research
;           PO 3000, Boulder, Colorado
;
;           Translated to NCL by Ed Stautler
;
;   Date:       Fri Oct 14 11:42:41 MDT 1994
;
;   Description:    Demonstrates MapPlot masking; loosely emulates the
;           LLU example 'colcon'
;


;
; Read data from input file 'mp03n.asc'. 
;
function getdat (
        m : integer,
        n : integer
)
begin
	return(asciiread("mp03n.asc",(/m,n/),"float"))
end


begin

    M = 50
    N = 50

    mask_specs = (/ "oceans" /)
;
; Create an application context. Set the app dir to the current directory
; so the application looks for a resource file in the working directory.
; The resource file sets most of the Contour resources that remain fixed
; throughout the life of the Contour object.
;
    appid = create "mp03" appClass defaultapp
        "appUsrDir" : "./"
        "appDefaultParent" : True
    end create
;
; Default is to display output to an X workstation
;
    wks_type = "x11"

    if (str_lower(wks_type).eq."ncgm") then
;
; Create an ncgmWorkstation object.
;
        wid = create "mp03Work" ncgmWorkstationClass defaultapp
           "wkMetaName" : "./mp03n.ncgm"
        end create
    end if
    if (str_lower(wks_type).eq."x11") then
;
; Create an X11 workstation.
;
      wid = create "mp03Work" windowWorkstationClass defaultapp
          "wkPause" : True
      end create
    end if
    if (str_lower(wks_type).eq."oldps") then
;
; Create an older-style PostScript workstation.
;
      wid = create "mp03Work" psWorkstationClass defaultapp
       "wkPSFileName" : "./mp03n.ps"
      end create
    end if
    if (str_lower(wks_type).eq."oldpdf") then
;
; Create an older-style PDF workstation.
;
      wid = create "mp03Work" pdfWorkstationClass defaultapp
       "wkPDFFileName" : "./mp03n.pdf"
      end create
    end if
    if (str_lower(wks_type).eq."pdf".or.str_lower(wks_type).eq."ps") then
;
; Create a cairo PS/PDF Workstation object.
;
      wid = create "mp03Work" documentWorkstationClass defaultapp
       "wkFileName" : "./mp03n"
       "wkFormat" : wks_type
      end create
    end if
    if (str_lower(wks_type).eq."png") then
;
; Create a cairo PNG Workstation object.
;
      wid = create "mp03Work" imageWorkstationClass defaultapp
       "wkFileName" : "./mp03n"
       "wkFormat" : wks_type
      end create
    end if

;
; Call the routine 'getdat' to create the first array of contour
; data. Create a ScalarField data object and hand it the data created by
; 'getdat'. Define the extent of the data coordinates as the whole globe 
; 
    dataid = create "Gendat" scalarFieldClass appid
        "sfDataArray" : getdat(M,N)
        "sfXCStartV" : -180
        "sfXCEndV" : 180
        "sfYCStartV" : -90
        "sfYCEndV" : 90
    end create
;
; Create a Contour object, supplying the ScalarField object as data,
; and setting the size of the viewport.
;
    cnid = create "Contour1" contourPlotClass wid
        "cnScalarFieldData" : dataid
        "cnLabelDrawOrder" : "postdraw"
    end create
;
; Create a MapPlot object, setting the fill to draw over the main draw,
; and masking out the oceans.
;
    mapid = create "Map1" mapPlotClass wid
        "mpFillOn" : True
        "pmTitleDisplayMode" : "always"
        "tiMainString" : "mp03n"
        "mpFillDrawOrder" : "postdraw"
        "mpAreaMaskingOn" : True
        "mpMaskAreaSpecifiers" : mask_specs
    end create
;
; Overlay the Contour object on the MapPlot object
;
    overlay(mapid, cnid)
    
    draw(mapid)
    frame(wid)
;
; Destroy the objects created, close the HLU library and exit.
;
    delete(mapid)
    delete(wid)
end

APT Browse - Built by Thomas Orozco.