/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/Themes/Ambiance/1.3/SectionsForPageHeadStyle.qml is in ubuntu-ui-toolkit-theme 1.3.1918+16.04.20160404-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 | /*
* Copyright 2016 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3
Item {
id: sectionsStyle
implicitWidth: sectionsRow.width
implicitHeight: units.gu(4)
enabled: styledItem.enabled
/*!
The foreground color of unselected sections.
*/
property color sectionColor: enabled
? theme.palette.normal.backgroundTertiaryText
: theme.palette.disabled.backgroundTertiaryText
/*!
The foreground color of the selected section.
*/
property color selectedSectionColor: enabled
? theme.palette.selected.backgroundTertiaryText
: theme.palette.selectedDisabled.backgroundTertiaryText
/*!
The background color for the pressed section button.
*/
property color pressedBackgroundColor: theme.palette.highlighted.background
/*!
The font size for the text in the buttons.
*/
property int textSize: Label.Small
/*!
The spacing on the left and right sides of the label
inside a section button.
*/
property real horizontalLabelSpacing: units.gu(2)
/*!
The height of the bar underlining the sections.
*/
property real underlineHeight: units.dp(2)
Row {
id: sectionsRow
anchors {
top: parent.top
bottom: parent.bottom
horizontalCenter: parent.horizontalCenter
}
width: childrenRect.width
Repeater {
id: sectionsRepeater
model: styledItem.model
objectName: "sections_repeater"
AbstractButton {
id: sectionButton
anchors {
top: parent ? parent.top : undefined
bottom: parent ? parent.bottom : undefined
}
objectName: "section_button_" + index
width: label.width + 2 * sectionsStyle.horizontalLabelSpacing
height: sectionsRow.height
property bool selected: index === styledItem.selectedIndex
onClicked: styledItem.selectedIndex = index
// Background pressed highlight
Rectangle {
visible: parent.pressed
anchors.fill: parent
color: sectionsStyle.pressedBackgroundColor
}
// Section title
Label {
id: label
objectName: "section_button_label_" + index
// modelData may be either a string, or an Action
text: modelData.hasOwnProperty("text") ? modelData.text : modelData
textSize: sectionsStyle.textSize
anchors.centerIn: parent
color: sectionButton.selected ?
sectionsStyle.selectedSectionColor :
sectionsStyle.sectionColor
}
// Section title underline
Rectangle {
anchors {
bottom: parent.bottom
left: parent.left
right: parent.right
}
height: sectionsStyle.underlineHeight
color: sectionButton.selected ?
sectionsStyle.selectedSectionColor :
sectionsStyle.sectionColor
}
}
}
}
}
|