/usr/share/unity8/Dash/DashNavigation.qml is in unity8-common 8.12+16.04.20160401-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 | /*
* Copyright (C) 2014,2015 Canonical, Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.3
import Dash 0.1
Item {
id: root
objectName: "dashNavigation"
// set by parent
property var scope: null
property real availableHeight
signal leafClicked()
// internal
readonly property var currentNavigation: scope && scope.hasNavigation ? scope.getNavigation(scope.currentNavigationId) : null
// Are we drilling down the tree or up?
property bool isEnteringChildren: false
visible: height != 0
implicitHeight: scope && scope.hasNavigation ? navigationListView.y + navigationListView.height : 0
function resetNavigation() {
if (navigationModel.count > 1) {
clear();
}
}
Column {
id: headersColumn
anchors {
top: parent.top
left: parent.left
right: parent.right
}
function pop(popsNeeded) {
if (popsNeeded == 0)
return;
isEnteringChildren = false;
navigationListView.currentIndex = navigationListView.currentIndex - popsNeeded;
navigationModel.setProperty(navigationListView.currentIndex, "nullifyNavigation", false);
navigationModel.remove(navigationModel.count - popsNeeded, popsNeeded);
popsNeeded = Math.min(headersModel.count, popsNeeded);
// This is effectively deleting ourselves, so needs to be the last thing of the function
headersModel.remove(headersModel.count - popsNeeded, popsNeeded);
}
Repeater {
model: ListModel {
id: headersModel
// Roles
// headerText: the text to show
// navigationId: the navigation Id that represents
// parentNavigationId: the parent navigation Id
}
delegate: DashNavigationHeader {
objectName: "dashNavigationHeader" + index
height: index == 0 && headersModel.count > 1 ? 0 : units.gu(5)
width: headersColumn.width
backVisible: index != 0
text: headerText
onBackClicked: {
scope.setNavigationState(parentNavigationId);
var popsNeeded = headersModel.count - index;
headersColumn.pop(popsNeeded);
}
onTextClicked: {
scope.setNavigationState(navigationId);
var popsNeeded = headersModel.count - index - 1;
headersColumn.pop(popsNeeded);
root.leafClicked();
}
}
}
}
ListView {
id: navigationListView
objectName: "navigationListView"
orientation: ListView.Horizontal
interactive: false
model: ListModel {
id: navigationModel
// We have two roles
// navigationId: the navigation id of the navigation the list represents
// nullifyNavigation: overrides navigationId to be null
// This is used to "clear" the delegate when going "right" on the tree
}
anchors {
top: headersColumn.bottom
left: parent.left
right: parent.right
}
readonly property int maxHeight: root.availableHeight - navigationListView.y
property int prevHeight: maxHeight
height: currentItem ? currentItem.height : maxHeight
onHeightChanged: {
if (currentItem) {
prevHeight = currentItem.desiredHeight;
}
}
highlightMoveDuration: UbuntuAnimation.FastDuration
delegate: DashNavigationList {
objectName: "navigation" + index
visible: height > 0
width: navigationListView.width
property real desiredHeight: {
if (navigation && navigation.loaded && x == navigationListView.contentX)
{
return Math.min(implicitHeight, navigationListView.maxHeight);
} else {
return navigationListView.prevHeight;
}
}
height: desiredHeight
navigation: (nullifyNavigation || !scope) ? null : scope.getNavigation(navigationId)
currentNavigation: root.currentNavigation
onEnterNavigation: { // var newNavigationId, string newNavigationLabel, bool hasChildren
scope.setNavigationState(newNavigationId);
// We only need to add a new item to the model
// if we have children, otherwise just load it
if (hasChildren) {
isEnteringChildren = true;
navigationModel.append({"navigationId": newNavigationId, "nullifyNavigation": false});
headersModel.append({"headerText": newNavigationLabel,
"navigationId": newNavigationId,
"parentNavigationId": navigationId
});
navigationListView.currentIndex++;
} else {
root.leafClicked();
}
}
}
onContentXChanged: {
if (navigationListView.highlightMoveDuration == 0)
return;
if (contentX == width * navigationListView.currentIndex) {
if (isEnteringChildren) {
navigationModel.setProperty(navigationListView.currentIndex - 1, "nullifyNavigation", true);
}
}
}
}
property bool isFirstLoad: false
onScopeChanged: clear();
function clear() {
navigationModel.clear();
headersModel.clear();
isFirstLoad = true;
}
function setNewNavigation() {
if (isFirstLoad && currentNavigation && currentNavigation.loaded) {
isFirstLoad = false;
if (currentNavigation.count > 0) {
navigationModel.append({"navigationId": scope.currentNavigationId, "nullifyNavigation": false});
} else {
navigationModel.append({"navigationId": currentNavigation.parentNavigationId, "nullifyNavigation": false});
}
headersModel.append({"headerText": currentNavigation.allLabel != "" ? currentNavigation.allLabel : currentNavigation.label,
"navigationId": currentNavigation.navigationId,
"parentNavigationId": currentNavigation.parentNavigationId
});
}
}
Connections {
target: currentNavigation
onLoadedChanged: setNewNavigation();
}
onCurrentNavigationChanged: setNewNavigation();
}
|