/usr/lib/x86_64-linux-gnu/perl5/5.22/MongoDB/Op/_ListIndexes.pm is in libmongodb-perl 1.2.2-1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 | #
# Copyright 2014 MongoDB, Inc.
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
package MongoDB::Op::_ListIndexes;
# Encapsulate index list operation; returns array ref of index documents
use version;
our $VERSION = 'v1.2.2';
use Moo;
use MongoDB::Error;
use MongoDB::Op::_Command;
use MongoDB::Op::_Query;
use MongoDB::_Constants;
use Types::Standard qw(
InstanceOf
Str
);
use Tie::IxHash;
use Try::Tiny;
use Safe::Isa;
use namespace::clean;
has db_name => (
is => 'ro',
required => 1,
isa => Str,
);
has coll_name => (
is => 'ro',
required => 1,
isa => Str,
);
has client => (
is => 'ro',
required => 1,
isa => InstanceOf ['MongoDB::MongoClient'],
);
with $_ for qw(
MongoDB::Role::_PrivateConstructor
MongoDB::Role::_ReadOp
MongoDB::Role::_CommandCursorOp
);
sub execute {
my ( $self, $link, $topology ) = @_;
my $res =
$link->accepts_wire_version(3)
? $self->_command_list_indexes( $link, $topology )
: $self->_legacy_list_indexes( $link, $topology );
return $res;
}
sub _command_list_indexes {
my ( $self, $link, $topology ) = @_;
my $op = MongoDB::Op::_Command->_new(
db_name => $self->db_name,
query => Tie::IxHash->new( listIndexes => $self->coll_name, cursor => {} ),
query_flags => {},
read_preference => $self->read_preference,
bson_codec => $self->bson_codec,
);
my $res = try {
$op->execute( $link, $topology );
}
catch {
if ( $_->$_isa("MongoDB::DatabaseError") ) {
return undef if $_->code == NAMESPACE_NOT_FOUND();
}
die $_;
};
return $res ? $self->_build_result_from_cursor($res) : $self->_empty_query_result($link);
}
sub _legacy_list_indexes {
my ( $self, $link, $topology ) = @_;
my $ns = $self->db_name . "." . $self->coll_name;
my $op = MongoDB::Op::_Query->_new(
modifiers => {},
allow_partial_results => 0,
batch_size => 0,
comment => '',
cursor_type => 'non_tailable',
limit => 0,
max_time_ms => 0,
no_cursor_timeout => 0,
oplog_replay => 0,
projection => undef,
skip => 0,
sort => undef,
db_name => $self->db_name,
coll_name => 'system.indexes',
bson_codec => $self->bson_codec,
client => $self->client,
read_preference => $self->read_preference,
filter => Tie::IxHash->new( ns => $ns ),
);
return $op->execute( $link, $topology );
}
1;
|