/usr/share/perl5/Paranoid/Network/IPv6.pm is in libparanoid-perl 0.36-3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 | # Paranoid::Network::IPv6 -- IPv6-specific network functions
#
# (c) 2012, Arthur Corliss <corliss@digitalmages.com>
#
# $Id: IPv6.pm,v 0.3 2012/09/24 23:20:22 acorliss Exp $
#
# This software is licensed under the same terms as Perl, itself.
# Please see http://dev.perl.org/licenses/ for more information.
#
#####################################################################
#####################################################################
#
# Environment definitions
#
#####################################################################
package Paranoid::Network::IPv6;
use 5.006;
use strict;
use warnings;
use vars qw($VERSION @EXPORT @EXPORT_OK %EXPORT_TAGS);
use base qw(Exporter);
use Paranoid::Debug qw(:all);
use Paranoid::Network::Socket;
use Carp;
my @base = qw(ipv6NetConvert ipv6NetPacked ipv6NetIntersect);
my @constants = qw(MAXIPV6CIDR IPV6REGEX IPV6CIDRRGX IPV6BASE IPV6BRDCST
IPV6MASK);
my @ipv6sort = qw(ipv6StrSort ipv6PackedSort ipv6NumSort);
($VERSION) = ( q$Revision: 0.3 $ =~ /(\d+(?:\.(\d+))+)/sm );
@EXPORT = @base;
@EXPORT_OK = ( @base, @constants, @ipv6sort );
%EXPORT_TAGS = (
all => [@EXPORT_OK],
base => [@base],
constants => [@constants],
ipv6Sort => [@ipv6sort],
);
use constant MAXIPV6CIDR => 128;
use constant IPV6REGEX => qr/
:(?::[abcdef\d]{1,4}){1,7} |
[abcdef\d]{1,4}(?:::?[abcdef\d]{1,4}){1,7} |
(?:[abcdef\d]{1,4}:){1,7}:
/smix;
use constant IPV6CIDRRGX => qr#(@{[ IPV6REGEX ]})(?:/(\d+))?#sm;
use constant IPV6BASE => 0;
use constant IPV6BRDCST => 1;
use constant IPV6MASK => 2;
use constant CHUNKMASK => 0xffffffff;
use constant CHUNK => 32;
use constant IPV6CHUNKS => 4;
use constant IPV6LENGTH => 16;
#####################################################################
#
# Module code follows
#
#####################################################################
sub ipv6NetConvert ($) {
# Purpose: Takes a string representation of an IPv6 network
# address and returns a list of lists containing
# the binary network address, broadcast address,
# and netmask, each broken into 32bit chunks.
# Also allows for a plain IP being passed, in which
# case it only returns the binary IP.
# Returns: Array, empty on errors
# Usage: @network = ipv6NetConvert($netAddr);
my $netAddr = shift;
my $n = defined $netAddr ? $netAddr : 'undef';
my ( $bnet, $bmask, @tmp, @rv );
pdebug( "entering w/$n", PDLEVEL1 );
pIn();
if ( has_ipv6() or $] >= 5.012 ) {
# Extract net address, mask
if ( defined $netAddr ) {
( $bnet, $bmask ) = ( $netAddr =~ m#^@{[ IPV6CIDRRGX ]}$#sm );
}
if ( defined $bnet and length $bnet ) {
# First, convert $bnet to see if we have a valid IP address
$bnet = [ unpack 'NNNN', inet_pton( AF_INET6(), $bnet ) ];
if ( defined $bnet and length $bnet ) {
# Save our network address
push @rv, $bnet;
if ( defined $bmask and length $bmask ) {
# Convert netmask
if ( $bmask <= MAXIPV6CIDR ) {
# Add the mask in 32-bit chunks
@tmp = ();
while ( $bmask >= CHUNK ) {
push @tmp, CHUNKMASK;
$bmask -= CHUNK;
}
# Push the final segment if there's a remainder
if ($bmask) {
push @tmp,
CHUNKMASK - ( ( 2**( CHUNK - $bmask ) ) - 1 );
}
# Add zero'd chunks to fill it out
while ( @tmp < IPV6CHUNKS ) {
push @tmp, 0x0;
}
# Finally, save the chunks
$bmask = [@tmp];
} else {
$bmask = undef;
}
if ( defined $bmask ) {
# Apply the mask to the base address
foreach ( 0 .. ( IPV6CHUNKS - 1 ) ) {
$$bnet[$_] &= $$bmask[$_];
}
# Calculate and save our broadcast address
@tmp = ();
foreach ( 0 .. ( IPV6CHUNKS - 1 ) ) {
$tmp[$_] =
$$bnet[$_] | ( $$bmask[$_] ^ CHUNKMASK );
}
push @rv, [@tmp];
# Save our mask
push @rv, $bmask;
} else {
pdebug( 'invalid netmask passed', PDLEVEL1 );
}
}
} else {
pdebug( 'failed to convert IPv6 address', PDLEVEL1 );
}
} else {
pdebug( 'failed to extract an IPv6 address', PDLEVEL1 );
}
} else {
pdebug( 'IPv6 support not present', PDLEVEL1 );
}
pOut();
pdebug( "leaving w/rv: @rv", PDLEVEL1 );
return @rv;
}
sub ipv6NetPacked ($) {
# Purpose: Wrapper script for ipv6NetConvert that repacks all of its
# 32bit chunks into opaque strings in network-byte order.
# Returns: Array
# Usage: @network = ipv6NetPacked($netAddr);
my $netAddr = shift;
my $n = defined $netAddr ? $netAddr : 'undef';
my @rv;
pdebug( "entering w/$n", PDLEVEL1 );
pIn();
@rv = ipv6NetConvert($netAddr);
foreach (@rv) {
$_ = pack 'NNNN', @$_;
}
pOut();
pdebug( "leaving w/@rv", PDLEVEL1 );
return @rv;
}
sub _cmpArrays ($$) {
# Purpose: Compares IPv6 chunked address arrays
# Returns: -1: net1 < net 2
# 0: net1 == net2
# 1: net1 > net2
# Usage: $rv = _cmpArrays( $aref1, $aref2 );
my $aref1 = shift;
my $aref2 = shift;
my $rv = 0;
pdebug( "entering w/$aref1, $aref2", PDLEVEL2 );
pIn();
while ( scalar @$aref1 ) {
unless ( $$aref1[0] == $$aref2[0] ) {
$rv = $$aref1[0] > $$aref2[0] ? 1 : -1;
last;
}
shift @$aref1;
shift @$aref2;
}
pOut();
pdebug( "leaving w/rv: $rv", PDLEVEL2 );
return $rv;
}
sub ipv6NetIntersect (@) {
# Purpose: Tests whether network address ranges intersect
# Returns: Integer, denoting whether an intersection exists, and what
# kind:
#
# -1: destination range encompasses target range
# 0: both ranges do not intersect at all
# 1: target range encompasses destination range
#
# Usage: $rv = ipv6NetIntersect($net1, $net2);
my $tgt = shift;
my $dest = shift;
my $t = defined $tgt ? $tgt : 'undef';
my $d = defined $dest ? $dest : 'undef';
my $rv = 0;
my ( @tnet, @dnet );
pdebug( "entering w/$t, $d", PDLEVEL1 );
pIn();
# Bypas if one or both isn't defined -- obviously no intersection
unless ( !defined $tgt or !defined $dest ) {
# Treat any array references as IPv6 addresses already translated into
# 32bit integer chunks
@tnet = ref($tgt) eq 'ARRAY' ? $tgt : ipv6NetConvert($tgt);
@dnet = ref($dest) eq 'ARRAY' ? $dest : ipv6NetConvert($dest);
# insert bogus numbers for non IP-address info
@tnet = ( [ -1, 0, 0, 0 ] ) unless scalar @tnet;
@dnet = ( [ -2, 0, 0, 0 ] ) unless scalar @dnet;
# Dummy up broadcast address for those single IPs passed (in lieu of
# network ranges)
if ( $#tnet == 0 ) {
$tnet[IPV6BRDCST] = $tnet[IPV6BASE];
$tnet[IPV6MASK] = [ CHUNKMASK, CHUNKMASK, CHUNKMASK, CHUNKMASK ];
}
if ( $#dnet == 0 ) {
$dnet[IPV6BRDCST] = $dnet[IPV6BASE];
$dnet[IPV6MASK] = [ CHUNKMASK, CHUNKMASK, CHUNKMASK, CHUNKMASK ];
}
if ( _cmpArrays( $tnet[IPV6BASE], $dnet[IPV6BASE] ) <= 0
and _cmpArrays( $tnet[IPV6BRDCST], $dnet[IPV6BRDCST] ) >= 0 ) {
# Target fully encapsulates dest
$rv = 1;
} elsif ( _cmpArrays( $tnet[IPV6BASE], $dnet[IPV6BASE] ) >= 0
and _cmpArrays( $tnet[IPV6BRDCST], $dnet[IPV6BRDCST] ) <= 0 ) {
# Dest fully encapsulates target
$rv = -1;
}
}
pOut();
pdebug( "leaving w/rv: $rv", PDLEVEL1 );
return $rv;
}
{
no strict 'refs';
sub ipv6NumSort {
# Purpose: Sorts IPv6 addresses represented in numeric form
# Returns: -1, 0, 1
# Usage: @sorted = sort &ipv6NumSort @ipv4;
my ($pkg) = caller;
my ( $i, $rv );
foreach $i ( 0 .. 3 ) {
$rv = $${"${pkg}::a"}[$i] <=> $${"${pkg}::b"}[$i];
last if $rv;
}
return $rv;
}
sub ipv6PackedSort {
# Purpose: Sorts IPv6 addresses represented by packed strings
# Returns: -1, 0, 1
# Usage: @sorted = sort &ipv6PackedSort @ipv6;
no warnings 'once';
my ($pkg) = caller;
$a = [ unpack 'NNNN', ${"${pkg}::a"} ];
$b = [ unpack 'NNNN', ${"${pkg}::b"} ];
return ipv6NumSort();
}
sub ipv6StrSort {
# Purpose: Sorts IPv6 addresses represented in string form
# Returns: -1, 0, 1
# Usage: @sorted = sort &ipv4StrSort @ipv4;
my ($pkg) = caller;
my $a1 = ${"${pkg}::a"};
my $b1 = ${"${pkg}::b"};
my ( $i, $rv );
$a1 =~ s#/.+##sm;
$a1 = [ unpack 'NNNN', inet_pton( AF_INET6(), $a1 ) ];
$b1 =~ s#/.+##sm;
$b1 = [ unpack 'NNNN', inet_pton( AF_INET6(), $b1 ) ];
foreach $i ( 0 .. 3 ) {
$rv = $$a1[$i] <=> $$b1[$i];
last if $rv;
}
return $rv;
}
}
1;
__END__
=head1 NAME
Paranoid::Network::IPv6 - IPv6-related functions
=head1 VERSION
$Id: IPv6.pm,v 0.3 2012/09/24 23:20:22 acorliss Exp $
=head1 SYNOPSIS
use Paranoid::Network::IPv6;
@net = ipv6NetConvert($netAddr);
$rv = ipv6NetIntersect($net1, $net2);
or
use Paranoid::Network::IPv6 qw(:all);
print "Valid IP address\n" if $netAddr =~ /^@{[ IPV6REGEX ]}$/;
@net = ipv6NetConvert($netAddr);
$broadcast = $net[IPV6BRDCST];
use Paranoid::Network::IPv6 qw(:ipv6Sort);
@nets = sort ipv6StrSort @nets;
@nets = sort ipv6PackedSort @nets;
@nets = sort ipv6NumSort @nets;
=head1 DESCRIPTION
This module contains a few convenience functions for working with IPv6
addresses.
By default only B<ipv6NetConvert>, B<ipv6NetPacked>, and
B<ipv4NetIntersect> are imported. Other symbol sets are:
Name Description
---------------------------------------------
all all functions/constants
base default exported functions
constants constants
ipv6Sort sort functions
=head1 SUBROUTINES/METHODS
=head2 ipv6NetConvert
@net = ipv6NetConvert($netAddr);
This function takes an IPv4 network address in string format and converts it
into and array of arrays. The arrays will contain the base network address,
the broadcast address, and the netmask, each split into native 32bit integer
format chunks. Each sub array is essentially what you would get from:
@chunks = unpack 'NNNN', inet_pton(AF_INET6, '::1');
using '::1' as the sample IPv6 address.
The network address must have the netmask in CIDR format. In the case of a
single IP address, the array with only have one subarray, that of the IP
itself, split into 32bit integers.
Passing any argument to this function that is not a string representation of
an IP address (including undef values) will cause this function to return an
empty array.
=head2 ipv6NetPacked
@net = ipv6NetPacked('fe80::/64');
This function is a wrapper for B<ipv6NetConvert>, but instead of subarrays
each element is the packed (opaque) string as returned by B<inet_pton>.
=head2 ipv6NetIntersect
$rv = ipv6NetIntersect($net1, $net2);
This function tests whether an IP or subnet intersects with another IP or
subnet. The return value is essentially boolean, but the true value can vary
to indicate which is a subset of the other:
-1: destination range encompasses target range
0: both ranges do not intersect at all
1: target range encompasses destination range
The function handles the same string formats as B<ipv6NetConvert>, but will
allow you to test single IPs in integer format as well.
=head2 ipv6StrSort
@sorted = sort ipv6StrSort @nets;
This function allows IPv6 addresses and networks to be passed in string
format. Networks can be in CIDR format. Sorts in ascending order.
:w
=head2 ipv6PackedSort
@sorted = sort ipv6PackedSort @nets;
This function sorts addresses that are in packed format, such as returned by
L<inet_pton>. Sorts in ascending order.
=head2 ipv6NumSort
@sorted = sort ipv6NumSort @nets;
This function sorts addresses that are in unpacked, native integer format, such
as one gets from:
@ip = unpack 'NNNN', inet_pton(AF_INET6, $ipAddr);
Sorts in ascending order. List of addresses should be a list of lists.
=head1 CONSTANTS
These are only imported if explicity requested or with the B<:all> tag.
=head2 MAXIPV6CIDR
Simply put: 128. This is the largest CIDR notation supported in IPv6.
=head2 IPV6REGEX
Regular expression:
qr/
:(?::[abcdef\d]{1,4}){1,7} |
[abcdef\d]{1,4}(?:::?[abcdef\d]{1,4}){1,7} |
(?:[abcdef\d]{1,4}:){1,7}:
/smix;
You can use this for validating IP addresses as such:
$ip =~ m#^@{[ IPV6REGEX ]}$#;
or to extract potential IPs from extraneous text:
(@ips) = ( $string =~ m#(@{[ IPV6REGEX ]})#g);
=head2 IPV6CIDRRGX
Regular expression:
qr#(@{[ IPV6REGEX ]})(?:/(\d+))?#sm
By default this will extract an IP or CIDR notation network address:
($net, $mask) = ( $ip =~ m#^@{[ IPV6CIDRRGX ]}$# );
In the case of a simple IP address B<$mask> will be undefined.
=head2 IPV6BASE
This is the ordinal index of the base network address as returned by
B<ipv6NetConvert>.
=head2 IPV6BRDCST
This is the ordinal index of the broadcast address as returned by
B<ipv6NetConvert>.
=head2 IPV6MASK
This is the ordinal index of the network mask as returned by
B<ipv6NetConvert>.
=head1 DEPENDENCIES
=over
=item o
L<Paranoid>
=item o
L<Paranoid::Network::Socket>
=back
=head1 BUGS AND LIMITATIONS
=head1 AUTHOR
Arthur Corliss (corliss@digitalmages.com)
=head1 LICENSE AND COPYRIGHT
This software is licensed under the same terms as Perl, itself.
Please see http://dev.perl.org/licenses/ for more information.
(c) 2012, Arthur Corliss (corliss@digitalmages.com)
|