/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/1.3/Icon.qml is in qml-module-ubuntu-components 1.3.1918+16.04.20160404-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 | /*
* Copyright (C) 2015 Canonical, Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*
* Authors: Zsombor Egri <zsombor.egri@canonical.com>
* Loic Molinari <loic.molinari@canonical.com>
*/
import QtQuick 2.4
/*!
\qmltype Icon
\inqmlmodule Ubuntu.Components 1.3
\inherits Item
\ingroup ubuntu
\brief The Icon component displays an icon from the icon theme.
The icon theme contains a set of standard icons referred to by their name.
Using icons whenever possible enhances consistency accross applications.
Each icon has a name and can have different visual representations depending
on the size requested.
Icons can also be colorized. Setting the \l color property will make all pixels
with the \l keyColor (by default #808080) colored.
Example:
\qml
Icon {
width: 64
height: 64
name: "search"
}
\endqml
Example of colorization:
\qml
Icon {
width: 64
height: 64
name: "search"
color: UbuntuColors.warmGrey
}
\endqml
Icon themes are created following the
\l{http://standards.freedesktop.org/icon-theme-spec/icon-theme-spec-latest.html}{Freedesktop Icon Theme Specification}.
*/
Item {
id: icon
/*!
The name of the icon to display.
\qmlproperty string Icon::name
If both name and source are set, name will be ignored.
\note The complete list of icons available in Ubuntu is not published yet.
For now please refer to the folders where the icon themes are installed:
\list
\li Ubuntu Touch: \l file:/usr/share/icons/suru
\li Ubuntu Desktop: \l file:/usr/share/icons/ubuntu-mono-dark
\endlist
These 2 separate icon themes will be merged soon.
*/
property string name
/*!
The color that all pixels that originally are of color \l keyColor should take.
\qmlproperty color Icon::color
*/
property alias color: colorizedImage.keyColorOut
/*!
The color of the pixels that should be colorized.
By default it is set to #808080.
\qmlproperty color Icon::keyColor
*/
property alias keyColor: colorizedImage.keyColorIn
/*!
The source url of the icon to display. It has precedence over name.
If both name and source are set, name will be ignored.
\since Ubuntu.Components 1.1
\qmlproperty url Icon::source
*/
property alias source: image.source
/*!
\qmlproperty bool Icon::asynchronous
The property drives the image loading of the icon. Defaults to false.
*/
property alias asynchronous: image.asynchronous
implicitWidth: image.implicitWidth
implicitHeight: image.implicitHeight
Image {
id: image
objectName: "image"
anchors.fill: parent
fillMode: Image.PreserveAspectFit
sourceSize {
width: icon.width
height: icon.height
}
source: icon.name ? "image://theme/%1".arg(icon.name) : ""
cache: true
visible: !colorizedImage.visible
asynchronous: false
}
ShaderEffect {
id: colorizedImage
objectName: "shader"
anchors.fill: parent
// Whether or not a color has been set.
visible: image.status == Image.Ready && keyColorOut != Qt.rgba(0.0, 0.0, 0.0, 0.0)
property Image source: image
property color keyColorOut: Qt.rgba(0.0, 0.0, 0.0, 0.0)
property color keyColorIn: "#808080"
property real threshold: 0.1
fragmentShader: "
varying highp vec2 qt_TexCoord0;
uniform sampler2D source;
uniform highp vec4 keyColorOut;
uniform highp vec4 keyColorIn;
uniform lowp float threshold;
uniform lowp float qt_Opacity;
void main() {
lowp vec4 sourceColor = texture2D(source, qt_TexCoord0);
gl_FragColor = mix(keyColorOut * vec4(sourceColor.a), sourceColor, step(threshold, distance(sourceColor.rgb / sourceColor.a, keyColorIn.rgb))) * qt_Opacity;
}"
}
}
|