/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/Themes/Ambiance/1.3/OverflowPanel.qml is in ubuntu-ui-toolkit-theme 1.3.1918+16.04.20160404-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 | /*
* Copyright 2015 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components.Popups 1.3
import Ubuntu.Components 1.3
import Ubuntu.Components.ListItems 1.3 as ListItem
/*!
\internal
*/
ActionSelectionPopover {
id: overflow
// clicks next to the overflow panel must only close the panel,
// not trigger additional events.
grabDismissAreaEvents: true
/*!
The background color of the tabs panel and the actions overflow panel.
*/
property color backgroundColor: theme.palette.normal.background
/*!
The background color of the tapped item in the panel.
*/
property color highlightColor: theme.palette.highlighted.background
/*!
The foreground color (icon and text) of actions in the panel.
*/
property color foregroundColor: styledItem.enabled
? theme.palette.normal.backgroundText
: theme.palette.disabled.backgroundText
property bool square: true
callerMargin: -units.gu(1) + units.dp(4)
contentWidth: units.gu(20)
Binding {
target: overflow.__foreground.__styleInstance
property: "color"
value: overflow.backgroundColor
when: overflow.__foreground &&
overflow.__foreground.__styleInstance
}
delegate: AbstractButton {
id: actionButton
action: modelData
// close after triggering the action.
onClicked: overflow.hide()
implicitHeight: units.gu(6) + bottomDividerLine.height
width: parent ? parent.width : units.gu(31)
Rectangle {
visible: parent.pressed
anchors {
left: parent.left
right: parent.right
top: parent.top
}
height: parent.height - bottomDividerLine.height
color: overflow.highlightColor
}
Icon {
id: actionIcon
visible: "" != action.iconSource
source: action.iconSource
color: overflow.foregroundColor
anchors {
verticalCenter: parent.verticalCenter
verticalCenterOffset: units.dp(-1)
left: parent.left
leftMargin: units.gu(2)
}
width: units.gu(2)
height: units.gu(2)
}
Label {
anchors {
verticalCenter: parent.verticalCenter
verticalCenterOffset: units.dp(-1)
left: actionIcon.visible ? actionIcon.right : parent.left
leftMargin: units.gu(2)
right: parent.right
}
// In the tabs overflow panel there are no icons, and the font-size
// is medium as opposed to the small font-size in the actions overflow panel.
textSize: actionIcon.visible ? Label.Small : Label.Medium
elide: Text.ElideRight
text: action.text
color: overflow.foregroundColor
}
// The value of showDivider is automatically set by ActionSelectionPopover.
property bool showDivider
ListItem.ThinDivider {
id: bottomDividerLine
anchors.bottom: parent.bottom
visible: actionButton.showDivider
}
}
}
|