/usr/share/doc/basic256/examples/sprites/spriteslice.kbs is in basic256 0.9.6.69a-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 | # spriteslice.kbs - draw something on the screen and capture (slice) it
# into a sprite
# 2010-06-14 j.m.reneau
spritedim 4
dim dx(4)
dim dy(4)
# clear screen draw balls then slice out sprites
clg
# ball one - blue with square hole
color blue
circle 100,100,20
color clear
rect 90,90,20,20
# ball 2 - green with hole
color green
circle 100,200,20
color clear
circle 100,200,10
# ball 3 - red
color red
circle 200,100,20
# fourth is a square with a triangle cut out
color black
rect 200,200,35,35
color clear
poly {217,205,205,230,230,230}
# make sprites
spriteslice 0,80,80,41,41
spriteslice 1,180,80,41,41
spriteslice 2,80,180,41,41
spriteslice 3,200,200,35,35
print "sprites made"
pause 1
# layout screen
color yellow
rect 0,0,300,300
# move sprites to initial location and show
spritemove 0,100,100
spriteshow 0
pause .5
spritemove 1,200,200
spriteshow 1
pause .5
spritemove 2,100,200
spriteshow 2
pause .5
spritemove 3,200,100
spriteshow 3
pause .5
for i = 0 to 3
dx[i] = rand * 5
dy[i] = rand * 5
next i
while true
for i = 0 to 3
if spritex(i) + spritew(i) / 2 >= 300 or spritex(i) - spritew(i) / 2 <= 0 then dx[i] = dx[i] * -1
if spritey(i) + spriteh(i) / 2 >= 300 or spritey(i) - spriteh(i) / 2 <= 0 then dy[i] = dy[i] * -1
spritemove i, dx[i], dy[i]
next i
end while
|