/usr/share/perl5/Dancer2/Core/Role/Serializer.pm is in libdancer2-perl 0.166001+dfsg-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 | package Dancer2::Core::Role::Serializer;
# ABSTRACT: Role for Serializer engines
$Dancer2::Core::Role::Serializer::VERSION = '0.166001';
use Moo::Role;
use Dancer2::Core::Types;
use Scalar::Util 'blessed';
with 'Dancer2::Core::Role::Engine';
sub hook_aliases {
{
before_serializer => 'engine.serializer.before',
after_serializer => 'engine.serializer.after',
}
}
sub supported_hooks { values %{ shift->hook_aliases } }
sub _build_type {'Serializer'}
requires 'serialize';
requires 'deserialize';
has log_cb => (
is => 'ro',
isa => CodeRef,
default => sub { sub {1} },
);
has content_type => (
is => 'ro',
isa => Str,
required => 1,
writer => 'set_content_type'
);
around serialize => sub {
my ( $orig, $self, $content, $options ) = @_;
blessed $self && $self->execute_hook( 'engine.serializer.before', $content );
$content or return $content;
my $data;
eval {
$data = $self->$orig( $content, $options );
blessed $self
and $self->execute_hook( 'engine.serializer.after', $data );
1;
} or do {
my $error = $@ || 'Zombie Error';
blessed $self
and $self->log_cb->( core => "Failed to serialize the request: $error" );
};
return $data;
};
around deserialize => sub {
my ( $orig, $self, $content, $options ) = @_;
$content && length $content > 0
or return $content;
my $data;
eval {
$data = $self->$orig($content, $options);
1;
} or do {
my $error = $@ || 'Zombie Error';
$self->log_cb->( core => "Failed to deserialize the request: $error" );
};
return $data;
};
# most serializer don't have to overload this one
sub support_content_type {
my ( $self, $ct ) = @_;
return unless $ct;
my @toks = split ';', $ct;
$ct = lc( $toks[0] );
return $ct eq $self->content_type;
}
1;
__END__
=pod
=encoding UTF-8
=head1 NAME
Dancer2::Core::Role::Serializer - Role for Serializer engines
=head1 VERSION
version 0.166001
=head1 DESCRIPTION
Any class that consumes this role will be able to be used as a
serializer under Dancer2.
In order to implement this role, the consumer B<must> implement the
methods C<serialize> and C<deserialize>, and should define
the C<content_type> attribute value.
=head1 ATTRIBUTES
=head2 content_type
The I<content type> of the object after being serialized. For example,
a JSON serializer would have a I<application/json> content type
defined.
=head1 METHODS
=head2 serialize($content, [\%options])
The serialize method need to be implemented by the consumer. It
receives the serializer class object and a reference to the object to
be serialized. Should return the object after being serialized, in the
content type defined by the C<content_type> attribute.
A third optional argument is a hash reference of options to the
serializer.
The serialize method must return bytes and therefore has to handle any
encoding.
=head2 deserialize($content, [\%options])
The inverse method of C<serialize>. Receives the serializer class
object and a string that should be deserialized. The method should
return a reference to the deserialized Perl data structure.
A third optional argument is a hash reference of options to the
serializer.
The deserialize method receives encoded bytes and must therefore
handle any decoding required.
=head1 METHODS
=head1 AUTHOR
Dancer Core Developers
=head1 COPYRIGHT AND LICENSE
This software is copyright (c) 2015 by Alexis Sukrieh.
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
=cut
|