/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/1.3/MainView.qml is in qml-module-ubuntu-components 1.3.1918+16.04.20160404-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 | /*
* Copyright 2012-2015 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3 as Toolkit
import Ubuntu.PerformanceMetrics 1.0
import QtQuick.Window 2.2
/*!
\qmltype MainView
\inqmlmodule Ubuntu.Components 1.3
\ingroup ubuntu
\inherits StyledItem
\brief MainView is the root Item that should be used for all applications.
The simplest way to use a MainView is to include a single \l Page object
inside the MainView:
\qml
import QtQuick 2.4
import Ubuntu.Components 1.3
MainView {
width: units.gu(48)
height: units.gu(60)
Page {
header: PageHeader {
id: pageHeader
title: "Simple page"
}
Button {
anchors {
horizontalCenter: parent.horizontalCenter
top: pageHeader.bottom
topMargin: units.gu(5)
}
width: units.gu(15)
text: "Push me"
onClicked: print("Click!")
}
}
}
\endqml
It is not required to set the anchors of the \l Page as it will automatically fill its parent.
Do not include multiple Pages directly inside the MainView, but use \l AdaptivePageLayout
inside MainView to navigate between several Pages.
If the \l Page inside the MainView includes a Flickable, set the flickable property of
the PageHeader to automatically hide and show the header when the user scrolls up or down:
\qml
import QtQuick 2.4
import Ubuntu.Components 1.3
MainView {
width: units.gu(48)
height: units.gu(60)
Page {
header: PageHeader {
title: "Page with Flickable"
flickable: myFlickable
}
Flickable {
id: myFlickable
anchors.fill: parent
contentHeight: column.height
Column {
id: column
Repeater {
model: 100
Label {
text: "line "+index
}
}
}
}
}
}
\endqml
The same header behavior is automatic when using a ListView instead of a Flickable in the above
example.
The examples above show how to include a single \l Page inside a MainView, but more
advanced application structures are possible using \l AdaptivePageLayout.
*/
Toolkit.MainViewBase {
id: mainView
/*! \deprecated */
property bool automaticOrientation: false
/*!
\internal
Use default property to ensure children added do not draw over the header.
*/
default property alias contentsItem: contents.data
Item {
id: canvas
anchors {
fill: parent
bottomMargin: mainView.anchorToKeyboard &&
UbuntuApplication.inputMethod.visible ?
UbuntuApplication.inputMethod.keyboardRectangle.height : 0
}
Item {
id: contents
anchors {
fill: parent
}
}
/*!
The header of the MainView. Can be used to obtain the height of the header
in \l Page to determine the area for the \l Page to fill.
*/
AppHeader {
// This objectName is used in the MainView autopilot custom proxy object
// in order to select the application header.
// Also used in tst_header_locked_visible.qml.
objectName: "MainView_Header"
id: headerItem
property real bottomY: headerItem.y + headerItem.height
dividerColor: Qt.darker(mainView.headerColor, 1.1)
panelColor: Qt.lighter(mainView.headerColor, 1.1)
backgroundColor: mainView.headerColor
title: internal.activePage ? internal.activePage.title : ""
pageStack: internal.activePage ? internal.activePage.pageStack : null
contents: internal.activePage &&
internal.activePage.hasOwnProperty("__customHeaderContents") ?
internal.activePage.__customHeaderContents : null
Toolkit.PageHeadConfiguration {
id: defaultConfig
// Used when there is no active Page, or a Page 1.0 is used which
// does not have a PageHeadConfiguration.
}
config: visible && internal.activePage &&
internal.activePage.hasOwnProperty("head") ?
internal.activePage.head : defaultConfig
// don't show the application header if the page has its own header.
visible: !(internal.activePage &&
internal.activePage.hasOwnProperty("header") &&
internal.activePage.header) &&
internal.activePage
height: visible ? implicitHeight : 0
// 'window' is defined by QML between startup and showing on the screen.
// There is no signal for when it becomes available and re-declaring it is not safe.
property bool windowActive: typeof window != 'undefined'
onWindowActiveChanged: {
window.title = headerItem.title
}
Connections {
target: headerItem
onTitleChanged: {
if (headerItem.windowActive)
window.title = headerItem.title
}
}
}
Connections {
target: Qt.application
onActiveChanged: {
if (Qt.application.active) {
if (!(headerItem.config &&
headerItem.config.hasOwnProperty("locked") &&
headerItem.config.locked)) {
headerItem.exposed = true;
}
}
}
}
}
Toolkit.Object {
id: internal
// Even when using MainView 1.1, we still support Page 1.0.
// PageBase (=Page 1.0) is the superclass of Page 1.1.
property Item activePage: isPage(mainView.activeLeafNode) ? mainView.activeLeafNode : null
function isPage(item) {
return item && item.hasOwnProperty("__isPageTreeNode") &&
item.__isPageTreeNode &&
item.hasOwnProperty("title") &&
item.hasOwnProperty("flickable") &&
item.hasOwnProperty("active") &&
item.hasOwnProperty("pageStack")
}
}
__propagated: QtObject {
/*!
\internal
The header that will be propagated to the children in the page tree node.
It is used by Tabs to bind header's tabsModel.
*/
property AppHeader header: headerItem
/*!
\internal
The action manager that has the global context for the MainView's actions,
and to which a local context can be added for each Page that has actions.actions.
*/
property var actionManager: mainView.actionManager
/*!
\internal
Used by PageStack. This property only exists in MainView 1.2 and later.
*/
readonly property bool animateHeader: false
}
backgroundColor: theme.palette.normal.background
PerformanceOverlay {
id: performanceOverlay
active: false
}
}
|