/usr/share/ada/adainclude/aws/aws-containers-tables.adb is in libaws2.10.2-dev 2.10.2-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2000-2009, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
------------------------------------------------------------------------------
-- Parameters name/value are put into the Table_Type.Data field (vector). The
-- name as a key and the numeric index as a value is placed into map for fast
-- retrieval of all Name/Value pairs having the same name. Each value in the
-- map is a table of numeric indexes pointing into the Data field. The
-- parameters must be accessible using their name (string index) but also
-- using an numeric index. So given a set of parameters (K1=V1, K2=V2...), one
-- must be able to ask for the value for K1 but also the name of the second
-- key or the value of the third key.
--
-- Each K/V pair is then inserted into the Data table for access by numeric
-- index. And its numeric index is placed into the map indexed by name.
with Ada.Characters.Handling;
with Ada.Containers.Generic_Array_Sort;
package body AWS.Containers.Tables is
procedure Get_Indexes
(Table : Table_Type;
Name : String;
Indexes : out Name_Index_Table;
Found : out Boolean);
pragma Inline (Get_Indexes);
-- Returns all Name/Value indexes for the specified name.
-- Found is set to False if Name was not found in Table and True otherwise.
--------------------
-- Case_Sensitive --
--------------------
function Case_Sensitive (Table : Table_Type) return Boolean is
begin
return Table.Case_Sensitive;
end Case_Sensitive;
-----------
-- Count --
-----------
function Count (Table : Table_Type) return Natural is
begin
return Natural (Data_Table.Length (Table.Data));
end Count;
-----------
-- Count --
-----------
function Count (Table : Table_Type; Name : String) return Natural is
Value : Name_Index_Table;
Found : Boolean;
begin
Get_Indexes (Table, Name, Value, Found);
if Found then
return Natural (Name_Indexes.Length (Value));
else
return 0;
end if;
end Count;
-----------
-- Exist --
-----------
function Exist (Table : Table_Type; Name : String) return Boolean is
begin
return Index_Table.Contains
(Table.Index, Normalize_Name (Name, not Table.Case_Sensitive));
end Exist;
---------------------------
-- Generic_Iterate_Names --
---------------------------
procedure Generic_Iterate_Names
(Table : Table_Type; Coupler : String)
is
use type Ada.Containers.Count_Type;
CN : Index_Table.Cursor;
NI : Name_Indexes.Vector;
Idx : Key_Positive;
begin
CN := Index_Table.First (Table.Index);
while Index_Table.Has_Element (CN) loop
NI := Index_Table.Element (CN);
Idx := Name_Indexes.Element (NI, 1);
if Name_Indexes.Length (NI) = 1 then
Process
(Data_Table.Element (Table.Data, Idx).Name,
Data_Table.Element (Table.Data, Idx).Value);
else
declare
Value : Unbounded_String;
begin
for J in 1 .. Positive (Name_Indexes.Length (NI)) loop
Idx := Name_Indexes.Element (NI, J);
Append (Value, Data_Table.Element (Table.Data, Idx).Value);
if J < Positive (Name_Indexes.Length (NI)) then
Append (Value, Coupler);
end if;
end loop;
Process
(Data_Table.Element (Table.Data, Idx).Name,
To_String (Value));
end;
end if;
CN := Index_Table.Next (CN);
end loop;
end Generic_Iterate_Names;
---------
-- Get --
---------
function Get
(Table : Table_Type;
Name : String;
N : Positive := 1) return String
is
Value : Name_Index_Table;
Found : Boolean;
begin
Get_Indexes (Table, Name, Value, Found);
if Found and then N <= Natural (Name_Indexes.Length (Value)) then
return Data_Table.Element
(Table.Data, Name_Indexes.Element (Value, N)).Value;
else
return "";
end if;
end Get;
function Get (Table : Table_Type; N : Positive) return Element is
begin
if N <= Natural (Data_Table.Length (Table.Data)) then
return Data_Table.Element (Table.Data, Key_Positive (N));
else
return Null_Element;
end if;
end Get;
-----------------
-- Get_Indexes --
-----------------
procedure Get_Indexes
(Table : Table_Type;
Name : String;
Indexes : out Name_Index_Table;
Found : out Boolean)
is
Cursor : Index_Table.Cursor;
begin
Cursor := Index_Table.Find
(Table.Index, Normalize_Name (Name, not Table.Case_Sensitive));
if not Index_Table.Has_Element (Cursor) then
Found := False;
else
Found := True;
Indexes := Index_Table.Element (Cursor);
end if;
end Get_Indexes;
--------------
-- Get_Name --
--------------
function Get_Name
(Table : Table_Type; N : Positive := 1) return String is
begin
if N <= Natural (Data_Table.Length (Table.Data)) then
return Data_Table.Element (Table.Data, Key_Positive (N)).Name;
else
return "";
end if;
end Get_Name;
---------------
-- Get_Names --
---------------
function Get_Names
(Table : Table_Type; Sort : Boolean := False) return VString_Array
is
procedure Sort_Names is
new Ada.Containers.Generic_Array_Sort
(Positive, Unbounded_String, VString_Array);
Result : VString_Array (1 .. Name_Count (Table));
Cursor : Index_Table.Cursor;
Index : Natural := Result'First - 1;
begin
Cursor := Index_Table.First (Table.Index);
while Index_Table.Has_Element (Cursor) loop
Index := Index + 1;
Result (Index) := To_Unbounded_String (Index_Table.Key (Cursor));
Index_Table.Next (Cursor);
end loop;
if Sort then
Sort_Names (Result);
end if;
return Result;
end Get_Names;
---------------
-- Get_Value --
---------------
function Get_Value
(Table : Table_Type; N : Positive := 1) return String is
begin
if N <= Natural (Data_Table.Length (Table.Data)) then
return Data_Table.Element (Table.Data, Key_Positive (N)).Value;
else
return "";
end if;
end Get_Value;
----------------
-- Get_Values --
----------------
function Get_Values
(Table : Table_Type; Name : String) return VString_Array
is
Value : Name_Index_Table;
Found : Boolean;
begin
Get_Indexes (Table, Name, Value, Found);
if Found then
declare
Last : constant Natural
:= Natural (Name_Indexes.Length (Value));
Result : VString_Array (1 .. Last);
begin
for I in 1 .. Last loop
Result (I)
:= To_Unbounded_String
(Data_Table.Element
(Table.Data, Name_Indexes.Element (Value, I)).Value);
end loop;
return Result;
end;
else
return (1 .. 0 => Null_Unbounded_String);
end if;
end Get_Values;
-------------------
-- Iterate_Names --
-------------------
procedure Iterate_Names
(Table : Table_Type;
Coupler : String;
Process : not null access procedure (Name, Value : String))
is
procedure For_Each is new Generic_Iterate_Names (Process.all);
begin
For_Each (Table, Coupler);
end Iterate_Names;
----------------
-- Name_Count --
----------------
function Name_Count (Table : Table_Type) return Natural is
begin
return Natural (Index_Table.Length (Table.Index));
end Name_Count;
--------------------
-- Normalize_Name --
--------------------
function Normalize_Name
(Name : String; To_Upper : Boolean) return String is
begin
if To_Upper then
return Ada.Characters.Handling.To_Upper (Name);
else
return Name;
end if;
end Normalize_Name;
end AWS.Containers.Tables;
|