/usr/share/ada/adainclude/aws/aws-smtp-client.adb is in libaws2.10.2-dev 2.10.2-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- S M T P - Simple Mail Transfer Protocol --
-- --
-- Copyright (C) 2000-2011, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
------------------------------------------------------------------------------
with Ada.Calendar;
with Ada.Text_IO;
with Ada.Exceptions;
with GNAT.Calendar.Time_IO;
with AWS.Headers.Set;
with AWS.Messages;
with AWS.MIME;
with AWS.Net.Buffered;
with AWS.SMTP.Authentication;
pragma Warnings (Off, AWS.SMTP.Authentication);
-- Work around a visibility problem
with AWS.Utils;
package body AWS.SMTP.Client is
procedure Open
(Server : Receiver;
Sock : out Net.Socket_Access;
Status : out SMTP.Status);
-- Open session with a SMTP server
procedure Close
(Sock : in out Net.Socket_Access;
Status : in out SMTP.Status);
-- Close session with the SMTP server
procedure Output_Header
(Sock : Net.Socket_Type'Class;
From : E_Mail_Data;
To : Recipients;
CC : Recipients;
BCC : Recipients;
Subject : String;
Status : out SMTP.Status;
Is_MIME : Boolean := False);
-- Output SMTP headers (MAIL, RCPT, DATA, From, To, Subject, Date)
procedure Output_Simple_Header
(Sock : Net.Socket_Type'Class;
From : E_Mail_Data;
To : Recipients;
CC : Recipients;
BCC : Recipients;
Status : out SMTP.Status);
-- Output SMTP headers (MAIL, RCPT, DATA)
procedure Put_Translated_Line
(Sock : Net.Socket_Type'Class;
Text : String);
-- Translate a leading dot to two dots
procedure Terminate_Mail_Data (Sock : in out Net.Socket_Type'Class);
-- Send string CRLF & '.' & CRLF
procedure Shutdown (Sock : in out Net.Socket_Access);
-- Shutdown and close the socket. Do not raise an exception if the Socket
-- is not connected.
-----------------
-- Base64_Data --
-----------------
function Base64_Data (Name, Content : String) return Attachment is
begin
return (Base64_Data,
To_Unbounded_String (Name), To_Unbounded_String (Content));
end Base64_Data;
-----------
-- Close --
-----------
procedure Close
(Sock : in out Net.Socket_Access;
Status : in out SMTP.Status)
is
Answer : Server_Reply;
begin
Net.Buffered.Put_Line (Sock.all, "QUIT");
Check_Answer (Sock.all, Answer);
if Answer.Code /= Service_Closing then
Add (Answer, Status);
end if;
Net.Buffered.Shutdown (Sock.all);
Net.Free (Sock);
end Close;
----------
-- File --
----------
function File (Filename : String) return Attachment is
begin
return (File, To_Unbounded_String (Filename));
end File;
----------
-- Open --
----------
procedure Open
(Server : Receiver;
Sock : out Net.Socket_Access;
Status : out SMTP.Status)
is
Answer : Server_Reply;
begin
-- Clear status code
Clear (Status);
-- Open server
Sock := Net.Socket (Security => False);
Net.Connect (Sock.all, To_String (Server.Name), Server.Port);
-- Check connect message
Check_Answer (Sock.all, Answer);
if Answer.Code = Service_Ready then
-- Open session
Net.Buffered.Put_Line
(Sock.all, "HELO " & Net.Host_Name);
Check_Answer (Sock.all, Answer);
-- If no success, close the connection
if Answer.Code /= Requested_Action_Ok then
Add (Answer, Status);
Shutdown (Sock);
end if;
else
Add (Answer, Status);
Shutdown (Sock);
end if;
exception
when others =>
Shutdown (Sock);
raise;
end Open;
-------------------
-- Output_Header --
-------------------
procedure Output_Header
(Sock : Net.Socket_Type'Class;
From : E_Mail_Data;
To : Recipients;
CC : Recipients;
BCC : Recipients;
Subject : String;
Status : out SMTP.Status;
Is_MIME : Boolean := False)
is
function Current_Date return String;
-- Returns current date and time for SMTP "Date:" field
procedure Send (Header_Name : String; Emails : Recipients);
-- Write header Header_Name for the corresponding recipients
------------------
-- Current_Date --
------------------
function Current_Date return String is
TZ : constant String := Utils.Time_Zone;
begin
-- Format is: Mon, 1 Jan 2002 12:00:00 (+/-)HHMM
if TZ = "" then
return GNAT.Calendar.Time_IO.Image
(Calendar.Clock, "%a, %-d %b %Y %T");
else
return GNAT.Calendar.Time_IO.Image
(Calendar.Clock, "%a, %-d %b %Y %T ") & TZ;
end if;
end Current_Date;
----------
-- Send --
----------
procedure Send (Header_Name : String; Emails : Recipients) is
begin
if Emails /= No_Recipient then
Net.Buffered.Put
(Sock, Header_Name & ": " & Image (Emails (Emails'First)));
for K in Emails'First + 1 .. Emails'Last loop
Net.Buffered.Put (Sock, ", " & Image (Emails (K)));
end loop;
Net.Buffered.New_Line (Sock);
end if;
end Send;
begin
-- Output the MAIL, RCPT and DATA headers
Output_Simple_Header (Sock, From, To, CC, BCC, Status);
if Is_Ok (Status) then
-- Time Stamp
Net.Buffered.Put_Line (Sock, "Date: " & Current_Date);
-- From
Net.Buffered.Put_Line (Sock, "From: " & Image (From));
-- Subject
Net.Buffered.Put_Line (Sock, "Subject: " & Subject);
-- To
Send ("To", To);
-- CC
Send ("Cc", CC);
-- Note that BCC is not sent here as these are the data headers
-- sent to the client. The BCC recipients have been added into the
-- RCPT TO: fields.
if Is_MIME then
Net.Buffered.Put_Line
(Sock, "MIME-Version: 1.0 (produced by AWS/SMTP)");
else
Net.Buffered.New_Line (Sock);
end if;
end if;
end Output_Header;
--------------------------
-- Output_Simple_Header --
--------------------------
procedure Output_Simple_Header
(Sock : Net.Socket_Type'Class;
From : E_Mail_Data;
To : Recipients;
CC : Recipients;
BCC : Recipients;
Status : out SMTP.Status)
is
procedure Send (Emails : Recipients);
-- Procedure set to this recipient
----------
-- Send --
----------
procedure Send (Emails : Recipients) is
Answer : Server_Reply;
begin
for K in Emails'Range loop
Net.Buffered.Put_Line
(Sock,
"RCPT TO:<" & Image (Emails (K), Address) & '>');
Check_Answer (Sock, Answer);
if Answer.Code /= Requested_Action_Ok then
Add (Answer, Status);
end if;
end loop;
end Send;
Answer : Server_Reply;
begin
-- MAIL
Net.Buffered.Put_Line
(Sock, "MAIL FROM:<" & Image (From, Address) & '>');
Check_Answer (Sock, Answer);
if Answer.Code = Requested_Action_Ok then
-- RCPT
Send (To);
Send (CC);
Send (BCC);
if Is_Ok (Status) then
-- DATA
Net.Buffered.Put_Line (Sock, "DATA");
Check_Answer (Sock, Answer);
if Answer.Code /= Start_Mail_Input then
-- Not possible to send mail header data
Add (Answer, Status);
end if;
end if;
else
-- Error in From address
Add (Answer, Status);
end if;
end Output_Simple_Header;
-------------------------
-- Put_Translated_Line --
-------------------------
procedure Put_Translated_Line
(Sock : Net.Socket_Type'Class;
Text : String) is
begin
if Text'Length > 0 and then Text (Text'First) = '.' then
Net.Buffered.Put (Sock, ".");
end if;
Net.Buffered.Put_Line (Sock, Text);
end Put_Translated_Line;
----------
-- Send --
----------
procedure Send
(Server : Receiver;
From : E_Mail_Data;
To : E_Mail_Data;
Subject : String;
Message : String;
Status : out SMTP.Status;
CC : Recipients := No_Recipient;
BCC : Recipients := No_Recipient) is
begin
Send (Server, From, Recipients'(1 => To),
Subject, Message, Status, CC, BCC);
end Send;
----------
-- Send --
----------
procedure Send
(Server : Receiver;
From : E_Mail_Data;
To : E_Mail_Data;
Subject : String;
Message : String := "";
Attachments : Attachment_Set;
Status : out SMTP.Status;
CC : Recipients := No_Recipient;
BCC : Recipients := No_Recipient) is
begin
Send (Server, From, Recipients'(1 => To),
Subject, Message, Attachments, Status, CC, BCC);
end Send;
----------
-- Send --
----------
procedure Send
(Server : Receiver;
From : E_Mail_Data;
To : E_Mail_Data;
Subject : String;
Filename : Message_File;
Status : out SMTP.Status;
CC : Recipients := No_Recipient;
BCC : Recipients := No_Recipient)
is
Buffer : String (1 .. 2_048);
Last : Natural;
File : Text_IO.File_Type;
Sock : Net.Socket_Access;
Answer : Server_Reply;
begin
-- Open server
Open (Server, Sock, Status);
if Is_Ok (Status) then
if Server.Auth /= null then
Server.Auth.Before_Send (Sock.all, Status);
end if;
if Is_Ok (Status) then
Output_Header
(Sock.all, From, Recipients'(1 => To), CC, BCC, Subject, Status);
if Is_Ok (Status) then
-- Message body
Text_IO.Open (File, Text_IO.In_File, String (Filename));
while not Text_IO.End_Of_File (File) loop
Text_IO.Get_Line (File, Buffer, Last);
Put_Translated_Line (Sock.all, Buffer (1 .. Last));
end loop;
Text_IO.Close (File);
Terminate_Mail_Data (Sock.all);
Check_Answer (Sock.all, Answer);
if Is_Ok (Status) and then Server.Auth /= null then
Server.Auth.After_Send (Sock.all, Status);
end if;
if Answer.Code /= Requested_Action_Ok then
Add (Answer, Status);
end if;
end if;
end if;
Close (Sock, Status);
end if;
exception
-- Raise Server_Error for all problems encountered
when E : others =>
Shutdown (Sock);
if Text_IO.Is_Open (File) then
Text_IO.Close (File);
end if;
raise Server_Error with Ada.Exceptions.Exception_Information (E);
end Send;
----------
-- Send --
----------
procedure Send
(Server : Receiver;
From : E_Mail_Data;
To : Recipients;
Subject : String;
Message : String;
Status : out SMTP.Status;
CC : Recipients := No_Recipient;
BCC : Recipients := No_Recipient)
is
Sock : Net.Socket_Access;
Answer : Server_Reply;
begin
Open (Server, Sock, Status);
if Is_Ok (Status) then
if Server.Auth /= null then
Server.Auth.Before_Send (Sock.all, Status);
end if;
if Is_Ok (Status) then
Output_Header (Sock.all, From, To, CC, BCC, Subject, Status);
if Is_Ok (Status) then
-- Message body
Put_Translated_Line (Sock.all, Message);
Terminate_Mail_Data (Sock.all);
Check_Answer (Sock.all, Answer);
if Is_Ok (Status) and then Server.Auth /= null then
Server.Auth.After_Send (Sock.all, Status);
end if;
if Answer.Code /= Requested_Action_Ok then
Add (Answer, Status);
end if;
end if;
end if;
Close (Sock, Status);
end if;
exception
-- Raise Server_Error for all problems encountered
when E : others =>
Shutdown (Sock);
raise Server_Error with Ada.Exceptions.Exception_Information (E);
end Send;
----------
-- Send --
----------
procedure Send
(Server : Receiver;
From : E_Mail_Data;
To : Recipients;
Source : String;
Status : out SMTP.Status;
CC : Recipients := No_Recipient;
BCC : Recipients := No_Recipient)
is
Sock : Net.Socket_Access;
Answer : Server_Reply;
begin
Open (Server, Sock, Status);
if Is_Ok (Status) then
if Server.Auth /= null then
Server.Auth.Before_Send (Sock.all, Status);
end if;
if Is_Ok (Status) then
Output_Simple_Header (Sock.all, From, To, CC, BCC, Status);
if Is_Ok (Status) then
-- Message body
Put_Translated_Line (Sock.all, Source);
Terminate_Mail_Data (Sock.all);
Check_Answer (Sock.all, Answer);
if Is_Ok (Status) and then Server.Auth /= null then
Server.Auth.After_Send (Sock.all, Status);
end if;
if Answer.Code /= Requested_Action_Ok then
Add (Answer, Status);
end if;
end if;
end if;
Close (Sock, Status);
end if;
exception
-- Raise Server_Error for all problems encountered
when E : others =>
Shutdown (Sock);
raise Server_Error with Ada.Exceptions.Exception_Information (E);
end Send;
----------
-- Send --
----------
procedure Send
(Server : Receiver;
From : E_Mail_Data;
To : Recipients;
Subject : String;
Message : String := "";
Attachments : Attachment_Set;
Status : out SMTP.Status;
CC : Recipients := No_Recipient;
BCC : Recipients := No_Recipient)
is
Att_List : AWS.Attachments.List;
begin
-- Fill attachments list
if Message /= "" then
AWS.Attachments.Add
(Att_List,
"",
AWS.Attachments.Value
(Data => Message,
Content_Type => MIME.Text_Plain));
end if;
for K in Attachments'Range loop
declare
A : constant Attachment := Attachments (K);
H : AWS.Headers.List;
begin
case A.Kind is
when File =>
AWS.Attachments.Add
(Att_List,
Filename => To_String (A.Name),
Content_Id => "",
Encode => AWS.Attachments.Base64);
when Base64_Data =>
AWS.Headers.Set.Add
(H,
Messages.Content_Transfer_Encoding_Token,
"base64");
AWS.Attachments.Add
(Att_List,
To_String (A.Name),
AWS.Attachments.Value
(Name => To_String (A.Name),
Data => To_String (A.Data)),
Headers => H);
end case;
end;
end loop;
Send (Server, From, To, Subject, Att_List, Status, CC, BCC);
end Send;
procedure Send
(Server : Receiver;
From : E_Mail_Data;
To : Recipients;
Subject : String;
Attachments : AWS.Attachments.List;
Status : out SMTP.Status;
CC : Recipients := No_Recipient;
BCC : Recipients := No_Recipient)
is
use type AWS.Attachments.Root_MIME_Kind;
Sock : Net.Socket_Access;
Answer : Server_Reply;
Boundary : Unbounded_String;
begin
Open (Server, Sock, Status);
if Is_Ok (Status) then
if Server.Auth /= null then
Server.Auth.Before_Send (Sock.all, Status);
end if;
if Is_Ok (Status) then
Output_Header
(Sock.all, From, To, CC, BCC, Subject, Status, Is_MIME => True);
if Is_Ok (Status) then
-- Send MIME header
AWS.Attachments.Send_MIME_Header
(Sock.all, Attachments, Boundary);
-- Message for non-MIME compliant Mail reader
Net.Buffered.Put_Line
(Sock.all, "This is multipart MIME message");
Net.Buffered.Put_Line
(Sock.all,
"If you read this, your mailer does not support MIME.");
Net.Buffered.New_Line (Sock.all);
AWS.Attachments.Send
(Sock.all, Attachments, To_String (Boundary));
Terminate_Mail_Data (Sock.all);
Check_Answer (Sock.all, Answer);
if Is_Ok (Status) and then Server.Auth /= null then
Server.Auth.After_Send (Sock.all, Status);
end if;
if Answer.Code /= Requested_Action_Ok then
Add (Answer, Status);
end if;
end if;
end if;
Close (Sock, Status);
end if;
exception
-- Raise Server_Error for all problem encountered
when E : others =>
Shutdown (Sock);
raise Server_Error with Ada.Exceptions.Exception_Information (E);
end Send;
--------------
-- Shutdown --
--------------
procedure Shutdown (Sock : in out Net.Socket_Access) is
use type Net.Socket_Access;
begin
if Sock /= null then
Net.Buffered.Shutdown (Sock.all);
Net.Free (Sock);
end if;
end Shutdown;
-------------------------
-- Terminate_Mail_Data --
-------------------------
procedure Terminate_Mail_Data (Sock : in out Net.Socket_Type'Class) is
begin
Net.Buffered.New_Line (Sock);
Net.Buffered.Put (Sock, ".");
Net.Buffered.New_Line (Sock);
end Terminate_Mail_Data;
end AWS.SMTP.Client;
|