/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/Themes/Ambiance/1.3/BottomEdgeStyle.qml is in ubuntu-ui-toolkit-theme 1.3.1918+16.04.20160404-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 | /*
* Copyright (C) 2015 Canonical, Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3
import Ubuntu.Components.Styles 1.3
BottomEdgeStyle {
id: bottomEdgeStyle
//setup properties
property BottomEdge bottomEdge: styledItem
panel: panelItem
panelAnimation: panelBehavior
revealThreshold: bottomEdge.hint.height + units.gu(2)
//deprecated for now
contentItem: bottomEdge.contentItem
// own styling properties
property color backgroundColor: !panelItem.collapsing
? Qt.rgba(0, 0, 0, Math.min(0.25, (height - revealThreshold - panelItem.y) / (height - revealThreshold)))
: "transparent"
property color panelColor: theme.palette.normal.overlay
property color shadowColor: "#000000"
anchors.fill: parent
Rectangle {
id: background
anchors.fill: parent
color: backgroundColor
z: -1
}
Rectangle {
id: panelItem
objectName: "bottomedge_panel"
property bool collapsing: false
anchors {
left: parent.left
right: parent.right
top: parent.bottom
topMargin: bottomEdge.status >= BottomEdge.Revealed
? -(bottomEdge.height * bottomEdge.dragProgress)
: 0
}
height: bottomEdge.contentItem ? bottomEdge.contentItem.height : 0
color: panelColor
opacity: bottomEdge.status >= BottomEdge.Revealed ? 1.0 : 0.0
Behavior on anchors.topMargin { UbuntuNumberAnimation { id: panelBehavior } }
Connections {
target: bottomEdge
onCollapseStarted: panelItem.collapsing = true
onCollapseCompleted: panelItem.collapsing = false
}
state: bottomEdge.status > BottomEdge.Hidden ? "drop-hint" : ""
states: [
State {
name: "drop-hint"
PropertyChanges {
target: bottomEdge.hint
restoreEntryValues: false
status: BottomEdgeHint.Inactive
}
}
]
// shadows
Rectangle {
id: topShadow
anchors {
bottom: parent.top
left: parent.left
right: parent.right
}
height: units.gu(1.5)
gradient: Gradient {
GradientStop { position: 0.0; color: Qt.rgba(shadowColor.r, shadowColor.g, shadowColor.b, 0.0) }
GradientStop { position: 0.75; color: Qt.rgba(shadowColor.r, shadowColor.g, shadowColor.b, 0.05) }
GradientStop { position: 1.0; color: Qt.rgba(shadowColor.r, shadowColor.g, shadowColor.b, 0.1) }
}
}
Rectangle {
id: bottomShadow
anchors {
top: parent.bottom
left: parent.left
right: parent.right
}
height: units.gu(1.5)
rotation: 180
gradient: Gradient {
GradientStop { position: 0.0; color: Qt.rgba(shadowColor.r, shadowColor.g, shadowColor.b, 0.0) }
GradientStop { position: 0.75; color: Qt.rgba(shadowColor.r, shadowColor.g, shadowColor.b, 0.05) }
GradientStop { position: 1.0; color: Qt.rgba(shadowColor.r, shadowColor.g, shadowColor.b, 0.1) }
}
}
}
}
|