/usr/share/perl5/POE/Component/IRC/Cookbook/Resolver.pod is in libpoe-component-irc-perl 6.83+dfsg-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 | =encoding utf8
=head1 NAME
POE::Component::IRC::Cookbook::Resolver - A bot that can resolve DNS records
=head1 SYNOPSIS
This bot uses L<POE::Component::Client::DNS|POE::Component::Client::DNS>
to DNS records for channel members.
=head1 DESCRIPTION
#!/usr/bin/env perl
use strict;
use warnings;
use IRC::Utils qw(parse_user);
use POE;
use POE::Component::Client::DNS;
use POE::Component::IRC::State;
use POE::Component::IRC::Plugin::AutoJoin;
use POE::Component::IRC::Plugin::BotCommand;
POE::Session->create(
package_states => [
main => [ qw(_start irc_botcmd_resolve dns_response) ]
],
);
$poe_kernel->run();
sub _start {
my $heap = $_[HEAP];
my $irc = POE::Component::IRC::State->spawn(
Nick => 'resolver_bot',
Server => 'irc.freenode.net',
);
$heap->{irc} = $irc;
$irc->plugin_add('AutoJoin', POE::Component::IRC::Plugin::AutoJoin->new(
Channels => [ '#test_channel1', '#test_channel2' ]
));
$irc->plugin_add('BotCommand', POE::Component::IRC::Plugin::BotCommand->new(
Commands => {
resolve => 'Usage: resolve <host>'
}
));
$heap->{dns} = POE::Component::Client::DNS->spawn();
$irc->yield(register => 'botcmd_resolve');
$irc->yield('connect');
return;
}
sub irc_botcmd_resolve {
my $dns = $_[HEAP]->{dns};
my $nick = parse_user( $_[ARG0] );
my ($channel, $host) = @_[ARG1, ARG2];
my $res = $dns->resolve(
event => 'dns_response',
host => $host,
context => {
channel => $channel,
nick => $nick,
},
);
$poe_kernel->yield(dns_response => $res) if $res;
return;
}
sub dns_response {
my $irc = $_[HEAP]->{irc};
my $res = $_[ARG0];
my @answers = $res->{response}
? map { $_->rdatastr } $res->{response}->answer()
: ();
$irc->yield(
'privmsg',
$res->{context}->{channel},
$res->{context}->{nick} . (@answers
? ": @answers"
: ': no answers for "' . $res->{host} . '"')
);
return;
}
=head1 AUTHOR
Hinrik E<Ouml>rn SigurE<eth>sson, hinrik.sig@gmail.com
|