/usr/share/zsh/functions/Misc/ztodo is in zsh-common 5.1.1-1ubuntu2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 | # vim: set ft=zsh et sw=2 sts=2:
emulate -L zsh
setopt no_sh_word_split null_glob no_ksh_arrays
typeset -gHA __ztodolist
typeset -gH __ztodolastwrite
local cachefile short_format list_format
local tmp needupdate=0
local -a todos
zstyle -s ':ztodo:*' cache-file cachefile ||
cachefile="~/.ztodolist"
zstyle -s ':ztodo:*' short-format short_format ||
short_format="You have %n thing%1(n..s) to do here."
zstyle -s ':ztodo:*' list-format list_format ||
list_format="%-2n: %e"
tmp=(${~tmp::=$cachefile(ms-$(( ${(%)tmp::="%D{%s}"} - ${__ztodolastwrite:-0} )))})
(( $#tmp )) &&
. $~cachefile
todos=( ${(ps:\0:)__ztodolist[$PWD]} )
if (( $# )); then
case "$1" in
(add)
shift
todos=( $todos "$*" )
needupdate=1
;;
(del)
shift
todos[$1]=()
needupdate=1
;;
(clear)
shift
todos=()
needupdate=1
;;
(list)
shift
local i
for (( i = 1; i <= $#todos; i++ )); do
zformat -f tmp $list_format n:$i e:"${todos[$i]//\%/%%}"
print -P "$tmp"
done
;;
esac
else
if [[ $#todos -gt 0 ]]; then
zformat -f tmp $short_format n:$#todos
print -P "$tmp"
fi
fi
(( $#todos )) &&
__ztodolist[$PWD]=${(pj:\0:)todos} ||
unset "__ztodolist[$PWD]"
(( needupdate )) &&
print -r "__ztodolist=( ${(kv@qq)^^__ztodolist} )" > ${~cachefile}
__ztodolastwrite="${(%)tmp::="%D{%s}"}"
|