/usr/share/augeas/lenses/dist/mailscanner.aug is in augeas-lenses 1.4.0-0ubuntu1.1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 | (*
Module: Mailscanner
Parses MailScanner configuration files.
Author: Andrew Colin Kissa <andrew@topdog.za.net>
Baruwa Enterprise Edition http://www.baruwa.com
About: License
This file is licensed under the LGPL v2+.
About: Configuration files
This lens applies to /etc/MailScanner/MailScanner.conf and files in
/etc/MailScanner/conf.d/. See <filter>.
*)
module Mailscanner =
autoload xfm
(************************************************************************
* Group: USEFUL PRIMITIVES
*************************************************************************)
let comment = Util.comment
let empty = Util.empty
let space = Sep.space
let eol = Util.eol
let non_eq = /[^ =\t\r\n]+/
let non_space = /[^# \t\n]/
let any = /.*/
let word = /[A-Za-z%][ :<>%A-Za-z0-9_.-]+[A-Za-z%2]/
let include_kw = /include/
let keys = word - include_kw
let eq = del /[ \t]*=/ " ="
let indent = del /[ \t]*(\n[ \t]+)?/ " "
let line_value = store (non_space . any . non_space | non_space)
(************************************************************************
* Group: Entries
*************************************************************************)
let include_line = Build.key_value_line include_kw space (store non_eq)
let normal_line = [ key keys . eq . (indent . line_value)? . eol ]
(************************************************************************
* Group: Lns and Filter
*************************************************************************)
let lns = (empty|include_line|normal_line|comment) *
let filter = (incl "/etc/MailScanner/MailScanner.conf")
. (incl "/etc/MailScanner/conf.d/*.conf")
let xfm = transform lns filter
|