/usr/lib/ats2-postiats-0.2.6/libc/sys/SATS/wait.sats is in ats2-lang 0.2.6-2.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 | (***********************************************************************)
(* *)
(* Applied Type System *)
(* *)
(***********************************************************************)
(*
** ATS/Postiats - Unleashing the Potential of Types!
** Copyright (C) 2011-2013 Hongwei Xi, ATS Trustful Software, Inc.
** All rights reserved
**
** ATS is free software; you can redistribute it and/or modify it under
** the terms of the GNU GENERAL PUBLIC LICENSE (GPL) as published by the
** Free Software Foundation; either version 3, or (at your option) any
** later version.
**
** ATS is distributed in the hope that it will be useful, but WITHOUT ANY
** WARRANTY; without even the implied warranty of MERCHANTABILITY or
** FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
** for more details.
**
** You should have received a copy of the GNU General Public License
** along with ATS; see the file COPYING. If not, please write to the
** Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
** 02110-1301, USA.
*)
(* ****** ****** *)
//
// Author: Hongwei Xi
// Authoremail: gmhwxiATgmailDOTcom
// Start Time: May, 2013
//
(* ****** ****** *)
%{#
#include "libc/sys/CATS/wait.cats"
%} // end of [%{#]
(* ****** ****** *)
#define ATS_PACKNAME "ATSLIB.libc"
#define ATS_EXTERN_PREFIX "atslib_" // prefix for external names
(* ****** ****** *)
#define NSH (x) x // for commenting: no sharing
#define SHR (x) x // for commenting: it is shared
(* ****** ****** *)
staload
TYPES =
"libc/sys/SATS/types.sats"
typedef pid_t = $TYPES.pid_t
(* ****** ****** *)
absprop
WIFEXITED_p (s:int, b:bool)
fun WEXITSTATUS{s:int}
(
pf: WIFEXITED_p (s, true) | status: int s
) : int = "mac#%" // end of [WEXITSTATUS]
fun WIFEXITED{s:int}
(status: int s): [b:bool] (WIFEXITED_p (s, b) | bool b) = "mac#%"
// end of [WIFEXITED]
(* ****** ****** *)
absprop
WIFSIGNALED_p (s:int, b:bool)
fun WTERMSIG{s:int}
(
pf: WIFSIGNALED_p (s, true) | status: int s
) : int = "mac#%" // end of [WTERMSIG]
fun WIFSIGNALED{s:int}
(status: int s): [b:bool] (WIFSIGNALED_p (s, b) | bool b) = "mac#%"
// end of [WIFSIGNALED]
(* ****** ****** *)
absprop
WIFSTOPPED_p (s:int, b:bool)
fun WSTOPSIG{s:int}
(
pf: WIFSTOPPED_p (s, true) | status: int s
) : int = "mac#%" // end of [WSTOPSIG]
fun WIFSTOPPED {s:int}
(status: int s): [b:bool] (WIFSTOPPED_p (s, b) | bool b) = "mac#%"
// end of [WIFSTOPPED]
(* ****** ****** *)
absprop
WIFCONTINUED_p (s:int, b:bool)
fun WIFCONTINUED {s:int}
(status: int s): [b:bool] (WIFCONTINUED_p (s, b) | bool b) = "mac#%"
// end of [WIFCONTINUED]
(* ****** ****** *)
absprop
WCOREDUMP_p (s:int, b:bool)
fun WCOREDUMP {s:int}
(status: int s): [b:bool] (WCOREDUMP_p (s, b) | bool b) = "mac#%"
// end of [WCOREDUMP]
(* ****** ****** *)
//
symintr wait
fun wait_void (): pid_t = "mac#%"
fun wait_status (status: &int? >> int): pid_t = "mac#%"
overload wait with wait_void
overload wait with wait_status
//
(* ****** ****** *)
abst@ype
waitopt_t0ype = $extype"ats_int_type"
typedef waitopt = waitopt_t0ype
macdef WNONE = $extval (waitopt, "0")
macdef WNOHANG = $extval (waitopt, "WNOHANG")
macdef WUNTRACED = $extval (waitopt, "WUNTRACED")
macdef WCONTINUED = $extval (waitopt, "WCONTINUED")
fun lor_waitopt_waitopt
(opt1: waitopt, opt2: waitopt): waitopt
overload lor with lor_waitopt_waitopt
(* ****** ****** *)
fun waitpid
(
chldpid: pid_t, status: &int? >> int, opt: waitopt
) : pid_t = "mac#%" // end of [waitpid]
(* ****** ****** *)
(* end of [wait.sats] *)
|