/usr/bin/virt-list-filesystems

#!/usr/bin/env perl
# virt-list-filesystems
# Copyright (C) 2009-2016 Red Hat Inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.

use warnings;
use strict;

use Sys::Guestfs;
use Pod::Usage;
use Getopt::Long;
use Locale::TextDomain 'libguestfs';

=head1 NAME

virt-list-filesystems - List filesystems in a virtual machine or disk image

=head1 SYNOPSIS

 virt-list-filesystems [--options] domname

 virt-list-filesystems [--options] disk.img [disk.img ...]

=head1 OBSOLETE

This tool is obsolete.  Use L<virt-filesystems(1)> as a more
flexible replacement.

=head1 DESCRIPTION

C<virt-list-filesystems> is a command line tool to list
the filesystems that are contained in a virtual machine or
disk image.

C<virt-list-filesystems> is just a simple wrapper around
L<libguestfs(3)> functionality.  For more complex cases you should
look at the L<guestfish(1)> tool.

=head1 OPTIONS

=over 4

=cut

my $help;

=item B<--help>

Display brief help.

=cut

my $version;

=item B<--version>

Display version number and exit.

=cut

my $uri;

=item B<-c URI>

=item B<--connect URI>

If using libvirt, connect to the given I<URI>.  If omitted, then we
connect to the default libvirt hypervisor.

If you specify guest block devices directly, then libvirt is not used
at all.

=cut

my $format;

=item B<--format> raw

Specify the format of disk images given on the command line.  If this
is omitted then the format is autodetected from the content of the
disk image.

If disk images are requested from libvirt, then this program asks
libvirt for this information.  In this case, the value of the format
parameter is ignored.

If working with untrusted raw-format guest disk images, you should
ensure the format is always specified.

=cut

my $long;

=item B<-l>

=item B<--long>

With this option, C<virt-list-filesystems> displays the type of
each filesystem too (where "type" means C<ext3>, C<xfs> etc.)

=cut

my $all;

=item B<-a>

=item B<--all>

Normally we only show mountable filesystems.  If this option
is given then swap devices are shown too.

=back

=cut

# Configure bundling, otherwise '-al' is treated as '--all'.
Getopt::Long::Configure ("bundling");

GetOptions ("help|?" => \$help,
            "version" => \$version,
            "connect|c=s" => \$uri,
            "format=s" => \$format,
            "long|l" => \$long,
            "all|a" => \$all,
    ) or pod2usage (2);
pod2usage (1) if $help;
if ($version) {
    my $g = Sys::Guestfs->new ();
    my %h = $g->version ();
    print "$h{major}.$h{minor}.$h{release}$h{extra}\n";
    exit
}

pod2usage (__"virt-list-filesystems: no image or VM name given")
    if @ARGV <= 0;

my $g = Sys::Guestfs->new ();

my @args = (readonly => 1);
push @args, format => $format if defined $format;

if (-e $ARGV[0]) {
    $g->add_drive ($_, @args) foreach @ARGV;
}
else {
    push @args, libvirturi => $uri if defined $uri;
    $g->add_domain ($_, @args) foreach @ARGV;
}

$g->launch ();

# List of filesystems.
my %fses = $g->list_filesystems ();

my ($dev, $fstype);
foreach $dev (sort keys %fses) {
    $fstype = $fses{$dev};

    if ($all || ($fstype ne "swap" && $fstype ne "unknown")) {
        print $g->canonical_device_name ($dev);
        if ($long) {
            print " $fstype";
        }
        print "\n";
    }
}

=head1 SEE ALSO

L<guestfs(3)>,
L<guestfish(1)>,
L<virt-cat(1)>,
L<virt-tar(1)>,
L<virt-filesystems(1)>,
L<virt-list-partitions(1)>,
L<Sys::Guestfs(3)>,
L<Sys::Virt(3)>,
L<http://libguestfs.org/>.

=head1 AUTHOR

Richard W.M. Jones L<http://people.redhat.com/~rjones/>

=head1 COPYRIGHT

Copyright (C) 2009 Red Hat Inc.
libguestfs-tools 1:1.32.2-4ubuntu2 / usr / bin / virt-list-filesystems
