/usr/share/camitk-3.2/cmake/macros/CamiTKLibrary.cmake is in libcamitk3-dev 3.2.2-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 | #!
#! \addtogroup CamiTKMacros
#!
#! macro camitk_library simplifies the declaration of a library inside CamiTK
#! and is to be used for all inner project libraries
#!
#! The name of the CEP library is deduced from the name of the directory, unless LIBNAME is provided
#!
#! If the library is compiled as shared, it adds the needed library properties
#! If it needs relocation flag fPIC (on some plateforms), this macro should determine
#! if this is the case and specify this flag
#!
#! usage:
#! \code
#! camitk_library(
#! SHARED|STATIC
#! SOURCES source1.cpp source1.h...
#! TARGET_LINK_LIBRARIES lib1 lib2...
#! [INCLUDE_DIRECTORIES dir1 dir2...]
#! [NEEDS_LIBXML2]
#! [NEEDS_XERCESC]
#! [NEEDS_XSD]
#! [LINK_DIRECTORIES dir1 dir2...]
#! [LIBNAME libname]
#! [PUBLIC]
#! [HEADERS_TO_INSTALL]
#! [CEP_NAME]
#! [DESCRIPTION]
#!
#! )
#! \endcode
#!
#! \param SHARED optional, if the library should be compiled as shared
#! \param SOURCES all sources to be included in the library
#! \param INCLUDE_DIRECTORIES all needed include directories (${CMAKE_CURRENT_SOURCE_DIR} and ${CMAKE_CURRENT_BINARY_DIR} are automatically added)
#! \param TARGET_LINK_LIBRARIES all the libraries to be used during the link
#! \param NEEDS_LIBXML2 add this if the CEP library needs libxml2
#! \param NEEDS_XERCESC add this if your action / component needs XercesC library
#! \param NEEDS_XSD add this if your action needs Codesynthesis xsd cxx (xml schema compiler)
#! \param LIBNAME force the CEP library name to be different from the directory it is in
#! \param LINK_DIRECTORIES additional directories to use in link_directories(...)
#! \param PUBLIC The library is a public library that has to be loaded directly by the operating system.
#! It is generally only needed for SDK library. A public library should not be installed in the
#! lib/${CAMITK_SHORT_VERSION_STRING} but directly in lib/ (on Unix/MacOS) or bin/ (on windows)
#! \param HEADERS_TO_INSTALL list of headers to install, if present this will automatically
#! create an "install-COMPONENT_NAMEcomponent" target, that can be used
#! anywhere else to manage dependencies to this component.
#! The headers are installed ${CAMITK_BUILD_INCLUDE_DIR}/COMPONENT_NAME
#! when the target "install-COMPONENT_NAMEcomponent" is called.
#! \param CEP_NAME specify the CEP_NAME, which is used to categorized the extension for packaging purpose
#! No CEP_NAME provided will result in default categorization (generic extension).
#! \param DESCRIPTION Simple description of the extension. Used for packaging presentation for instance.
macro(camitk_library)
get_directory_name(${CMAKE_CURRENT_SOURCE_DIR} DEFAULT_LIBRARY_NAME)
parse_arguments(${DEFAULT_LIBRARY_NAME_CMAKE}
"SOURCES;TARGET_LINK_LIBRARIES;INCLUDE_DIRECTORIES;LIBNAME;LINK_DIRECTORIES;HEADERS_TO_INSTALL;CEP_NAME;DESCRIPTION" # possible lists
"SHARED;STATIC;NEEDS_LIBXML2;NEEDS_XERCESC;NEEDS_XSD;PUBLIC" # possible options
${ARGN}
)
# if the libname is forced to be different (for string comparison problem, and
# why there is a double quote here, see http://www.cmake.org/pipermail/cmake/2011-October/046939.html)
# NSIS requires that cpack component names do not feature space or "-" characters
if (PACKAGING_NSIS)
if ("${${DEFAULT_LIBRARY_NAME_CMAKE}_LIBNAME}" STREQUAL "")
set(LIBRARY_TARGET_NAME library_${DEFAULT_LIBRARY_NAME})
else()
set(LIBRARY_TARGET_NAME library_${${DEFAULT_LIBRARY_NAME_CMAKE}_LIBNAME})
endif()
else()
if ("${${DEFAULT_LIBRARY_NAME_CMAKE}_LIBNAME}" STREQUAL "")
set(LIBRARY_TARGET_NAME library-${DEFAULT_LIBRARY_NAME})
else()
set(LIBRARY_TARGET_NAME library-${${DEFAULT_LIBRARY_NAME_CMAKE}_LIBNAME})
endif()
endif()
# when installing, remove the prefix 'library'
string(REGEX REPLACE "^library_|^library-" "" LIBRARY_NAME ${LIBRARY_TARGET_NAME})
# includes
include_directories ( ${${DEFAULT_LIBRARY_NAME_CMAKE}_INCLUDE_DIRECTORIES}
${CMAKE_CURRENT_SOURCE_DIR}
${CMAKE_CURRENT_BINARY_DIR}
)
# Looking for LibXML2.0
set(LIBXML2_LIBRARIES)
if(${DEFAULT_LIBRARY_NAME_CMAKE}_NEEDS_LIBXML2)
# LibXml2 is required
find_package(Xml2)
if (LIBXML2_FOUND)
add_definitions(${LIBXML2_DEFINITIONS})
include_directories(${LIBXML2_INCLUDE_DIR})
else()
# most probably win32 or crosscompiling
message(WARNING "${LIBRARY_TARGET_NAME}: libxml2 required")
endif()
endif()
# Looking for XercesC
set(XERCESC_LIBRARIES)
if(${DEFAULT_LIBRARY_NAME_CMAKE}_NEEDS_XERCESC)
# XercesC is required
find_package(XercesC REQUIRED)
if (XERCESC_FOUND)
include_directories(${XERCESC_INCLUDE_DIR})
else()
# most probably win32 or crosscompiling
message(STATUS "${LIBRARY_TARGET_NAME}: xerces-c required")
endif()
endif()
# Looking for codesynthesis XSD CXX
if(${DEFAULT_LIBRARY_NAME_CMAKE}_NEEDS_XSD)
# XercesC is required
find_package(XercesC REQUIRED)
if (XERCESC_FOUND)
include_directories(${XERCESC_INCLUDE_DIR})
find_package(XSD REQUIRED)
include_directories(${XSD_INCLUDE_DIR})
else()
# most probably win32 or crosscompiling
message(ERROR "${LIBRARY_TARGET_NAME}: xerces-c required because of XSD cxx, please set XERCESC_INCLUDE_DIR")
endif()
endif()
# some additional link directories are needed
if (NOT "${${DEFAULT_LIBRARY_NAME_CMAKE}_LINK_DIRECTORIES}" STREQUAL "")
link_directories(${${DEFAULT_LIBRARY_NAME_CMAKE}_LINK_DIRECTORIES})
endif()
# Adding shared or static library
if (${DEFAULT_LIBRARY_NAME_CMAKE}_SHARED) # shared library
message(STATUS "Adding shared library: ${LIBRARY_TARGET_NAME}")
add_library(${LIBRARY_TARGET_NAME} SHARED ${${DEFAULT_LIBRARY_NAME_CMAKE}_SOURCES})
# prepare the library specific info (SONAME...)
set(${LIBRARY_TARGET_NAME}_LIBRARY_PROPERTIES ${${LIBRARY_TARGET_NAME}_LIBRARY_PROPERTIES}
VERSION "${CAMITK_VERSION_MAJOR}.${CAMITK_VERSION_MINOR}.${CAMITK_VERSION_PATCH}"
SOVERSION "${CAMITK_VERSION_MAJOR}"
)
# set the library specific info (SONAME...)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES ${${LIBRARY_TARGET_NAME}_LIBRARY_PROPERTIES} LINK_INTERFACE_LIBRARIES "")
elseif (${DEFAULT_LIBRARY_NAME_CMAKE}_STATIC) # static library
message(STATUS "Adding static library: ${LIBRARY_TARGET_NAME}")
add_library(${LIBRARY_TARGET_NAME} STATIC ${${DEFAULT_LIBRARY_NAME_CMAKE}_SOURCES})
else()
message(FATAL_ERROR "In adding static library ${LIBRARY_TARGET_NAME}.\n Please specify the library type: SHARED or STATIC")
endif()
# We are building a static or shared library.
# Specify, regarding the platform where to build the binaries depending on the library type (public / private)
if (${DEFAULT_LIBRARY_NAME_CMAKE}_PUBLIC) # Public library => build in the bin folder
if (MSVC)
# With Visual Studio, public libraries are built in build\bin directory, else it's in build\lib
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${CAMITK_BUILD_BIN_DIR}
LIBRARY_OUTPUT_DIRECTORY_DEBUG ${CAMITK_BUILD_BIN_DIR}
LIBRARY_OUTPUT_DIRECTORY_RELEASE ${CAMITK_BUILD_BIN_DIR}
)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CAMITK_BUILD_BIN_DIR}
RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CAMITK_BUILD_BIN_DIR}
RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CAMITK_BUILD_BIN_DIR}
)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${CAMITK_BUILD_BIN_DIR}
ARCHIVE_OUTPUT_DIRECTORY_DEBUG ${CAMITK_BUILD_BIN_DIR}
ARCHIVE_OUTPUT_DIRECTORY_RELEASE ${CAMITK_BUILD_BIN_DIR}
)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES DEBUG_POSTFIX ${CAMITK_DEBUG_POSTFIX})
else()
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CAMITK_BUILD_PUBLIC_LIB_DIR})
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${CAMITK_BUILD_PUBLIC_LIB_DIR})
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${CAMITK_BUILD_PUBLIC_LIB_DIR})
endif()
else() # Private library => build in lib folder
if (MSVC)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${CAMITK_BUILD_PRIVATE_LIB_DIR}
LIBRARY_OUTPUT_DIRECTORY_DEBUG ${CAMITK_BUILD_PRIVATE_LIB_DIR}
LIBRARY_OUTPUT_DIRECTORY_RELEASE ${CAMITK_BUILD_PRIVATE_LIB_DIR}
)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CAMITK_BUILD_PRIVATE_LIB_DIR}
RUNTIME_OUTPUT_DIRECTORY_DEBUG ${CAMITK_BUILD_PRIVATE_LIB_DIR}
RUNTIME_OUTPUT_DIRECTORY_RELEASE ${CAMITK_BUILD_PRIVATE_LIB_DIR}
)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${CAMITK_BUILD_PRIVATE_LIB_DIR}
ARCHIVE_OUTPUT_DIRECTORY_DEBUG ${CAMITK_BUILD_PRIVATE_LIB_DIR}
ARCHIVE_OUTPUT_DIRECTORY_RELEASE ${CAMITK_BUILD_PRIVATE_LIB_DIR}
)
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES DEBUG_POSTFIX ${CAMITK_DEBUG_POSTFIX})
else()
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${CAMITK_BUILD_PRIVATE_LIB_DIR})
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${CAMITK_BUILD_PRIVATE_LIB_DIR})
set_target_properties(${LIBRARY_TARGET_NAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${CAMITK_BUILD_PRIVATE_LIB_DIR})
endif()
endif()
# change the output library name (without the prefix 'library')
set_target_properties(${LIBRARY_TARGET_NAME}
PROPERTIES OUTPUT_NAME ${LIBRARY_NAME}
)
# Update XML Project description adding this target as a subproject of the main CamiTK project with
# its dependencies (in the CMake target point of view)
camitk_sub_project_add(CEP_LIBRARY ${LIBRARY_TARGET_NAME})
# 64bits and other platform with relocation needs -fPIC
include(TestCXXAcceptsFlag)
check_cxx_accepts_flag(-fPIC FPIC_FLAG_ACCEPTED)
# no need to add -fPIC on mingw, otherwise it generates a warning: -fPIC ignored for target (all code is position independent) [enabled by default]
# msvc is also accepting the flag, but then produce warning D9002 : ignoring unknown option '-fPIC' cl
if(FPIC_FLAG_ACCEPTED AND NOT WIN32)
set_property(TARGET ${LIBRARY_TARGET_NAME} APPEND PROPERTY COMPILE_FLAGS -fPIC)
endif()
#add libraries needed during the link
target_link_libraries(${LIBRARY_TARGET_NAME} ${${DEFAULT_LIBRARY_NAME_CMAKE}_TARGET_LINK_LIBRARIES} ${LIBXML2_LIBRARIES} ${XERCESC_LIBRARY})
# generate an install target for headers in include/{camitk-version}/libraries
if(${DEFAULT_LIBRARY_NAME_CMAKE}_HEADERS_TO_INSTALL)
export_headers(${${DEFAULT_LIBRARY_NAME_CMAKE}_HEADERS_TO_INSTALL} COMPONENT ${LIBRARY_TARGET_NAME} GROUP libraries)
endif()
# lib installation (depending if this one is public or not)
if (${DEFAULT_LIBRARY_NAME_CMAKE}_PUBLIC) # public library
if(WIN32)
# public library -> install in bin folder
install(TARGETS ${LIBRARY_TARGET_NAME}
RUNTIME DESTINATION bin
LIBRARY DESTINATION lib
ARCHIVE DESTINATION lib/${CAMITK_SHORT_VERSION_STRING}
COMPONENT ${LIBRARY_NAME_INSTALL}
)
else()
# other public libraries -> install in lib folder
install(TARGETS ${LIBRARY_TARGET_NAME}
RUNTIME DESTINATION lib
LIBRARY DESTINATION lib
ARCHIVE DESTINATION lib
COMPONENT ${LIBRARY_NAME_INSTALL}
)
endif()
else()
# private library -> install in lib/camitk-version folder
install(TARGETS ${LIBRARY_TARGET_NAME}
RUNTIME DESTINATION lib/${CAMITK_SHORT_VERSION_STRING}
LIBRARY DESTINATION lib/${CAMITK_SHORT_VERSION_STRING}
ARCHIVE DESTINATION lib/${CAMITK_SHORT_VERSION_STRING}
COMPONENT ${LIBRARY_NAME_INSTALL}
)
endif()
# Categorized the library in the install shield wizard.
if(${DEFAULT_LIBRARY_NAME_CMAKE}_CEP_NAME)
if (${DEFAULT_LIBRARY_NAME_CMAKE}_CEP_NAME MATCHES "SDK")
# The default SDK extensions are categorized as "required" and are not "unselectable" by the user at installation time
cpack_add_component(${LIBRARY_TARGET_NAME}
DISPLAY_NAME ${LIBRARY_TARGET_NAME}
DESCRIPTION ${${DEFAULT_LIBRARY_NAME_CMAKE}_DESCRIPTION}
REQUIRED
GROUP SDK
)
else()
# Extension is selectable for installation in the wizard of the installer
cpack_add_component(${LIBRARY_TARGET_NAME}
DISPLAY_NAME ${LIBRARY_TARGET_NAME}
DESCRIPTION ${${DEFAULT_LIBRARY_NAME_CMAKE}_DESCRIPTION}
GROUP ${${DEFAULT_LIBRARY_NAME_CMAKE}_CEP_NAME}
)
endif()
else()
# Extension if not categorized for packaging presentation
cpack_add_component(${LIBRARY_TARGET_NAME}
DISPLAY_NAME ${LIBRARY_TARGET_NAME}
DESCRIPTION ${${DEFAULT_LIBRARY_NAME_CMAKE}_DESCRIPTION}
)
endif()
endmacro()
# Old macro to configure a tool
# Use camitk_library macro instead
# TODO CAMITK_OBSOLETE. This macro is marked as obsolete. It is to be removed in CamiTK 4.0
macro(camitk_tool)
message(WARNING "Warning: ${CMAKE_CURRENT_SOURCE_DIR}/CMakeLists.txt: camitk_tool macro is deprecated, please usecamitk_library(...) instead (use the same parameters).")
# string(REPLACE "NEEDS_TOOL" "NEEDS_CEP_LIBRARIES" OBSOLETE_ARGN ${ARGN})
# message(STATUS "**************************************** ${ARGN} ===>>> ${OBSOLETE_ARGN} ")
camitk_library(${OBSOLETE_ARGN})
endmacro()
|