/usr/share/doc/faust/examples/lfboost.dsp is in faust 0.9.46-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 | declare name "lfboost";
declare version "1.0";
declare author "Grame";
declare license "BSD";
declare copyright "(c)GRAME 2006";
//------------------------------------------------------------------
// DAFX, Digital Audio Effects (Wiley ed.)
// chapter 2 : filters
// section 2.3 : Equalizers
// page 53 : second order shelving filter design
//------------------------------------------------------------------
import("math.lib");
import("music.lib");
//----------------------low frequency boost filter -------------------------------
// lfboost(F,G)
// F : frequency (in Hz)
// G : gain (in dB)
//
//--------------------------------------------------------------------------------
lfboost(F,G) = TF2( (1 + sqrt(2*V)*K + V*K*K) / denom,
2 * (V*K*K - 1) / denom,
(1 - sqrt(2*V)*K + V*K*K) / denom,
2 * (K*K - 1) / denom,
(1 - sqrt(2)*K + K*K) / denom
)
with {
V = db2linear(G);
K = tan(PI*F/SR);
denom = 1 + sqrt(2)*K + K*K;
};
//====================low frequency boost process ===============================
process = vgroup("lowboost", lfboost(
nentry("freq [unit:Hz][style:knob]", 100, 20, 150, 1),
vslider("gain [unit:dB]", 0, -20, 20, 0.1)
) );
|