/usr/lib/x86_64-linux-gnu/qt5/qml/QtQuick/Controls/Styles/Base/DelayButtonStyle.qml is in qml-module-qtquick-controls 5.5.1-1ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 | /****************************************************************************
**
** Copyright (C) 2015 The Qt Company Ltd.
** Contact: http://www.qt.io/licensing/
**
** This file is part of the Qt Quick Extras module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:LGPL3$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or later as published by the Free
** Software Foundation and appearing in the file LICENSE.GPL included in
** the packaging of this file. Please review the following information to
** ensure the GNU General Public License version 2.0 requirements will be
** met: http://www.gnu.org/licenses/gpl-2.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.2
import QtGraphicalEffects 1.0
import QtQuick.Controls.Styles 1.4
import QtQuick.Extras 1.4
import QtQuick.Extras.Private.CppUtils 1.1
/*!
\qmltype DelayButtonStyle
\inqmlmodule QtQuick.Controls.Styles
\since 5.5
\ingroup controlsstyling
\brief Provides custom styling for DelayButton.
You can create a custom DelayButton by replacing the following delegates:
\list
\li \l foreground
\li \l {ButtonStyle::}{label}
\endlist
*/
CircularButtonStyle {
id: delayButtonStyle
/*!
The \l DelayButton that this style is attached to.
*/
readonly property DelayButton control: __control
/*!
The gradient of the progress bar around the button.
*/
property Gradient progressBarGradient: Gradient {
GradientStop {
position: 0
color: "#ff6666"
}
GradientStop {
position: 1
color: "#ff0000"
}
}
/*!
The color of the drop shadow under the progress bar.
*/
property color progressBarDropShadowColor: "#ff6666"
background: Item {
implicitWidth: __buttonHelper.implicitWidth
implicitHeight: __buttonHelper.implicitHeight
Canvas {
id: backgroundCanvas
anchors.fill: parent
Connections {
target: control
onPressedChanged: backgroundCanvas.requestPaint()
onCheckedChanged: backgroundCanvas.requestPaint()
}
onPaint: {
var ctx = getContext("2d");
__buttonHelper.paintBackground(ctx);
}
}
}
/*!
The foreground of the button.
The progress bar is drawn here.
*/
property Component foreground: Item {
id: foregroundItem
state: "normal"
states: [
State {
name: "normal"
PropertyChanges {
target: foregroundItem
opacity: 1
}
},
State {
name: "activated"
}
]
transitions: [
Transition {
from: "normal"
to: "activated"
SequentialAnimation {
loops: Animation.Infinite
NumberAnimation {
target: foregroundItem
property: "opacity"
from: 0.8
to: 0
duration: 500
easing.type: Easing.InOutSine
}
NumberAnimation {
target: foregroundItem
property: "opacity"
from: 0
to: 0.8
duration: 500
easing.type: Easing.InOutSine
}
}
}
]
Connections {
target: control
onActivated: state = "activated"
onCheckedChanged: if (!control.checked) state = "normal"
}
CircularProgressBar {
id: progressBar
visible: false
width: Math.min(parent.width, parent.height) + progressBarDropShadow.radius * 3 * 2
height: width
anchors.centerIn: parent
antialiasing: true
barWidth: __buttonHelper.outerArcLineWidth
inset: progressBarDropShadow.radius * 3
minimumValueAngle: -180
maximumValueAngle: 180
progress: control.progress
// TODO: Add gradient property if/when we drop support for building with 5.1.
function updateGradient() {
clearStops();
for (var i = 0; i < progressBarGradient.stops.length; ++i) {
addStop(progressBarGradient.stops[i].position, progressBarGradient.stops[i].color);
}
}
Component.onCompleted: updateGradient()
Connections {
target: delayButtonStyle
onProgressBarGradientChanged: progressBar.updateGradient()
}
}
DropShadow {
id: progressBarDropShadow
anchors.fill: progressBar
fast: true
// QTBUG-33747
// cached: !control.pressed
radius: 4
samples: radius * 2
color: progressBarDropShadowColor
source: progressBar
}
}
panel: Item {
implicitWidth: backgroundLoader.implicitWidth
implicitHeight: backgroundLoader.implicitHeight
Loader {
id: backgroundLoader
anchors.fill: parent
sourceComponent: background
}
Loader {
id: foregroundLoader
anchors.fill: parent
sourceComponent: foreground
}
Loader {
id: labelLoader
sourceComponent: label
anchors.fill: parent
anchors.leftMargin: padding.left
anchors.topMargin: padding.top
anchors.rightMargin: padding.right
anchors.bottomMargin: padding.bottom
}
}
}
|