/usr/lib/ats2-postiats-0.2.6/libats/DATS/hashtbl_linprb.dats is in ats2-lang 0.2.6-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486 487 488 489 490 491 492 493 494 495 496 497 498 499 500 501 502 503 504 505 506 507 508 509 510 511 512 513 514 515 516 517 518 519 520 521 522 523 524 525 526 527 528 529 530 531 532 533 534 535 536 537 538 539 540 541 542 543 544 545 546 547 548 549 550 551 552 553 554 555 556 557 558 559 560 561 562 563 564 565 566 567 568 569 570 571 572 573 574 575 576 577 578 579 580 581 582 583 584 585 586 587 588 589 590 591 592 593 594 595 596 597 598 599 600 601 602 603 604 605 606 607 608 609 610 611 612 613 614 615 616 617 618 619 620 621 622 623 624 625 626 627 628 629 630 631 632 633 634 635 636 637 638 639 640 641 642 643 644 645 646 647 648 649 650 651 652 653 654 655 656 657 658 659 660 661 662 663 664 665 666 667 668 669 670 671 672 673 674 675 676 677 678 679 680 681 682 683 684 685 686 687 688 689 690 691 692 693 694 695 696 697 698 699 700 701 702 703 704 705 706 707 708 709 710 711 712 713 714 715 716 717 718 719 720 | (***********************************************************************)
(* *)
(* Applied Type System *)
(* *)
(***********************************************************************)
(*
** ATS/Postiats - Unleashing the Potential of Types!
** Copyright (C) 2011-2014 Hongwei Xi, ATS Trustful Software, Inc.
** All rights reserved
**
** ATS is free software; you can redistribute it and/or modify it under
** the terms of the GNU GENERAL PUBLIC LICENSE (GPL) as published by the
** Free Software Foundation; either version 3, or (at your option) any
** later version.
**
** ATS is distributed in the hope that it will be useful, but WITHOUT ANY
** WARRANTY; without even the implied warranty of MERCHANTABILITY or
** FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
** for more details.
**
** You should have received a copy of the GNU General Public License
** along with ATS; see the file COPYING. If not, please write to the
** Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
** 02110-1301, USA.
*)
(* ****** ****** *)
(* Author: Hongwei Xi *)
(* Authoremail: hwxi AT cs DOT bu DOT edu *)
(* Start time: May, 2014 *)
(* ****** ****** *)
#define ATS_PACKNAME "ATSLIB.libats.hashtbl_linprb"
#define ATS_DYNLOADFLAG 0 // no need for dynloading at run-time
#define ATS_EXTERN_PREFIX "atslib_" // prefix for external names
(* ****** ****** *)
staload
UN = "prelude/SATS/unsafe.sats"
(* ****** ****** *)
staload
STRING = "libc/SATS/string.sats"
(* ****** ****** *)
staload "libats/SATS/hashfun.sats"
(* ****** ****** *)
staload "libats/SATS/hashtbl_linprb.sats"
(* ****** ****** *)
#include "./SHARE/hashtbl.hats" // code reuse
(* ****** ****** *)
implement
{key,itm}
hashtbl_linprb_keyitm_nullize (kx) = let
vtypedef ki = @(key, itm)
val _(*ptr*) =
$STRING.memset_unsafe(addr@(kx), 0, sizeof<ki>)
prval () =
__assert (kx) where
{
extern praxi __assert (&(ki)? >> _): void
} (* end of [prval] *)
in
// nothing
end // end of [hashtbl_linprb_keyitm_nullize]
(* ****** ****** *)
implement(itm)
hashtbl_linprb_keyitm_is_null<string,itm> (kx) = (string2ptr(kx.0) = 0)
(* ****** ****** *)
extern
fun{
key:t0p;
itm:vt0p
} keyitmarr_linprb{m:int}
(
A: &array((key,itm), m), cap: size_t(m), k0: key, ans: &bool? >> _
) : Ptr0 // end of [keyitmarr_linprb]
(* ****** ****** *)
implement
{key,itm}
keyitmarr_linprb
{m}(A, cap, k0, ans) = let
//
val p0 = addr@(A)
vtypedef ki = @(key, itm)
val p_end = ptr_add<ki> (p0, cap)
//
fun loop
(
p: ptr, ans: &bool? >> _
) : ptr =
(
if
p < p_end
then let
val (pf, fpf | p) =
$UN.ptr0_vtake{ki}(p)
val isnul =
hashtbl_linprb_keyitm_is_null<key,itm> (!p)
prval ((*void*)) = fpf (pf)
in
if isnul
then let
val () = ans := false in p
end // end of [then]
else let
val (pf, fpf | p) =
$UN.ptr0_vtake{ki}(p)
val keq = equal_key_key<key> (k0, p->0)
prval ((*void*)) = fpf (pf)
in
if keq
then let
val () = ans := true in p
end // end of [then]
else loop (ptr_succ<ki> (p), ans)
// end of [if]
end // end of [else]
// end of [if]
end // end of [then]
else let
val () = ans := false in the_null_ptr
end // end of [else]
)
//
val p_kx = loop(addr@(A), ans)
//
in
g1ofg0 (p_kx) // it needs to be of the type [Ptr0]
end // end of [keyitmarr_linprb]
(* ****** ****** *)
extern
fun{
key:t0p;
itm:vt0p
} keyitmarr_linprb2
{m:int}{ofs:int | ofs <= m}
(
A: &array((key,itm), m), cap: size_t(m), ofs: size_t(ofs), k0: key, ans: &bool? >> _
) : Ptr0 // end of [keyitmarr_linprb2]
(* ****** ****** *)
implement
{key,itm}
keyitmarr_linprb2
{m}{ofs}
(
A, cap, ofs, k0, ans
) = let
//
val p0 = addr@(A)
vtypedef ki = @(key, itm)
val p1 = ptr_add<ki> (p0, ofs)
//
stadef n1 = ofs and n2 = m - ofs
//
val (pf, fpf | p1) = $UN.ptr0_vtake{array(ki,n2)}(p1)
val p_kx = keyitmarr_linprb<key,itm> (!p1, cap - ofs, k0, ans)
prval () = fpf (pf)
//
in
//
if p_kx > 0
then p_kx
else let
val (pf, fpf | p0) = $UN.ptr0_vtake{array(ki,n1)}(p0)
val p_kx = keyitmarr_linprb<key,itm> (!p0, ofs, k0, ans)
prval () = fpf (pf)
in
p_kx
end // end of [else]
// end of [if]
//
end // end of [keyitmarr_linprb2]
(* ****** ****** *)
extern
fun{
key:t0p;
itm:vt0p
} keyitmarr_reinserts
{m:int}
(
A: &array((key,itm), m) >> _, cap: size_t(m), p_kx: ptr
) : void // end of [keyitmarr_reinserts]
(* ****** ****** *)
implement
{key,itm}
keyitmarr_reinserts
{m}(A, cap, p_kx) = let
//
val p0 = addr@(A)
vtypedef ki = @(key, itm)
val p_end = ptr_add<ki> (p0, cap)
//
fun
loop
(
A: &array(ki, m) >> _, cap: size_t(m), p_kx: ptr
) : bool = let
in
//
if
p_kx < p_end
then let
//
val (pf, fpf | p_kx) = $UN.ptr0_vtake{ki}(p_kx)
val isnul =
hashtbl_linprb_keyitm_is_null<key,itm> (!p_kx)
//
in
if isnul
then let
prval () = fpf (pf) in true(*stopped*)
end // end of [then]
else let
val k = p_kx->0
val hk = hash_key<key> (k)
val ofs = g0uint_mod (hk, $UN.cast{ulint}(cap))
val ofs = $UN.cast{sizeLt(m)}(ofs)
//
var ans: bool // uninitized
val p2_kx = keyitmarr_linprb2<key,itm> (A, cap, ofs, k, ans)
//
in
if ans
then let
prval () = fpf (pf)
in
loop (A, cap, ptr_succ<ki> (p_kx))
end // end of [then]
else let
val (pf2, fpf2 | p2_kx) = $UN.ptr0_vtake{ki?}(p2_kx)
val () = p2_kx->0 := p_kx->0
val () = p2_kx->1 := p_kx->1
val () = hashtbl_linprb_keyitm_nullize<key,itm> (!p_kx)
prval () = $UN.castview0((pf, fpf))
prval () = $UN.castview0((pf2, fpf2))
in
loop (A, cap, ptr_succ<ki> (p_kx))
end // end of [else]
// end of [if]
end // end of [else]
// end of [if]
end // end of [then]
else false (*~stopped*)
//
end // end of [loop]
//
val stopped = loop (A, cap, p_kx)
val _(*true*) =
(
if not(stopped) then loop (A, cap, p0) else true
) : bool // end of [val]
//
in
// nothing
end // end of [keyitmarr_reinserts]
(* ****** ****** *)
datavtype hashtbl
(
key:t@ype, itm:vt@ype+
) =
{m:int | m >= 1}
HASHTBL of (
arrayptr ((key, itm), m), size_t m, size_t(*ntot*)
) (* end of [HASHTBL] *)
// end of [hashtbl]
(* ****** ****** *)
assume
hashtbl_vtype (key:t0p, itm:vt0p) = hashtbl (key, itm)
(* ****** ****** *)
implement
{key,itm}
hashtbl_make_nil
(cap) = let
//
vtypedef ki = @(key, itm)
//
prval
[m:int]
EQINT () = eqint_make_guint (cap)
//
val A0 =
arrayptr_make_uninitized<ki> (cap)
val p_A0 = ptrcast(A0)
val _(*ptr*) =
$STRING.memset_unsafe (p_A0, 0, cap*sizeof<ki>)
val A0 = $UN.castvwtp0{arrayptr(ki,m)}(A0)
//
in
HASHTBL (A0, cap, i2sz(0))
end // end of [hashtbl_make_nil]
(* ****** ****** *)
implement{
} hashtbl_get_size
(tbl) = let
//
val+HASHTBL(A, cap, ntot) = tbl in ntot
//
end // end of [hashtbl_get_size]
(* ****** ****** *)
implement{
} hashtbl_get_capacity
(tbl) = let
//
val+HASHTBL (A, cap, ntot) = tbl in (cap)
//
end // end of [hashtbl_get_capacity]
(* ****** ****** *)
implement
{key,itm}
hashtbl_search_ref
(tbl, k0) = let
//
val+HASHTBL{..}{m}(A, cap, ntot) = tbl
//
val hk = hash_key<key> (k0)
val ofs = g0uint_mod (hk, $UN.cast{ulint}(cap))
val ofs = $UN.cast{sizeLt(m)}(ofs)
//
val p_A = ptrcast(A)
prval pf_A = arrayptr_takeout(A)
var ans: bool // uninitalized
val p_kx = keyitmarr_linprb2<key,itm> (!p_A, cap, ofs, k0, ans)
prval ((*void*)) = arrayptr_addback (pf_A | A)
//
in
//
if ans then let
vtypedef ki = @(key, itm)
val (pf, fpf | p_kx) = $UN.ptr0_vtake{ki}(p_kx)
val p_itm = addr@(p_kx->1)
prval ((*void*)) = fpf (pf)
in
$UN.cast{cPtr1(itm)}(p_itm)
end else cptr_null{itm}((*void*))
//
end // end of [hashtbl_search_ref]
(* ****** ****** *)
implement
{key,itm}
hashtbl_insert
(tbl, k, x, res) = let
//
vtypedef ki = @(key, itm)
//
val+@HASHTBL{..}{m}(A, cap, ntot) = tbl
//
val hk = hash_key<key> (k)
val ofs = g0uint_mod (hk, $UN.cast{ulint}(cap))
val ofs = $UN.cast{sizeLt(m)}(ofs)
//
val p_A = ptrcast(A)
prval pf_A = arrayptr_takeout(A)
var ans: bool // uninitalized
val p_kx = keyitmarr_linprb2<key,itm> (!p_A, cap, ofs, k, ans)
prval ((*void*)) = arrayptr_addback (pf_A | A)
//
in
//
if ans
then let
val (pf, fpf | p_kx) = $UN.ptr0_vtake{ki}(p_kx)
val x2 = p_kx->1
val () = p_kx->1 := x
prval ((*void*)) = fpf (pf)
val () = res := x2
prval () = opt_some{itm}(res)
prval () = fold@ (tbl)
in
true
end // end of [then]
else let
//
// HX-2013-05: [k] is not found
//
in
if p_kx > 0 then let
val (pf, fpf | p_kx) = $UN.ptr0_vtake{ki?}(p_kx)
val () = p_kx->0 := k
val () = p_kx->1 := x
val () = ntot := succ(ntot)
prval () = $UN.castview0((pf, fpf))
prval () = opt_none{itm}(res)
prval () = fold@ (tbl)
val () =
if hashtbl$recapacitize() > 0
then ignoret(hashtbl_adjust_capacity<key,itm> (tbl))
// end of [if] // end of [val]
in
false
end else let
val () = res := x
prval () = opt_some{itm}(res)
prval () = fold@ (tbl)
in
true
end // end of [if]
end // end of [else]
//
end // end of [hashtbl_insert]
(* ****** ****** *)
implement
{key,itm}
hashtbl_takeout
(tbl, k, res) = let
//
val+@HASHTBL{..}{m}(A, cap, ntot) = tbl
//
val hk = hash_key<key> (k)
val ofs = g0uint_mod (hk, $UN.cast{ulint}(cap))
val ofs = $UN.cast{sizeLt(m)}(ofs)
//
val p_A = ptrcast(A)
prval pf_A = arrayptr_takeout(A)
var ans: bool // uninitalized
val p_kx = keyitmarr_linprb2<key,itm> (!p_A, cap, ofs, k, ans)
prval ((*void*)) = arrayptr_addback (pf_A | A)
//
in
//
if ans
then let
vtypedef ki = @(key, itm)
val (pf, fpf | p_kx) = $UN.ptr0_vtake{ki}(p_kx)
val () = res := p_kx->1
val () = hashtbl_linprb_keyitm_nullize<key,itm> (!p_kx)
val () = ntot := pred (ntot)
prval () = $UN.castview0 ((pf, fpf))
prval pf_A = arrayptr_takeout(A)
val () = keyitmarr_reinserts<key,itm> (!p_A, cap, ptr_succ<ki> (p_kx))
prval ((*void*)) = arrayptr_addback (pf_A | A)
prval () = fold@ (tbl)
prval () = opt_some{itm}(res)
in
true
end // end of [then]
else let
prval () = fold@ (tbl)
prval () = opt_none{itm}(res)
in
false
end // end of [else]
//
end // end of [hashtbl_takeout]
(* ****** ****** *)
implement
{key,itm}
hashtbl_reset_capacity
(tbl, cap2) = let
//
val+@HASHTBL{..}{m}(A, cap, ntot) = tbl
//
in
//
if
ntot <= cap2
then let
//
val p0 = ptrcast(A)
vtypedef ki = @(key, itm)
val p_end = ptr_add<ki> (p0, cap)
//
fun
loop{m2:int}
(
p_A2: ptr, cap2: size_t(m2), p: ptr
) : void = let
in
//
if
p < p_end
then let
val (pf, fpf | p) =
$UN.ptr0_vtake{ki}(p)
val isnul =
hashtbl_linprb_keyitm_is_null<key,itm> (!p)
in
if isnul
then let
prval ((*void*)) = fpf (pf)
in
loop (p_A2, cap2, ptr_succ<ki> (p))
end // end of [then]
else let
val k = p->0
val hk = hash_key<key> (k)
var ans: bool // uninitalized
val ofs = g0uint_mod (hk, $UN.cast{ulint}(cap2))
val ofs = $UN.cast{sizeLt(m2)}(ofs)
val (pf_A2, fpf_A2 | p_A2) = $UN.ptr0_vtake{array(ki,m2)}(p_A2)
val p_kx = keyitmarr_linprb2<key,itm> (!p_A2, cap2, ofs, k, ans)
prval ((*void*)) = fpf_A2 (pf_A2)
val (pf_kx, fpf_kx | p_kx) = $UN.ptr0_vtake{ki?}(p_kx)
val () = p_kx->0 := k
val () = p_kx->1 := p->1
prval () = $UN.castview0((pf, fpf))
prval () = $UN.castview0((pf_kx, fpf_kx))
in
loop (p_A2, cap2, ptr_succ<ki> (p))
end // end of [else]
end // end of [then]
else () // end of [else]
//
end // end of [loop]
//
prval
[m2:int]
EQINT () = eqint_make_guint (cap2)
//
val A2 =
arrayptr_make_uninitized<ki> (cap2)
val p_A2 = ptrcast(A2)
val _(*ptr*) =
$STRING.memset_unsafe (p_A2, 0, cap2*sizeof<ki>)
val ((*void*)) = loop (p_A2, cap2, p0)
val A2 = $UN.castvwtp0{arrayptr(ki,m2)}(A2)
//
val () =
arrayptr_free ($UN.castvwtp0{arrayptr(ki?,m)}(A))
//
val () = A := A2
val () = cap := cap2
prval () = fold@ (tbl)
//
in
true
end // end of [then]
else let
prval () = fold@ (tbl)
in
false
end // end of [else]
//
end // end of [hashtbl_reset_capacity]
(* ****** ****** *)
//
// HX: please reimplement it if needed
//
implement
{key,itm}
hashtbl_adjust_capacity
(tbl) = let
//
val+HASHTBL (A, cap, ntot) = tbl
//
in
//
if ntot + ntot >= cap
then hashtbl_reset_capacity (tbl, cap + cap) else false
//
end // end of [hashtbl_adjust_capacity]
(* ****** ****** *)
implement
{key,itm}{env}
hashtbl_foreach_env
(tbl, env) = let
//
val+HASHTBL (A, cap, _) = tbl
//
val p0 = ptrcast(A)
vtypedef ki = @(key, itm)
val p_end = ptr_add<ki> (p0, cap)
//
fun
loop
(
p: ptr, env: &env >> _
) : void = let
in
//
if
p < p_end
then let
val (pf, fpf | p) =
$UN.ptr0_vtake{ki}(p)
val isnul =
hashtbl_linprb_keyitm_is_null<key,itm> (!p)
in
if isnul
then let
prval () = fpf (pf)
in
loop (ptr_succ<ki> (p), env)
end // end of [then]
else let
val () =
hashtbl_foreach$fwork<key,itm><env> (p->0, p->1, env)
prval () = fpf (pf)
in
loop (ptr_succ<ki> (p), env)
end // end of [else]
// end of [if]
end // end of [then]
else ((*exit*)) // end of [else]
//
end // end of [loop]
//
in
loop (p0, env)
end // end of [hashtbl_foreach_env]
(* ****** ****** *)
implement
{key,itm}
hashtbl_free (tbl) = let
//
typedef ki = @(key, itm)
//
val+~HASHTBL (A, cap, ntot) = tbl in arrayptr_free{ki}(A)
//
end // end of [hashtbl_free]
(* ****** ****** *)
implement
{key,itm}{ki2}
hashtbl_flistize
(tbl) = let
//
val+~HASHTBL (A, cap, _) = tbl
//
val p0 = ptrcast(A)
vtypedef ki = @(key, itm)
val p_end = ptr_add<ki> (p0, cap)
//
fun
loop
(
p: ptr
, res: List0_vt(ki2)
) : List0_vt(ki2) = let
in
//
if
p > p0
then let
val p = ptr_pred<ki> (p)
val (pf, fpf | p) = $UN.ptr0_vtake{ki}(p)
val isnul = hashtbl_linprb_keyitm_is_null<key,itm> (!p)
in
if isnul
then let
prval ((*void*)) = fpf (pf)
in
loop (p, res)
end // end of [then]
else let
val kx2 =
hashtbl_flistize$fopr<key,itm><ki2> (p->0, p->1)
val res = list_vt_cons{ki2}(kx2, res)
val ((*void*)) = hashtbl_linprb_keyitm_nullize<key,itm> (!p)
prval ((*void*)) = $UN.castview0 ((pf, fpf))
in
loop (p, res)
end // end of [else]
// end of [if]
end // end of [then]
else res // end of [else]
//
end // end of [loop]
//
val res = $effmask_all(loop (p_end, list_vt_nil(*void*)))
//
val ((*freed*)) = arrayptr_free($UN.castvwtp0{arrayptr(ki?,0)}(A))
//
in
res
end // end of [hashtbl_flistize]
(* ****** ****** *)
(* end of [hashtbl_linprb.dats] *)
|