/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/1.3/UbuntuListView.qml is in qml-module-ubuntu-components 1.3.1918+16.04.20160404-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 | /*
* Copyright 2015 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3 as Toolkit
/*!
\qmltype UbuntuListView
\inqmlmodule Ubuntu.Components 1.1
\ingroup ubuntu
\inherits ListView
\brief A ListView with special features tailored for a look and feel fitting the
Ubuntu Touch platform.
The UbuntuListView works just like a regular ListView, but it adds special features
such as expanding/collapsing items (when used together with the Expandable item).
It provides features like automatically positioning the expanding item when it
expands and collapsing it again when the user taps outside of it.
Examples:
\qml
import Ubuntu.Components 1.3
import Ubuntu.Components.ListItems 1.3 as ListItem
Item {
ListModel {
id: listModel
}
UbuntuListView {
id: ubuntuListView
anchors { left: parent.left; right: parent.right }
height: units.gu(24)
model: listModel
delegate: ListItem.Expandable {
id: expandingItem
expandedHeight: units.gu(30)
onClicked: {
ubuntuListView.expandedIndex = index;
}
}
}
}
\endqml
*/
ListView {
id: root
/*!
\deprecated
The index of the currently expanded item. -1 if no item is expanded.
\b {THIS PROPERTY IS DEPRECATED. USE THE NEW ListItem TO HANDLE EXPANSION}
*/
property int expandedIndex: -1
/*!
\qmlproperty pullToRefresh UbuntuListView::pullToRefresh
\readonly
\since Ubuntu.Components 1.1
Attached PullToRefresh to control manual model refresh. The component is disabled
by default.
\qml
import QtQuick 2.4
import Ubuntu.Components 1.3
UbuntuListView {
width: units.gu(40)
height: units.gu(71)
model: XmlListModel {
source: "http://feeds.reuters.com/reuters/topNews"
query: "/rss/channel/item"
XmlRole { name: "title"; query: "title/string()" }
}
// let refresh control know when the refresh gets completed
pullToRefresh {
enable: true
refreshing: model.status === XmlListModel.Loading
onRefresh: model.reload()
}
delegate: ListItem {
ListItemLayout {
title.text: modelData
}
onClicked: {
ListView.view.model.reload();
}
}
}
\endqml
*/
readonly property alias pullToRefresh: refreshItem
PullToRefresh {
objectName: "listview_pulltorefresh"
id: refreshItem
enabled: false
}
QtObject {
id: priv
function positionViewAtIndexAnimated(expandedIndex) {
animation.from = root.contentY;
root.currentIndex = expandedIndex;
if (expandedIndex == root.count - 1) {
root.positionViewAtIndex(expandedIndex, ListView.End);
} else {
root.positionViewAtIndex(expandedIndex + 1, ListView.End);
}
var effectiveExpandedHeight = Math.min(root.currentItem.expandedHeight, root.height - root.currentItem.collapsedHeight);
if (root.contentY - root.originY == 0) {
if (((root.currentIndex + 1) * root.currentItem.collapsedHeight) + effectiveExpandedHeight > root.height) {
animation.to = ((root.currentIndex + 1) * root.currentItem.collapsedHeight + effectiveExpandedHeight) - root.height + root.originY
} else {
animation.to = root.originY
}
} else {
animation.to = root.contentY + (effectiveExpandedHeight - root.currentItem.collapsedHeight);
}
animation.start();
}
function requestFocus(reason) {
// lookup for the currentItem, and if it is a FocusScope, focus the view
// this will also focus the currentItem
if (root.currentItem && root.currentItem.hasOwnProperty("activeFocusOnPress")) {
// is the currentItem a ListItem?
if (QuickUtils.inherits(root.currentItem, "UCListItem")) {
root.currentItem.requestFocus(reason);
} else {
root.forceActiveFocus(reason);
}
}
}
}
focus: true
/*!
\internal
Grab focus when moved, flicked or clicked
*/
onMovementStarted: priv.requestFocus(Qt.MouseFocusReason)
onFlickStarted: priv.requestFocus(Qt.MouseFocusReason)
Toolkit.Mouse.onClicked: priv.requestFocus(Qt.MouseFocusReason)
/*!
Expand the item at the given index.
*/
onExpandedIndexChanged: {
if (expandedIndex < 0) {
return;
}
priv.positionViewAtIndexAnimated(expandedIndex, ListView.End)
}
UbuntuNumberAnimation {
id: animation
target: root
property: "contentY"
}
MouseArea {
parent: contentItem
anchors.fill: parent
z: 2
enabled: root.expandedIndex != -1
onClicked: root.expandedIndex = -1;
}
// animate move displaced
moveDisplaced: Transition {
UbuntuNumberAnimation {
properties: "x,y"
}
}
// highlight current item
highlight: Rectangle {
color: theme.palette.selected.background
}
highlightMoveDuration: 0
}
|