/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Components/ListItems/1.2/ExpandablesColumn.qml is in qml-module-ubuntu-components-gles 1.3.1918+16.04.20160404-0ubuntu3.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 | /*
* Copyright 2014 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU Lesser General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import Ubuntu.Components 1.2
/*!
\qmltype ExpandablesColumn
\inqmlmodule Ubuntu.Components.ListItems 1.0
\ingroup ubuntu-listitems
\brief A column to be used together with the \l Expandable item.
This lays out its content just like a regular Column inside a Flickable but
when used together with items of type \l Expandable it provides additional features
like automatically positioning the expanding item when it expands and collapsing
it again when the user taps outside of it.
Examples:
\qml
import Ubuntu.Components 1.2
import Ubuntu.Components.ListItems 1.0 as ListItem
ListItem.ExpandablesColumn {
anchors { left: parent.left; right: parent.right }
height: units.gu(24)
Repeater {
model: 8
ListItem.Expandable {
expandedHeight: units.gu(30)
onClicked: {
expanded = true;
}
}
}
}
\endqml
*/
Flickable {
id: root
contentHeight: column.height
/*!
Points to the currently expanded item. Null if no item is expanded.
\qmlproperty Item expandedItem
*/
readonly property alias expandedItem: priv.expandedItem
/*!
Expand the given item. The item must be a child of this ListView.
*/
function expandItem(item) {
if (!item.hasOwnProperty("expandedHeight") || !item.hasOwnProperty("collapsedHeight")) {
return;
}
if (priv.expandedItem != null) {
priv.expandedItem.expanded = false;
}
priv.expandedItem = item;
var maxExpandedHeight = root.height - item.collapsedHeight;
var expandedItemHeight = Math.min(item.expandedHeight, maxExpandedHeight);
var bottomIntersect = root.mapFromItem(item).y + expandedItemHeight - maxExpandedHeight;
if (bottomIntersect > 0) {
contentY += bottomIntersect;
}
}
/*!
Collapse the currently expanded item. If there isn't any item expanded, this function does nothing.
*/
function collapse() {
priv.expandedItem.expanded = false;
priv.expandedItem = null;
}
/*!
Reparent any content to inside the Column.
\qmlproperty QtObject children
\default
*/
default property alias children: column.data
/*! \internal */
QtObject {
id: priv
/*! \internal
Points to the currently expanded item. Null if no item is expanded.
*/
property var expandedItem: null
}
Behavior on contentY {
UbuntuNumberAnimation { }
}
Column {
id: column
anchors { left: parent.left; right: parent.right }
}
MouseArea {
anchors { left: parent.left; right: parent.right; top: parent.top }
height: root.mapFromItem(priv.expandedItem).y + root.contentY
enabled: priv.expandedItem != null
onClicked: root.collapse();
}
MouseArea {
anchors { left: parent.left; right: parent.right; bottom: parent.bottom }
height: priv.expandedItem != null ? root.contentHeight - (root.mapFromItem(priv.expandedItem).y + root.contentY + priv.expandedItem.height) : 0
enabled: priv.expandedItem != null
onClicked: root.collapse();
}
}
|