/usr/share/puppet/modules.available/ironic/manifests/db.pp is in puppet-module-ironic 7.0.0-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 | # == Class: ironic::db
#
# Configure the Ironic database
#
# === Parameters
#
# [*database_connection*]
# Url used to connect to database.
# (Optional) Defaults to 'sqlite:////var/lib/ironic/ovs.sqlite'.
#
# [*database_idle_timeout*]
# Timeout when db connections should be reaped.
# (Optional) Defaults to 3600.
#
# [*database_max_retries*]
# Maximum db connection retries during startup.
# Setting -1 implies an infinite retry count.
# (Optional) Defaults to 10.
#
# [*database_retry_interval*]
# Interval between retries of opening a sql connection.
# (Optional) Defaults to 10.
#
# [*database_min_pool_size*]
# Minimum number of SQL connections to keep open in a pool.
# (Optional) Defaults to 1.
#
# [*database_max_pool_size*]
# Maximum number of SQL connections to keep open in a pool.
# (Optional) Defaults to 10.
#
# [*database_max_overflow*]
# If set, use this value for max_overflow with sqlalchemy.
# (Optional) Defaults to 20.
#
class ironic::db (
$database_connection = 'sqlite:////var/lib/ironic/ovs.sqlite',
$database_idle_timeout = 3600,
$database_max_retries = 10,
$database_retry_interval = 10,
$database_min_pool_size = 1,
$database_max_pool_size = 10,
$database_max_overflow = 20,
) {
# NOTE(spredzy): In order to keep backward compatibility we rely on the pick function
# to use ironic::<myparam> if ironic::db::<myparam> isn't specified.
$database_connection_real = pick($::ironic::database_connection, $database_connection)
$database_idle_timeout_real = pick($::ironic::database_idle_timeout, $database_idle_timeout)
$database_max_retries_real = pick($::ironic::database_max_retries, $database_max_retries)
$database_retry_interval_real = pick($::ironic::database_retry_interval, $database_retry_interval)
$database_min_pool_size_real = pick($::ironic::database_min_pool_size, $database_min_pool_size)
$database_max_pool_size_real = pick($::ironic::database_max_pool_size, $database_max_pool_size)
$database_max_overflow_real = pick($::ironic::database_max_overflow, $database_max_overflow)
validate_re($database_connection_real,
'(sqlite|mysql|postgresql):\/\/(\S+:\S+@\S+\/\S+)?')
if $database_connection_real {
case $database_connection_real {
/^mysql:\/\//: {
$backend_package = false
require 'mysql::bindings'
require 'mysql::bindings::python'
}
/^postgresql:\/\//: {
$backend_package = false
require 'postgresql::lib::python'
}
/^sqlite:\/\//: {
$backend_package = $::ironic::params::sqlite_package_name
}
default: {
fail('Unsupported backend configured')
}
}
if $backend_package and !defined(Package[$backend_package]) {
package {'ironic-backend-package':
ensure => present,
name => $backend_package,
tag => 'openstack',
}
}
ironic_config {
'database/connection': value => $database_connection_real, secret => true;
'database/idle_timeout': value => $database_idle_timeout_real;
'database/max_retries': value => $database_max_retries_real;
'database/retry_interval': value => $database_retry_interval_real;
'database/min_pool_size': value => $database_min_pool_size_real;
'database/max_pool_size': value => $database_max_pool_size_real;
'database/max_overflow': value => $database_max_overflow_real;
}
}
}
|