/usr/share/ada/adainclude/aws/aws-url-set.adb is in libaws2.10.2-dev 2.10.2-4.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 | ------------------------------------------------------------------------------
-- Ada Web Server --
-- --
-- Copyright (C) 2007-2011, AdaCore --
-- --
-- This library is free software; you can redistribute it and/or modify --
-- it under the terms of the GNU General Public License as published by --
-- the Free Software Foundation; either version 2 of the License, or (at --
-- your option) any later version. --
-- --
-- This library is distributed in the hope that it will be useful, but --
-- WITHOUT ANY WARRANTY; without even the implied warranty of --
-- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU --
-- General Public License for more details. --
-- --
-- You should have received a copy of the GNU General Public License --
-- along with this library; if not, write to the Free Software Foundation, --
-- Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. --
-- --
------------------------------------------------------------------------------
with Ada.Strings.Fixed;
with AWS.Parameters.Set;
with AWS.URL.Raise_URL_Error;
with AWS.Utils;
package body AWS.URL.Set is
function Normalize (Path : Unbounded_String) return Unbounded_String;
-- Returns Path with all possible occurences of parent and current
-- directories removed. Does not raise exception.
---------------------
-- Connection_Data --
---------------------
procedure Connection_Data
(URL : in out Object;
Host : String;
Port : Positive;
Security : Boolean) is
begin
if Host = "" then
URL.Host := To_Unbounded_String ("localhost");
else
URL.Host := To_Unbounded_String (Host);
end if;
URL.Port := Port;
if Security then
URL.Protocol := HTTPS;
else
URL.Protocol := HTTP;
end if;
end Connection_Data;
---------------
-- Normalize --
---------------
function Normalize (Path : Unbounded_String) return Unbounded_String is
URL_Path : Unbounded_String := Path;
K : Natural;
P : Natural;
begin
-- Checks for current directory and removes all occurences
-- Look for starting ./
if Length (URL_Path) >= 2 and then Slice (URL_Path, 1, 2) = "./" then
Delete (URL_Path, 1, 1);
end if;
-- Look for all // references
K := 1;
loop
K := Index (URL_Path, "//", From => K);
exit when K = 0;
if K > 1 and then Slice (URL_Path, K - 1, K - 1) = ":" then
K := K + 1;
else
Delete (URL_Path, K, K);
end if;
end loop;
-- Look for all /./ references
K := 1;
loop
K := Index (URL_Path, "/./", From => K);
exit when K = 0;
Delete (URL_Path, K, K + 1);
end loop;
-- Checks for parent directory
P := 1;
loop
K := Index (URL_Path, "/../", From => P);
exit when K = 0;
-- Look for previous directory, which should be removed
P := Strings.Fixed.Index
(Slice (URL_Path, 1, K - 1), "/", Strings.Backward);
exit when P = 0;
Delete (URL_Path, P, K + 2);
end loop;
return URL_Path;
end Normalize;
----------------
-- Parameters --
----------------
procedure Parameters (URL : in out Object; Set : AWS.Parameters.List) is
begin
URL.Parameters := Set;
end Parameters;
function Parameters
(URL : not null access Object) return access AWS.Parameters.List is
begin
return URL.Parameters'Unchecked_Access;
end Parameters;
-----------
-- Parse --
-----------
procedure Parse
(Item : in out Object;
URL : String;
Check_Validity : Boolean := True;
Normalize : Boolean := False)
is
FTP_Token : constant String := "ftp://";
HTTP_Token : constant String := "http://";
HTTPS_Token : constant String := "https://";
L_URL : constant String :=
Strings.Fixed.Translate
(URL, Strings.Maps.To_Mapping ("\", "/"));
P : Natural;
procedure Parse (URL : String; Protocol_Specified : Boolean);
-- Parse URL, the URL must not contain the HTTP_Token prefix.
-- Protocol_Specified is set to True when the protocol (http:// or
-- https:// prefix) was specified. This is used to raise ambiguity
-- while parsing the URL. See comment below.
-----------
-- Parse --
-----------
procedure Parse (URL : String; Protocol_Specified : Boolean) is
function "+" (S : String) return Unbounded_String
renames To_Unbounded_String;
procedure Parse_Path_File (Start : Positive);
-- Parse Path and File URL information starting at position Start in
-- URL.
I1, I2, I3 : Natural;
F : Positive;
---------------------
-- Parse_Path_File --
---------------------
procedure Parse_Path_File (Start : Positive) is
PF : constant String := URL (Start .. URL'Last);
I3 : constant Natural :=
Strings.Fixed.Index (PF, "/", Strings.Backward);
begin
if I3 = 0 then
-- No '/' so this is certainly a single file. As a special
-- exception we check for current and parent directories
-- which must be part of the path.
declare
File : constant String := URL (Start .. URL'Last);
begin
if File = ".." or else File = "." then
Item.Path := +File;
Item.File := +"";
else
Item.Path := +"";
Item.File := +File;
end if;
end;
else
-- Check that after the last '/' we have not a current or
-- parent directories which must be part of the path.
declare
File : constant String := URL (I3 + 1 .. URL'Last);
begin
if File = ".." or else File = "." then
Item.Path := +URL (Start .. URL'Last);
Item.File := +"";
else
Item.Path := +URL (Start .. I3);
Item.File := +File;
end if;
end;
end if;
end Parse_Path_File;
User_Password : Boolean := False;
begin
I1 := Strings.Fixed.Index (URL, ":");
I2 := Strings.Fixed.Index (URL, "/");
I3 := Strings.Fixed.Index (URL, "@");
-- Check for [user:password@]
if I1 /= 0 and then I3 /= 0 and then I1 < I3 then
-- We have [user:password@]
Item.User := +URL (URL'First .. I1 - 1);
Item.Password := +URL (I1 + 1 .. I3 - 1);
F := I3 + 1;
-- Check if there is another ':' specified
I1 := Strings.Fixed.Index (URL (F .. URL'Last), ":");
User_Password := True;
else
F := URL'First;
end if;
if I1 = 0
and then not User_Password
and then not Protocol_Specified
then
-- No ':', there is no port specified and no host since we did
-- not have a [user:password@] parsed and there was no protocol
-- specified. Let's just parse the data as a path information.
--
-- There is ambiguity here, the data could be either:
--
-- some_host_name/some_path
-- or
-- relative_path/some_more_path
--
-- As per explanations above we take the second choice.
Item.Host := +"";
Parse_Path_File (URL'First);
elsif I1 = 0 then
-- In this case we have not port specified but a [user:password@]
-- was found, we expect the first string to be the hostname.
if I2 = 0 then
-- No path information, case [user:password@host]
Item.Host := +URL (F .. URL'Last);
Item.Path := +"/";
else
-- A path, case [user:password@host/path]
Item.Host := +URL (F .. I2 - 1);
Parse_Path_File (I2);
end if;
else
if I2 = 0 then
-- No path, we have [host:port]
Item.Host := +URL (F .. I1 - 1);
if Utils.Is_Number (URL (I1 + 1 .. URL'Last)) then
Item.Port := Positive'Value (URL (I1 + 1 .. URL'Last));
else
Raise_URL_Error (Set.Parse.URL, "Port is not valid");
end if;
Item.Path := +"/";
elsif I1 < I2 then
-- Here we have a complete URL [host:port/path]
Item.Host := +URL (F .. I1 - 1);
if Utils.Is_Number (URL (I1 + 1 .. I2 - 1)) then
Item.Port := Positive'Value (URL (I1 + 1 .. I2 - 1));
else
Raise_URL_Error (Set.Parse.URL, "Port is not valid");
end if;
Parse_Path_File (I2);
else
-- Here we have a complete URL, with no port specified
-- The semicolon is part of the URL [host/path]
Item.Host := +URL (F .. I2 - 1);
Parse_Path_File (I2);
end if;
end if;
end Parse;
begin
Item.Protocol := HTTP;
-- Checks for parameters
P := Strings.Fixed.Index (L_URL, "?");
if P = 0 then
P := L_URL'Last;
else
AWS.Parameters.Set.Add (Item.Parameters, L_URL (P .. L_URL'Last));
P := P - 1;
end if;
-- Checks for prefix
if Utils.Match (L_URL, HTTP_Token) then
Item.Port := Default_HTTP_Port;
Parse (L_URL (L_URL'First + HTTP_Token'Length .. P), True);
elsif Utils.Match (L_URL, HTTPS_Token) then
Item.Port := Default_HTTPS_Port;
Parse (L_URL (L_URL'First + HTTPS_Token'Length .. P), True);
Item.Protocol := HTTPS;
elsif Utils.Match (L_URL, FTP_Token) then
Item.Port := Default_FTP_Port;
Parse (L_URL (L_URL'First + FTP_Token'Length .. P), True);
Item.Protocol := FTP;
elsif L_URL /= "" then
-- Prefix is not recognized, this is either because there is no
-- protocol specified or the protocol is not supported by AWS. For
-- example a javascript reference start with "javascript:". This
-- will be caught on the next parsing level.
--
-- At least we know that it is not a Secure HTTP protocol URL.
Parse (L_URL (L_URL'First .. P), False);
end if;
-- Normalize the URL path
Item.N_Path := Set.Normalize (Item.Path);
-- Set status
declare
Path_Len : constant Natural := Length (Item.N_Path);
begin
if (Path_Len >= 4 and then Slice (Item.N_Path, 1, 4) = "/../")
or else
(Path_Len = 3 and then Slice (Item.N_Path, 1, 3) = "/..")
then
Item.Status := Wrong;
else
Item.Status := Valid;
end if;
end;
-- If Normalize is activated, the active URL Path is the normalized one
if Normalize then
Item.Path := Item.N_Path;
end if;
-- Raise URL_Error if the URL is suspicious
if Check_Validity and then Item.Status = Wrong then
Raise_URL_Error
(To_String (Item.N_Path),
"Reference Web root parent directory");
end if;
end Parse;
end AWS.URL.Set;
|