/usr/lib/x86_64-linux-gnu/qt5/qml/Ubuntu/Settings/Vpn/DialogFile.qml is in qtdeclarative5-ubuntu-settings-components 0.7+16.04.20160321.1-0ubuntu1.
This file is owned by root:root, with mode 0o644.
The actual contents of the file can be viewed below.
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 | /*
* Copyright (C) 2016 Canonical Ltd.
*
* This program is free software: you can redistribute it and/or modify it
* under the terms of the GNU Lesser General Public License version 3,
* as published by the Free Software Foundation.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*/
import QtQuick 2.4
import QtQuick.Layouts 1.1
import Ubuntu.Components 1.3
import Ubuntu.Components.ListItems 1.3 as ListItems
import Ubuntu.Components.Popups 1.3
import Ubuntu.Settings.Vpn 0.1
import Qt.labs.folderlistmodel 2.1
Dialog {
objectName: "vpnDialogFile"
id: dialog
property string currentFilePath: ""
signal accept(string path)
signal reject
function hideFunc() {
DialogFileProperties.lastFolder = modelFs.folder
currentFilePath = ""
}
function rejectFunc() {
hideFunc()
dialog.reject()
}
function acceptFunc() {
var path = currentFilePath
hideFunc()
dialog.accept(path)
}
FolderListModel {
id: modelFs
showDirs: true
showFiles: true
showHidden: true
showDirsFirst: true
showDotAndDotDot: false
showOnlyReadable: false
sortField: FolderListModel.Name
folder: (DialogFileProperties.lastFolder === "")? "file:///home/" : DialogFileProperties.lastFolder
}
ColumnLayout {
height: root.height - units.gu(10)
spacing: units.gu(1)
Flow {
spacing: units.gu(1)
Layout.fillWidth: true
Repeater {
model: {
var ret = []
var path = "file:///"
ret.push({ "name" : "/", "url" : path })
var tmp = modelFs.folder.toString().replace("file:///", "").split("/")
for (var idx = 0; idx < tmp.length; idx++) {
var name = tmp[idx] + "/"
if (name !== "/") {
path += name
ret.push({ "name" : name, "url" : path })
}
}
return ret
}
delegate: Row {
spacing: units.gu(0.7)
property bool isCurrent : Positioner.isLastItem
Rectangle {
width: units.gu(0.7)
height: width
color: "gray"
rotation: 45
visible: (model.index > 0)
anchors.verticalCenter: parent.verticalCenter
}
Label {
objectName: "vpnFilePathItem_" + model.modelData["name"]
text: model.modelData["name"]
font.weight: (isCurrent ? Font.Bold : Font.Normal)
font.underline: hoverDetector.containsMouse
color: "darkblue"
anchors.verticalCenter: parent.verticalCenter
MouseArea {
id: hoverDetector
enabled: !isCurrent
hoverEnabled: true
anchors.fill: parent
onClicked: modelFs.folder = model.modelData["url"]
}
}
}
}
}
Rectangle {
Layout.fillWidth: true
Layout.fillHeight: true
border {
width: 1
color: "lightgrey"
}
ListView {
objectName: "vpnFileList"
anchors.fill: parent
anchors.margins: 1
clip: true
model: modelFs
delegate: ListItems.Standard {
objectName: "vpnFileItem_" + model.fileName
text: model.fileName
iconFrame: false
iconName: model.fileIsDir ? "folder" : "empty"
selected: (model.filePath === currentFilePath)
onClicked: {
if (model.fileIsDir) {
modelFs.folder = model.fileURL
} else {
currentFilePath = model.filePath
}
}
}
}
}
RowLayout {
spacing: units.gu(1)
Layout.fillWidth: true
Button {
objectName: "vpnFileCancel"
Layout.fillWidth: true
text: i18n.dtr("ubuntu-settings-components", "Cancel")
onClicked: rejectFunc()
color: UbuntuColors.red
}
Button {
objectName: "vpnFileAccept"
Layout.fillWidth: true
enabled: currentFilePath !== ""
text: i18n.dtr("ubuntu-settings-components", "Accept")
onClicked: acceptFunc()
color: UbuntuColors.green
}
}
}
}
|