/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/Themes/Ambiance/1.3/BubbleShape.qml is in ubuntu-ui-toolkit-theme 1.3.1918+16.04.20160404-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 | /*
* Copyright 2016 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3
Item {
id: bubbleShape
/*!
Do not use an UbuntuShape but a Rectangle as the background of the BubbleShape.
*/
property bool square: false
/*!
The background color of the bubble.
*/
property color color: square
? theme.palette.normal.background
: theme.palette.normal.overlay
property point target
property string direction: "down"
property bool clipContent: false
default property alias children: content.children
implicitWidth: units.gu(10)
implicitHeight: units.gu(8)
signal showCompleted()
signal hideCompleted()
opacity: 0.0
function show() {
hideAnimation.stop();
showAnimation.start();
}
function hide() {
showAnimation.stop();
hideAnimation.start();
}
ParallelAnimation {
id: showAnimation
NumberAnimation {
target: bubbleShape
property: "opacity"
from: 0.0
to: 1.0
duration: UbuntuAnimation.FastDuration
easing: UbuntuAnimation.StandardEasing
}
NumberAnimation {
target: scaleTransform
property: (direction === "up" || direction === "down") ? "yScale" : "xScale"
from: 0.91
to: 1.0
duration: UbuntuAnimation.FastDuration
easing: UbuntuAnimation.StandardEasing
}
onStopped: showCompleted()
}
NumberAnimation {
id: hideAnimation
target: bubbleShape
property: "opacity"
from: 1.0
to: 0.0
duration: UbuntuAnimation.FastDuration
easing: UbuntuAnimation.StandardEasing
onStopped: hideCompleted()
}
transform: Scale {
id: scaleTransform
origin.x: direction === "right" ? bubbleShape.width :
direction === "left" ? 0 :
bubbleShape.width/2.0
origin.y: direction === "up" ? 0 :
direction === "down" ? bubbleShape.height :
bubbleShape.height/2.0
}
BorderImage {
id: shadow
anchors.fill: parent
anchors.margins: square ? -units.gu(1) : -units.dp(2)
anchors.topMargin: square ? 0 : anchors.margins
source: !square ? Qt.resolvedUrl("../artwork/bubble_shadow.sci") : Qt.resolvedUrl("../artwork/header_overflow_dropshadow.sci")
opacity: 0.8
}
UbuntuShape {
anchors.fill: parent
aspect: UbuntuShape.Flat
backgroundColor: bubbleShape.color
source: bubbleShape.clipContent ? shapeSource : null
visible: !square
}
ShaderEffectSource {
id: shapeSource
visible: bubbleShape.clipContent
sourceItem: bubbleShape.clipContent ? content : null
hideSource: !square
// FIXME: visible: false prevents rendering so make it a nearly
// transparent 1x1 pixel instead
opacity: 0.01
width: 1
height: 1
}
Item {
id: content
anchors.fill: parent
Rectangle {
id: colorRect
anchors.fill: parent
color: bubbleShape.color
visible: bubbleShape.clipContent
}
}
}
|