/usr/share/perl5/Mojolicious/Command/routes.pm is in libmojolicious-perl 6.15+dfsg-1ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 | package Mojolicious::Command::routes;
use Mojo::Base 'Mojolicious::Command';
use re 'regexp_pattern';
use Getopt::Long qw(GetOptionsFromArray :config no_auto_abbrev no_ignore_case);
use Mojo::Util qw(encode tablify);
has description => 'Show available routes';
has usage => sub { shift->extract_usage };
sub run {
my ($self, @args) = @_;
GetOptionsFromArray \@args, 'v|verbose' => \my $verbose;
my $rows = [];
_walk($_, 0, $rows, $verbose) for @{$self->app->routes->children};
print encode('UTF-8', tablify($rows));
}
sub _walk {
my ($route, $depth, $rows, $verbose) = @_;
# Pattern
my $prefix = '';
if (my $i = $depth * 2) { $prefix .= ' ' x $i . '+' }
push @$rows, my $row = [$prefix . ($route->pattern->unparsed || '/')];
# Flags
my @flags;
push @flags, @{$route->over || []} ? 'C' : '.';
push @flags, (my $partial = $route->partial) ? 'D' : '.';
push @flags, $route->inline ? 'U' : '.';
push @flags, $route->is_websocket ? 'W' : '.';
push @$row, join('', @flags) if $verbose;
# Methods
my $via = $route->via;
push @$row, !$via ? '*' : uc join ',', @$via;
# Name
my $name = $route->name;
push @$row, $route->has_custom_name ? qq{"$name"} : $name;
# Regex (verbose)
my $pattern = $route->pattern;
$pattern->match('/', $route->is_endpoint && !$partial);
my $regex = (regexp_pattern $pattern->regex)[0];
my $format = (regexp_pattern($pattern->format_regex))[0];
push @$row, $regex, $format ? $format : '' if $verbose;
$depth++;
_walk($_, $depth, $rows, $verbose) for @{$route->children};
$depth--;
}
1;
=encoding utf8
=head1 NAME
Mojolicious::Command::routes - Routes command
=head1 SYNOPSIS
Usage: APPLICATION routes [OPTIONS]
Options:
-v, --verbose Print additional details about routes, flags indicate
C=Conditions, D=Detour, U=Under and W=WebSocket
=head1 DESCRIPTION
L<Mojolicious::Command::routes> lists all your application routes.
This is a core command, that means it is always enabled and its code a good
example for learning to build new commands, you're welcome to fork it.
See L<Mojolicious::Commands/"COMMANDS"> for a list of commands that are
available by default.
=head1 ATTRIBUTES
L<Mojolicious::Command::routes> inherits all attributes from
L<Mojolicious::Command> and implements the following new ones.
=head2 description
my $description = $routes->description;
$routes = $routes->description('Foo');
Short description of this command, used for the command list.
=head2 usage
my $usage = $routes->usage;
$routes = $routes->usage('Foo');
Usage information for this command, used for the help screen.
=head1 METHODS
L<Mojolicious::Command::routes> inherits all methods from
L<Mojolicious::Command> and implements the following new ones.
=head2 run
$routes->run(@ARGV);
Run this command.
=head1 SEE ALSO
L<Mojolicious>, L<Mojolicious::Guides>, L<http://mojolicio.us>.
=cut
|