/usr/share/ada/adainclude/aws/aws-resources-streams-zlib.adb is in libaws2.10.2-dev 2.10.2-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2003-2011, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
------------------------------------------------------------------------------
package body AWS.Resources.Streams.ZLib is
-----------
-- Close --
-----------
overriding procedure Close (Resource : in out Stream_Type) is
begin
if Resource.Source /= null then
Close (Resource.Source);
ZL.Close (Resource.Filter, Ignore_Error => True);
end if;
end Close;
--------------------
-- Deflate_Create --
--------------------
function Deflate_Create
(Source : Streams.Stream_Access;
Level : Compression_Level := ZL.Default_Compression;
Strategy : Strategy_Type := ZL.Default_Strategy;
Method : Compression_Method := ZL.Deflated;
Window_Bits : Window_Bits_Type := ZL.Default_Window_Bits;
Memory_Level : Memory_Level_Type := ZL.Default_Memory_Level;
Header : Header_Type := ZL.Default)
return Stream_Access
is
Result : constant Streams.Stream_Access := new Stream_Type;
begin
Deflate_Initialize
(Stream_Type (Result.all), Source, Level, Strategy, Method,
Window_Bits, Memory_Level, Header);
return Result;
end Deflate_Create;
------------------------
-- Deflate_Initialize --
------------------------
procedure Deflate_Initialize
(Resource : in out Stream_Type;
Source : Streams.Stream_Access;
Level : Compression_Level := ZL.Default_Compression;
Strategy : Strategy_Type := ZL.Default_Strategy;
Method : Compression_Method := ZL.Deflated;
Window_Bits : Window_Bits_Type := ZL.Default_Window_Bits;
Memory_Level : Memory_Level_Type := ZL.Default_Memory_Level;
Header : Header_Type := ZL.Default) is
begin
Create (Resource.Source, Source);
Resource.End_Of_File := False;
Resource.Rest_First := Resource.Buffer'Last + 1;
Resource.Rest_Last := Resource.Buffer'Last;
ZL.Deflate_Init
(Resource.Filter, Level, Strategy, Method,
Window_Bits, Memory_Level, Header);
end Deflate_Initialize;
-----------------
-- End_Of_File --
-----------------
overriding function End_Of_File
(Resource : Stream_Type) return Boolean is
begin
-- We could not use return End_Of_File (Resource.Source);
-- because end of source file would be reached earlier then
-- end of file of the encoded stream.
return Resource.End_Of_File;
end End_Of_File;
--------------------
-- Inflate_Create --
--------------------
function Inflate_Create
(Source : Streams.Stream_Access;
Window_Bits : Window_Bits_Type := ZL.Default_Window_Bits;
Header : Header_Type := ZL.Default)
return Stream_Access
is
Result : constant Streams.Stream_Access := new Stream_Type;
begin
Inflate_Initialize
(Stream_Type (Result.all), Source, Window_Bits, Header);
return Result;
end Inflate_Create;
------------------------
-- Inflate_Initialize --
------------------------
procedure Inflate_Initialize
(Resource : in out Stream_Type;
Source : Streams.Stream_Access;
Window_Bits : Window_Bits_Type := ZL.Default_Window_Bits;
Header : Header_Type := ZL.Default) is
begin
Create (Resource.Source, Source);
Resource.End_Of_File := False;
Resource.Rest_First := Resource.Buffer'Last + 1;
Resource.Rest_Last := Resource.Buffer'Last;
ZL.Inflate_Init (Resource.Filter, Window_Bits, Header);
end Inflate_Initialize;
----------
-- Read --
----------
overriding procedure Read
(Resource : in out Stream_Type;
Buffer : out Stream_Element_Array;
Last : out Stream_Element_Offset)
is
procedure Get
(Buffer : out Stream_Element_Array;
Last : out Stream_Element_Offset);
pragma Inline (Get);
-- Generic parameter for read source data
---------
-- Get --
---------
procedure Get
(Buffer : out Stream_Element_Array;
Last : out Stream_Element_Offset) is
begin
Read (Resource.Source, Buffer, Last);
end Get;
procedure Read_Encoded is new ZL.Read
(Read => Get,
Buffer => Resource.Buffer,
Rest_First => Resource.Rest_First,
Rest_Last => Resource.Rest_Last);
begin
Read_Encoded (Resource.Filter, Buffer, Last);
Resource.End_Of_File := Last < Buffer'Last;
end Read;
-----------
-- Reset --
-----------
overriding procedure Reset (Resource : in out Stream_Type) is
begin
Reset (Resource.Source);
end Reset;
---------------
-- Set_Index --
---------------
overriding procedure Set_Index
(Resource : in out Stream_Type;
To : Stream_Element_Offset) is
begin
Set_Index (Resource.Source, To);
end Set_Index;
end AWS.Resources.Streams.ZLib;
|