/usr/share/pacemaker/upgrade-1.3.xsl is in pacemaker-common 1.1.14-2ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 | <?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fn="http://www.w3.org/2005/02/xpath-functions">
<xsl:output method='xml' version='1.0' encoding='UTF-8' indent='yes'/>
<xsl:template match="role_ref">
<xsl:element name="role">
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="node()" />
</xsl:element>
</xsl:template>
<xsl:template match="read|write|deny">
<xsl:element name="acl_permission">
<xsl:attribute name="id"><xsl:value-of select="@id"/></xsl:attribute>
<xsl:attribute name="kind"><xsl:value-of select="name()"/></xsl:attribute>
<xsl:if test="@ref">
<xsl:attribute name="reference"><xsl:value-of select="@ref"/></xsl:attribute>
</xsl:if>
<xsl:if test="not(@ref)">
<xsl:if test="@tag">
<xsl:attribute name="object-type"><xsl:value-of select="@tag"/></xsl:attribute>
<xsl:if test="@attribute">
<xsl:attribute name="attribute"><xsl:value-of select="@attribute"/></xsl:attribute>
</xsl:if>
</xsl:if>
</xsl:if>
<xsl:if test="@xpath">
<xsl:attribute name="xpath"><xsl:value-of select="@xpath"/></xsl:attribute>
</xsl:if>
</xsl:element>
</xsl:template>
<xsl:template match="acl_user[role_ref]">
<!-- schema disallows role_ref's AND deny/reda/write -->
<xsl:element name="acl_target">
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="node()" />
</xsl:element>
</xsl:template>
<xsl:template match="acl_user[not(role_ref)]">
<xsl:element name="acl_target">
<xsl:for-each select="@*">
<xsl:apply-templates select="."/>
</xsl:for-each>
<xsl:if test="count(deny|read|write)" >
<xsl:element name="role">
<xsl:attribute name="id">
<xsl:text>auto-</xsl:text>
<xsl:value-of select="@id"/>
</xsl:attribute>
</xsl:element>
</xsl:if>
</xsl:element>
<xsl:if test="count(deny|read|write)" >
<xsl:element name="acl_role">
<xsl:attribute name="id">
<xsl:text>auto-</xsl:text>
<xsl:value-of select="@id"/>
</xsl:attribute>
<xsl:for-each select="node()">
<xsl:choose>
<xsl:when test="starts-with(name(), 'role_ref')"/>
<xsl:otherwise>
<xsl:apply-templates select="."/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</xsl:element>
</xsl:if>
</xsl:template>
<xsl:template match="@*">
<xsl:attribute name="{name()}">
<xsl:value-of select="."/>
</xsl:attribute>
</xsl:template>
<xsl:template match="/">
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="node()"/>
</xsl:template>
<xsl:template match="*">
<xsl:element name="{name()}">
<xsl:apply-templates select="@*"/>
<xsl:apply-templates select="node()" />
</xsl:element>
</xsl:template>
</xsl:stylesheet>
|