/usr/lib/ats2-postiats-0.2.6/libats/ML/DATS/filebas_dirent.dats is in ats2-lang 0.2.6-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 | (***********************************************************************)
(* *)
(* Applied Type System *)
(* *)
(***********************************************************************)
(*
** ATS/Postiats - Unleashing the Potential of Types!
** Copyright (C) 2010-2013 Hongwei Xi, ATS Trustful Software, Inc.
** All rights reserved
**
** ATS is free software; you can redistribute it and/or modify it under
** the terms of the GNU GENERAL PUBLIC LICENSE (GPL) as published by the
** Free Software Foundation; either version 3, or (at your option) any
** later version.
**
** ATS is distributed in the hope that it will be useful, but WITHOUT ANY
** WARRANTY; without even the implied warranty of MERCHANTABILITY or
** FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
** for more details.
**
** You should have received a copy of the GNU General Public License
** along with ATS; see the file COPYING. If not, please write to the
** Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
** 02110-1301, USA.
*)
(* ****** ****** *)
(* Author: Hongwei Xi *)
(* Authoremail: gmhwxiATgmailDOTcom *)
(* Start time: September, 2013 *)
(* ****** ****** *)
#define ATS_DYNLOADFLAG 0
(* ****** ****** *)
staload UN = "prelude/SATS/unsafe.sats"
(* ****** ****** *)
staload _(*INT*) = "prelude/DATS/integer.dats"
staload _(*STRING*) = "prelude/DATS/string.dats"
staload _(*STRING*) = "prelude/DATS/strptr.dats"
staload _(*UNSAFE*) = "prelude/DATS/unsafe.dats"
(* ****** ****** *)
//
staload "libats/ML/SATS/basis.sats"
staload "libats/ML/SATS/list0.sats"
staload "libats/ML/SATS/string.sats"
//
staload "libats/ML/SATS/filebas.sats"
//
(* ****** ****** *)
staload DIR = "libc/SATS/dirent.sats"
staload _(*anon*) = "libc/DATS/dirent.dats"
(* ****** ****** *)
staload QUE = "libats/SATS/qlist.sats"
staload _(*anon*) = "libats/DATS/qlist.dats"
(* ****** ****** *)
stadef dirent = $DIR.dirent
stadef DIRptr1 = $DIR.DIRptr1
stadef qstruct0 = $QUE.qstruct0
(* ****** ****** *)
implement
dirname_get_fnamelst
(dirname) = let
//
vtypedef res = $QUE.qstruct0 (string)
//
fun loop
(
dirp: !DIRptr1, res: &res >> _
) : void = let
//
var ent: dirent?
var result: ptr?
//
val err = $DIR.readdir_r (dirp, ent, result)
//
in
//
if result > 0 then let
prval () = opt_unsome{dirent}(ent)
val d_name = $DIR.dirent_get_d_name_gc (ent)
val () = $QUE.qstruct_insert (res, strptr2string(d_name))
in
loop (dirp, res)
end else let
prval () = opt_unnone{dirent}(ent)
in
// nothing
end // end of [if]
//
end // end of [loop]
//
val dirp = $DIR.opendir (dirname)
//
in
//
if $DIR.DIRptr2ptr(dirp) > 0 then let
var res: $QUE.qstruct
val () = $QUE.qstruct_initize{string}(res)
val () = loop (dirp, res)
val res2 = $QUE.qstruct_takeout_list (res)
prval () = $QUE.qstruct_uninitize{string}(res)
val () = $DIR.closedir_exn (dirp)
in
g0ofg1_list_vt (res2)
end else let
prval () = $DIR.DIRptr_free_null (dirp)
in
list0_nil(*void*)
end // end of [if]
//
end // end of [dirname_get_fnamelst]
(* ****** ****** *)
(* end of [dirent.dats] *)
|