/usr/share/webbrowser-app/webcontainer/WebApp.qml is in webapp-container 0.23+16.04.20160413-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 | /*
* Copyright 2013-2016 Canonical Ltd.
*
* This file is part of webbrowser-app.
*
* webbrowser-app is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* webbrowser-app is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import com.canonical.Oxide 1.5 as Oxide
import Ubuntu.Components 1.3
import Ubuntu.Unity.Action 1.1 as UnityActions
import Ubuntu.UnityWebApps 0.1 as UnityWebApps
import Qt.labs.settings 1.0
import "../actions" as Actions
import ".."
import "ColorUtils.js" as ColorUtils
BrowserView {
id: webapp
objectName: "webappBrowserView"
currentWebview: containerWebView.currentWebview
property alias url: containerWebView.url
property bool accountSwitcher
property string webappModelSearchPath: ""
property var webappUrlPatterns
property alias popupRedirectionUrlPrefixPattern: containerWebView.popupRedirectionUrlPrefixPattern
property alias webviewOverrideFile: containerWebView.webviewOverrideFile
property alias blockOpenExternalUrls: containerWebView.blockOpenExternalUrls
property alias localUserAgentOverride: containerWebView.localUserAgentOverride
property alias dataPath: containerWebView.dataPath
property alias runningLocalApplication: containerWebView.runningLocalApplication
property alias openExternalUrlInOverlay: containerWebView.openExternalUrlInOverlay
property string webappName: ""
property bool backForwardButtonsVisible: false
property bool chromeVisible: false
readonly property bool chromeless: !chromeVisible && !backForwardButtonsVisible && !accountSwitcher
readonly property real themeColorTextContrastFactor: 3.0
signal chooseAccount()
// Used for testing. There is a bug that currently prevents non visual Qt objects
// to be introspectable from AP which makes directly accessing the settings object
// not possible https://bugs.launchpad.net/autopilot-qt/+bug/1273956
property alias generatedUrlPatterns: urlPatternSettings.generatedUrlPatterns
actions: [
Actions.Back {
enabled: webapp.backForwardButtonsVisible && containerWebView.currentWebview && containerWebView.currentWebview.canGoBack
onTriggered: containerWebView.currentWebview.goBack()
},
Actions.Forward {
enabled: webapp.backForwardButtonsVisible && containerWebView.currentWebview && containerWebView.currentWebview.canGoForward
onTriggered: containerWebView.currentWebview.goForward()
},
Actions.Reload {
onTriggered: containerWebView.currentWebview.reload()
}
]
Settings {
id: urlPatternSettings
property string generatedUrlPatterns
}
function addGeneratedUrlPattern(urlPattern) {
if (urlPattern.trim().length === 0) {
return;
}
var patterns = []
if (urlPatternSettings.generatedUrlPatterns
&& urlPatternSettings.generatedUrlPatterns.trim().length !== 0) {
try {
patterns = JSON.parse(urlPatternSettings.generatedUrlPatterns)
} catch(e) {
console.error("Invalid JSON content found in url patterns file")
}
if (! (patterns instanceof Array)) {
console.error("Invalid JSON content type found in url patterns file (not an array)")
patterns = []
}
}
if (patterns.indexOf(urlPattern) < 0) {
patterns.push(urlPattern)
urlPatternSettings.generatedUrlPatterns = JSON.stringify(patterns)
}
}
function mergeUrlPatternSets(p1, p2) {
if ( ! (p1 instanceof Array)) {
return (p2 instanceof Array) ? p2 : []
}
if ( ! (p2 instanceof Array)) {
return (p1 instanceof Array) ? p1 : []
}
var p1hash = {}
var result = []
for (var i1 in p1) {
p1hash[p1[i1]] = 1
result.push(p1[i1])
}
for (var i2 in p2) {
if (! (p2[i2] in p1hash)) {
result.push(p2[i2])
}
}
return result
}
Item {
id: webviewContainer
anchors.fill: parent
WebappContainerWebview {
id: containerWebView
objectName: "webview"
wide: webapp.wide
anchors {
left: parent.left
right: parent.right
top: parent.top
}
height: parent.height - osk.height
developerExtrasEnabled: webapp.developerExtrasEnabled
onThemeColorMetaInformationDetected: {
var color = webappContainerHelper.rgbColorFromCSSColor(theme_color)
if (!webapp.chromeless && chromeLoader.item && color.length) {
chromeLoader.item.backgroundColor = theme_color
chromeLoader.item.chromeTextLabelColor =
ColorUtils.getMostConstrastedColor(
color,
Qt.darker(theme_color, themeColorTextContrastFactor),
Qt.lighter(theme_color, themeColorTextContrastFactor))
}
}
onSamlRequestUrlPatternReceived: {
addGeneratedUrlPattern(urlPattern)
}
webappUrlPatterns: mergeUrlPatternSets(urlPatternSettings.generatedUrlPatterns,
webapp.webappUrlPatterns)
/**
* Use the --webapp parameter value w/ precedence, but also take into account
* the fact that a webapp 'name' can come from a webapp-properties.json file w/o
* being explictly defined here.
*/
webappName: webapp.webappName === "" ? unityWebapps.name : webapp.webappName
Loader {
anchors {
fill: containerWebView
topMargin: (!webapp.chromeless && chromeLoader.item.state == "shown")
? chromeLoader.item.height
: 0
}
active: containerWebView.currentWebview &&
(webProcessMonitor.crashed || (webProcessMonitor.killed && !containerWebView.currentWebview.loading))
sourceComponent: SadPage {
webview: containerWebView.currentWebview
objectName: "mainWebviewSadPage"
}
WebProcessMonitor {
id: webProcessMonitor
webview: containerWebView.currentWebview
}
asynchronous: true
}
}
Loader {
anchors {
fill: containerWebView
topMargin: (!webapp.chromeless && chromeLoader.item.state == "shown") ? chromeLoader.item.height : 0
}
sourceComponent: ErrorSheet {
visible: containerWebView.currentWebview && containerWebView.currentWebview.lastLoadFailed
url: containerWebView.currentWebview ? containerWebView.currentWebview.url : ""
onRefreshClicked: {
if (containerWebView.currentWebview)
containerWebView.currentWebview.reload()
}
}
asynchronous: true
}
Loader {
id: chromeLoader
anchors {
top: parent.top
left: parent.left
right: parent.right
}
sourceComponent: webapp.chromeless ? progressbarComponent : chromeComponent
Component {
id: chromeComponent
Chrome {
webview: webapp.currentWebview
navigationButtonsVisible: webapp.backForwardButtonsVisible
accountSwitcher: webapp.accountSwitcher
anchors {
left: parent.left
right: parent.right
}
height: units.gu(6)
y: webapp.currentWebview ? containerWebView.currentWebview.locationBarController.offset : 0
onChooseAccount: webapp.chooseAccount()
}
}
Component {
id: progressbarComponent
ThinProgressBar {
webview: webapp.currentWebview
anchors {
left: parent.left
right: parent.right
top: parent.top
}
}
}
}
Binding {
when: webapp.currentWebview && !webapp.chromeless
target: webapp.currentWebview ? webapp.currentWebview.locationBarController : null
property: 'height'
value: webapp.currentWebview.visible ? chromeLoader.item.height : 0
}
ChromeController {
webview: webapp.currentWebview
forceHide: webapp.chromeless
defaultMode: webapp.hasTouchScreen
? Oxide.LocationBarController.ModeAuto
: Oxide.LocationBarController.ModeShown
}
}
UnityWebApps.UnityWebApps {
id: unityWebapps
name: webappName
bindee: containerWebView.currentWebview
actionsContext: actionManager.globalContext
model: UnityWebApps.UnityWebappsAppModel { searchPath: webappModelSearchPath }
injectExtraUbuntuApis: runningLocalApplication
injectExtraContentShareCapabilities: !runningLocalApplication
}
}
|